python3-pydantic-core: upgrade 2.34.1. -> 2.35.2

new version ptest needs module typing_inspection
| ImportError while importing test module '/usr/lib/python3-pydantic-core/ptest/tests/test_misc.py'.
| Hint: make sure your test modules/packages have valid Python names.
| Traceback:
| ../../python3.13/importlib/__init__.py:88: in import_module
|     return _bootstrap._gcd_import(name[level:], package, level)
|            ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
| tests/test_misc.py:10: in <module>
|     from typing_inspection import typing_objects
| E   ModuleNotFoundError: No module named 'typing_inspection'
| ERROR: tests/test_misc.py:tests/test_misc.py

Changelog:
==========
- update to speedate 0.16
- Better document SerializationInfo
- Fix generic issues with ValidationInfo and SerializationInfo
- Do not reuse validator and serializer when unpickling
- Remove unnecessary required fields count when exclude_none is set
- Update test dependencies after 3.8 dropped support
- Mark constructor parameters of exceptions as positional-only
- fix: submodel fields with wrap validator affect smart union selection
- use pypa/gh-action-pypi-publish
- add critical sections around bytearray reads
- simplify ser-as-any mechanism
- Coerce 'time' schema constraints
- drop serde-json preserve_order feature
- Remove core schema validation
- Improve uncaught PydanticUseDefault exception message
- Add support for Python 3.14
- drop pypy3.9 support, add pypy3.11 support
- Add ensure_ascii option
- Update repr of TzInfo
- Make ValidationInfo and SerializationInfo generic for context

Signed-off-by: Liu Yiding <liuyd.fnst@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 51 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pydantic-core_2.35.2.bb b/meta-python/recipes-devtools/python/python3-pydantic-core_2.35.2.bb
new file mode 100644
index 0000000000..1d0d1f477b
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pydantic-core_2.35.2.bb
@@ -0,0 +1,51 @@
+SUMMARY = "Provides the core functionality for pydantic validation and serialization."
+DESCRIPTION = "This package provides the core functionality for \
+pydantic validation and serialization.\
+\
+Pydantic-core is currently around 17x faster than pydantic V1."
+HOMEPAGE = "https://github.com/pydantic/pydantic-core"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ab599c188b4a314d2856b3a55030c75c"
+
+require ${BPN}-crates.inc
+
+SRC_URI += "file://0001-Upgrade-radium-to-1.0.patch;patchdir=${UNPACKDIR}/cargo_home/bitbake/bitvec-1.0.1/"
+SRC_URI += "file://0001-cargo.toml-Update-bitvec-to-use-radium-1.x.patch"
+SRC_URI[sha256sum] = "e010b13ff0d6375ee83f7478fbda42e1fbf55f1b2feef76b673c40861ffd31e6"
+
+DEPENDS = "python3-maturin-native python3-typing-extensions"
+
+inherit pypi cargo-update-recipe-crates python_maturin ptest-python-pytest
+
+PYPI_PACKAGE = "pydantic_core"
+UPSTREAM_CHECK_PYPI_PACKAGE = "${PYPI_PACKAGE}"
+
+RDEPENDS:${PN} += " \
+    python3-compression \
+    python3-typing-extensions \
+"
+
+INSANE_SKIP:${PN} = "already-stripped"
+
+# python3-misc is for Lib/timeit.py which is not split out elsewhere
+RDEPENDS:${PN}-ptest += "\
+        python3-dateutil \
+    python3-dirty-equals \
+    python3-hypothesis \
+    python3-inline-snapshot \
+    python3-misc \
+    python3-pytest-mock \
+    python3-pytest-timeout \
+    python3-pytest-benchmark \
+    python3-typing-inspection \
+        python3-tzdata \
+        python3-zoneinfo \
+"
+
+do_install_ptest:append () {
+    cp -rf ${S}/tests/ ${D}${PTEST_PATH}/
+    sed -i -e "/--automake/ s/$/ -k 'not test_model_class_root_validator_wrap and not test_model_class_root_validator_before and not test_model_class_root_validator_after'/" ${D}${PTEST_PATH}/run-ptest
+}
+
+BBCLASSEXTEND = "native nativesdk"