python3-prettytable: upgrade 3.10.0 -> 3.10.2

Changelog:
===========
- Fix typo in README.md
- Change how size of headers are calculated to fix ColorTable with title

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_3.10.2.bb b/meta-python/recipes-devtools/python/python3-prettytable_3.10.2.bb
new file mode 100644
index 0000000000..519b58d202
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_3.10.2.bb
@@ -0,0 +1,45 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c9a6829fcd174d9535b46211917c7671"
+
+
+SRC_URI[sha256sum] = "29ec6c34260191d42cd4928c28d56adec360ac2b1208a26c7e4f14b90cc8bc84"
+SRC_URI += " \
+        file://run-ptest \
+"
+inherit pypi ptest python_hatchling
+
+do_install:append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+DEPENDS += "\
+    python3-hatch-vcs-native \
+"
+
+RDEPENDS:${PN} += " \
+    python3-compression \
+    python3-html \
+    python3-importlib-metadata \
+    python3-json \
+    python3-math \
+    python3-wcwidth \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    python3-pytest \
+    python3-pytest-lazy-fixtures \
+    python3-sqlite3 \
+    python3-unittest-automake-output \
+"
+
+do_install_ptest() {
+     install -d ${D}${PTEST_PATH}/tests
+     cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+
+BBCLASSEXTEND = "native nativesdk"