python3-pillow: upgrade 12.1.1 -> 12.2.0

Contains fix for CVE-2026-40192

License-update: Copyright holder's name is spelled out fully instead of using abbreviation.

Changelog: https://pillow.readthedocs.io/en/stable/releasenotes/12.2.0.html

Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 67 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pillow_12.2.0.bb b/meta-python/recipes-devtools/python/python3-pillow_12.2.0.bb
new file mode 100644
index 0000000000..f3fcb2d3c1
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pillow_12.2.0.bb
@@ -0,0 +1,67 @@
+DESCRIPTION = "Python Imaging Library (Fork). Pillow is the friendly PIL fork by Alex \
+Clark and Contributors. PIL is the Python Imaging Library by Fredrik Lundh and \
+Contributors."
+HOMEPAGE = "https://pillow.readthedocs.io"
+LICENSE = "MIT-CMU"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a6f0ac3777cfc96ded1b825e32ae7c99"
+
+SRC_URI = "git://github.com/python-pillow/Pillow.git;branch=main;protocol=https;tag=${PV} \
+           file://0001-support-cross-compiling.patch \
+           "
+SRCREV = "3c41c095064200a02672d89cc5ff629eaf4b0d4f"
+
+inherit python_setuptools_build_meta ptest-python-pytest
+
+PTEST_PYTEST_DIR = "Tests"
+
+PEP517_BUILD_OPTS += " \
+    -C platform-guessing=disable \
+    -C zlib=enable \
+    -C jpeg=enable \
+    -C tiff=enable \
+    -C freetype=enable \
+    -C lcms=enable \
+    -C jpeg2000=enable \
+    -C webp=disable \
+    -C webpmux=disable \
+    -C imagequant=disable \
+"
+
+DEPENDS += " \
+    zlib \
+    jpeg \
+    tiff \
+    freetype \
+    lcms \
+    openjpeg \
+    python3-pybind11-native \
+"
+
+RDEPENDS:${PN} += " \
+    python3-misc \
+    python3-logging \
+    python3-numbers \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxcb', '', d)} \
+"
+# python3-compile for filecmp module
+RDEPENDS:${PN}-ptest += " \
+    bash \
+    ghostscript \
+    jpeg-tools \
+    libwebp \
+    python3-compile \
+    python3-core \
+    python3-image \
+    python3-mmap \
+    python3-pytest-timeout \
+    python3-resource \
+    python3-unixadmin\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'tk', '', d)} \
+"
+
+CVE_PRODUCT = "pillow"
+
+
+RPROVIDES:${PN} += "python3-imaging"
+
+BBCLASSEXTEND = "native nativesdk"