python3-prettytable: Upgrade 2.0.0 -> 2.1.0

Upgrade to release 2.1.0:

- Support formatting options in get_json_string()
- Replace setuptools/pkg_resources with importlib.metadata for
  getting version
- Docs: Add documentation for align, max_width, etc.
- Docs: Remove reference to Python 2.x print statement in README
- Docs: Update get_html_string with thead and tbody tags

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Acked-by: Trevor Gamblin <trevor.gamblin@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 39 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-prettytable_2.1.0.bb b/meta-python/recipes-devtools/python/python3-prettytable_2.1.0.bb
new file mode 100644
index 0000000000..fe7206255c
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-prettytable_2.1.0.bb
@@ -0,0 +1,39 @@
+SUMMARY = "Python library for displaying tabular data in a ASCII table format"
+HOMEPAGE = "http://code.google.com/p/prettytable"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c9a6829fcd174d9535b46211917c7671"
+
+SRC_URI[sha256sum] = "5882ed9092b391bb8f6e91f59bcdbd748924ff556bb7c634089d5519be87baa0"
+
+do_install_append() {
+    perm_files=`find "${D}${PYTHON_SITEPACKAGES_DIR}/" -name "*.txt" -o -name "PKG-INFO"`
+    for f in $perm_files; do
+        chmod 644 "${f}"
+    done
+}
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/PrettyTable/"
+UPSTREAM_CHECK_REGEX = "/PrettyTable/(?P<pver>(\d+[\.\-_]*)+)"
+
+BBCLASSEXTEND = "native nativesdk"
+inherit pypi ptest setuptools3
+
+SRC_URI += " \
+        file://run-ptest \
+"
+
+DEPENDS += "${PYTHON_PN}-setuptools-scm-native"
+
+RDEPENDS_${PN} += " \
+        ${PYTHON_PN}-math \
+        ${PYTHON_PN}-html \
+        ${PYTHON_PN}-wcwidth \
+"
+
+RDEPENDS_${PN}-ptest += " \
+        ${PYTHON_PN}-pytest \
+"
+
+do_install_ptest() {
+        cp -f ${S}/tests/test_prettytable.py ${D}${PTEST_PATH}/
+}