python3-prettytable: Upgrade 3.3.0 -> 3.4.1

Upgrade to release 3.4.1:

- Add option to specify line break character used in pagination
- Add header alignment attribute
- Revert "Add header alignment attribute"

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 44 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_3.4.1.bb b/meta-python/recipes-devtools/python/python3-prettytable_3.4.1.bb
new file mode 100644
index 0000000000..c8b50f0b2d
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_3.4.1.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c9a6829fcd174d9535b46211917c7671"
+
+SRC_URI[sha256sum] = "7d7dd84d0b206f2daac4471a72f299d6907f34516064feb2838e333a4e2567bd"
+
+do_install:append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/PrettyTable/"
+UPSTREAM_CHECK_REGEX = "/PrettyTable/(?P<pver>(\d+[\.\-_]*)+)"
+
+BBCLASSEXTEND = "native nativesdk"
+inherit pypi ptest setuptools3
+
+SRC_URI += " \
+        file://run-ptest \
+"
+
+DEPENDS += "${PYTHON_PN}-setuptools-scm-native"
+
+RDEPENDS:${PN} += " \
+        ${PYTHON_PN}-math \
+        ${PYTHON_PN}-html \
+        ${PYTHON_PN}-wcwidth \
+        ${PYTHON_PN}-json \
+        ${PYTHON_PN}-compression \
+        ${PYTHON_PN}-importlib-metadata \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-pytest-lazy-fixture \
+    ${PYTHON_PN}-sqlite3 \
+"
+
+do_install_ptest() {
+        cp -f ${S}/tests/test_prettytable.py ${D}${PTEST_PATH}/
+}