python3-pydantic: upgrade 2.7.3 -> 2.8.2

* Set RECIPE_NO_UPDATE_REASON because of issues we have been having with
  getting out of sync with required python3-pydantic-core version
* Add RDEPENDS for ptest:
  - python3-pydoc (for test_help cases)
  - python3-email-validator
  - The standard library provides the getpass module, we provide it
    in the python3-unixadmin sub-package of python3 recipe.
  - python3-rich

Full change log:
https://github.com/pydantic/pydantic/compare/v2.8.2...v2.7.3

Highlights of changes:

v2.8.2 (2024-07-03)
  * Fix issue with assertion caused by pluggable schema validator by
    @dmontagu in #9838
  * See https://docs.pydantic.dev/latest/changelog/#v282-2024-07-03

v2.8.1 (2024-07-03)¶
  * Bump pydantic-core to v2.20.1, pydantic-extra-types to v2.9.0 by
    @sydney-runkle in #9832
  * See https://docs.pydantic.dev/latest/changelog/#v281-2024-07-03

v2.8.0 (2024-07-01)
  * Bump pydantic-core to v2.20.0 by @sydney-runkle in #9745
  * Add support for Python 3.13 by @sydney-runkle in #9743
  * See https://docs.pydantic.dev/latest/changelog/#v280-2024-07-01

v2.7.4 (2024-06-12)
  * Bump pydantic.v1 to v1.10.16 reference by @sydney-runkle in #9639
  * See https://docs.pydantic.dev/latest/changelog/#v274-2024-06-12

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 59 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pydantic_2.8.2.bb b/meta-python/recipes-devtools/python/python3-pydantic_2.8.2.bb
new file mode 100644
index 0000000000..de610d7815
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pydantic_2.8.2.bb
@@ -0,0 +1,59 @@
+SUMMARY = "Data validation using Python type hinting"
+DESCRIPTION = "Data validation and settings management using Python \
+type hints.\
+\
+Fast and extensible, Pydantic plays nicely with your linters/IDE/brain. \
+Define how data should be in pure, canonical Python 3.7+; validate it with \
+Pydantic."
+HOMEPAGE = "https://github.com/samuelcolvin/pydantic"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=09280955509d1c4ca14bae02f21d49a6"
+
+inherit pypi python_hatchling
+
+SRC_URI[sha256sum] = "6f62c13d067b0755ad1c21a34bdd06c0c12625a22b0fc09c6b149816604f7c2a"
+
+DEPENDS += "python3-hatch-fancy-pypi-readme-native"
+
+RECIPE_NO_UPDATE_REASON = "Must be updated in sync with python3-pydantic-core."
+
+RDEPENDS:${PN} += "\
+    python3-annotated-types \
+    python3-core \
+    python3-datetime \
+    python3-image \
+    python3-io \
+    python3-json \
+    python3-logging \
+    python3-netclient \
+    python3-numbers \
+    python3-profile \
+    python3-pydantic-core \
+    python3-typing-extensions \
+"
+
+inherit ptest
+SRC_URI += "file://run-ptest"
+RDEPENDS:${PN}-ptest += "\
+    python3-cloudpickle \
+    python3-dirty-equals \
+    python3-email-validator \
+    python3-pydoc \
+    python3-pytest \
+    python3-pytest-mock \
+    python3-rich \
+    python3-unittest-automake-output \
+    python3-unixadmin \
+"
+
+do_install_ptest() {
+    cp -rf ${S}/tests/ ${D}${PTEST_PATH}/
+    # Requires 'ruff' (python3-ruff) which we cannot build
+    # until we have Rust 1.71+ in oe-core
+    rm -f ${D}${PTEST_PATH}/tests/test_docs.py
+    # We are not trying to support mypy
+    rm -f ${D}${PTEST_PATH}/tests/test_mypy.py
+    # We are not trying to run benchmarks
+    rm -rf ${D}${PTEST_PATH}/tests/benchmarks
+    sed -i -e "/--automake/ s/$/ -k 'not test_config_validation_error_cause and not test_dataclass_config_validate_default and not test_annotated_validator_nested and not test_use_bare and not test_use_no_fields and not test_validator_bad_fields_throws_configerror and not test_assert_raises_validation_error and not test_model_config_validate_default'/" ${D}${PTEST_PATH}/run-ptest
+}