python3-faker: add v40.1.2

Faker is a Python package that generates fake data for you. Whether you
need to bootstrap your database, create good-looking XML documents,
fill-in your persistence to stress test it, or anonymize data
taken from a production service, Faker is for you.

* Skip tests/pytest as this causes the 'pytests --automake' parser to fail
  for some reason [1] and the handful of tests are of questionable extra value.

Testsuite summary
TOTAL: 2151
PASS: 2146
SKIP: 5
XFAIL: 0
FAIL: 0
XPASS: 0
ERROR: 0
DURATION: 39

Dependency for python3-orjson ptest.

[1] https://gitlab.com/rossburton/python-unittest-automake-output/-/issues/9

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

3 files changed, 52 insertions, 0 deletions

diff --git a/meta-python/conf/include/ptest-packagelists-meta-python.inc b/meta-python/conf/include/ptest-packagelists-meta-python.inc
index 15172e7f22..a84718b704 100644
--- a/meta-python/conf/include/ptest-packagelists-meta-python.inc
+++ b/meta-python/conf/include/ptest-packagelists-meta-python.inc
@@ -130,6 +130,7 @@ PTESTS_SLOW_META_PYTHON = "\
     python3-arrow \
     python3-django \
     python3-ecdsa \
+    python3-faker \
     python3-fastapi \
     python3-google-auth \
     python3-lz4 \
diff --git a/meta-python/recipes-devtools/python/python3-faker/pytest.ini b/meta-python/recipes-devtools/python/python3-faker/pytest.ini
new file mode 100644
index 0000000000..26f64467ce
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-faker/pytest.ini
@@ -0,0 +1,3 @@
+[pytest]
+addopts =
+    --ignore=tests/pytest
diff --git a/meta-python/recipes-devtools/python/python3-faker_40.1.2.bb b/meta-python/recipes-devtools/python/python3-faker_40.1.2.bb
new file mode 100644
index 0000000000..2a9970a91c
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-faker_40.1.2.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Faker is a Python package that generates fake data for you."
+DESCRIPTION = "Faker is a Python package that generates fake data for you. \
+Whether you need to bootstrap your database, create good-looking XML documents, \
+fill-in your persistence to stress test it, or anonymize data taken from a \
+production service, Faker is for you."
+HOMEPAGE = "https://github.com/joke2k/faker"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=53360c4126f7d03b63cb79b0dab9e9e1"
+
+SRC_URI[sha256sum] = "b76a68163aa5f171d260fc24827a8349bc1db672f6a665359e8d0095e8135d30"
+
+inherit pypi setuptools3 ptest-python-pytest
+
+SRC_URI += "file://pytest.ini"
+
+PACKAGECONFIG ?= "tzdata"
+PACKAGECONFIG[tzdata] = ",,,python3-tzdata"
+
+RDEPENDS:${PN} += "\
+    python3-compression \
+    python3-core \
+    python3-crypt \
+    python3-datetime \
+    python3-image \
+    python3-json \
+    python3-logging \
+    python3-math \
+    python3-netclient \
+    python3-numbers \
+    python3-pickle \
+    python3-pytest \
+    python3-stringold \
+    python3-unittest \
+    python3-xml \
+    python3-zoneinfo \
+    "
+
+RDEPENDS:${PN}-ptest += "\
+    python3-freezegun \
+    python3-validators \
+"
+
+do_install_ptest:append() {
+    install ${UNPACKDIR}/pytest.ini ${D}${PTEST_PATH}/
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+