python3-prettytable: upgrade 3.11.0 -> 3.12.0

Changelog:
===========
- Emit DeprecationWarnings for hrule and tableStyle constants
- Add new themes to ColorTable
- Use SPDX license identifier
- Add IntEnum for HRuleStyle and VRuleStyle
- Add IntEnum for Table styles
- Add OptionsType
- Add attribute type hints
- Add missing attribute annotations
- Add type aliases for Align, VAlign, HeaderStyle
- Add type annotations for attributes property
- Improve TableHandler type annotations
- Improve function type annotations
- Improve row and column type annotations
- Improve type annotations for field names
- Include RowType in __all__
- Small improvements
- Generate __version__ at build to avoid slow importlib.metadata call
- Release to PyPI using Trusted Publishing
- Drop support for Python 3.8
- Update new home to prettytable/prettytable
- Fix drawing headerless colored tables with title
- 1Adjust format validation

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_3.12.0.bb b/meta-python/recipes-devtools/python/python3-prettytable_3.12.0.bb
new file mode 100644
index 0000000000..442aadda29
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_3.12.0.bb
@@ -0,0 +1,45 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c9a6829fcd174d9535b46211917c7671"
+
+
+SRC_URI[sha256sum] = "f04b3e1ba35747ac86e96ec33e3bb9748ce08e254dc2a1c6253945901beec804"
+SRC_URI += " \
+        file://run-ptest \
+"
+inherit pypi ptest python_hatchling
+
+do_install:append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+DEPENDS += "\
+    python3-hatch-vcs-native \
+"
+
+RDEPENDS:${PN} += " \
+    python3-compression \
+    python3-html \
+    python3-importlib-metadata \
+    python3-json \
+    python3-math \
+    python3-wcwidth \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    python3-pytest \
+    python3-pytest-lazy-fixtures \
+    python3-sqlite3 \
+    python3-unittest-automake-output \
+"
+
+do_install_ptest() {
+     install -d ${D}${PTEST_PATH}/tests
+     cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+
+BBCLASSEXTEND = "native nativesdk"