python3-prettytable: Upgrade 2.4.0 -> 3.1.1

Upgrade to release 3.1.1:

- Drop support for EOL Python 3.6
- Use <caption> tags to print html table titles
- Add colorful tables and themes
- Convert None to empty cell or custom value
- Resolve "KeyError" issue on _stringify_row

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Trevor Gamblin <trevor.gamblin@windriver.com>

1 files changed, 43 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_3.1.1.bb b/meta-python/recipes-devtools/python/python3-prettytable_3.1.1.bb
new file mode 100644
index 0000000000..3b75086fca
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_3.1.1.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c9a6829fcd174d9535b46211917c7671"
+
+SRC_URI[sha256sum] = "43c9e23272ca253d038ae76fe3adde89794e92e7fcab2ddf5b94b38642ef4f21"
+
+do_install:append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/PrettyTable/"
+UPSTREAM_CHECK_REGEX = "/PrettyTable/(?P<pver>(\d+[\.\-_]*)+)"
+
+BBCLASSEXTEND = "native nativesdk"
+inherit pypi ptest setuptools3
+
+SRC_URI += " \
+        file://run-ptest \
+"
+
+DEPENDS += "${PYTHON_PN}-setuptools-scm-native"
+
+RDEPENDS:${PN} += " \
+        ${PYTHON_PN}-math \
+        ${PYTHON_PN}-html \
+        ${PYTHON_PN}-wcwidth \
+        ${PYTHON_PN}-json \
+        ${PYTHON_PN}-compression \
+        ${PYTHON_PN}-importlib-metadata \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-sqlite3 \
+"
+
+do_install_ptest() {
+        cp -f ${S}/tests/test_prettytable.py ${D}${PTEST_PATH}/
+}