python3-prettytable: Upgrade 3.4.1 -> 3.6.0

Upgrade to release 3.6.0:

- Updated pre-commit with mypy
- Test Python 3.12 pre-releases
- Fix to min_table_width parameter
- Widen tables with long titles

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 46 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_3.6.0.bb b/meta-python/recipes-devtools/python/python3-prettytable_3.6.0.bb
new file mode 100644
index 0000000000..0c0692b144
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_3.6.0.bb
@@ -0,0 +1,46 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c9a6829fcd174d9535b46211917c7671"
+
+SRC_URI[sha256sum] = "2e0026af955b4ea67b22122f310b90eae890738c08cb0458693a49b6221530ac"
+
+do_install:append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/PrettyTable/"
+UPSTREAM_CHECK_REGEX = "/PrettyTable/(?P<pver>(\d+[\.\-_]*)+)"
+
+BBCLASSEXTEND = "native nativesdk"
+inherit pypi ptest python_hatchling
+
+SRC_URI += " \
+        file://run-ptest \
+"
+
+DEPENDS += "\
+    ${PYTHON_PN}-hatch-vcs-native \
+"
+
+RDEPENDS:${PN} += " \
+        ${PYTHON_PN}-math \
+        ${PYTHON_PN}-html \
+        ${PYTHON_PN}-wcwidth \
+        ${PYTHON_PN}-json \
+        ${PYTHON_PN}-compression \
+        ${PYTHON_PN}-importlib-metadata \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-pytest-lazy-fixture \
+    ${PYTHON_PN}-sqlite3 \
+"
+
+do_install_ptest() {
+        cp -f ${S}/tests/test_prettytable.py ${D}${PTEST_PATH}/
+}