python3-pillow: upgrade 10.3.0 -> 10.4.0

0001-support-cross-compiling.patch
refreshed for 10.4.0

Changelog:
===========
- Raise FileNotFoundError if show_file() path does not exist
- Improved reading 16-bit TGA images with colour
- Deprecate non-image ImageCms modes
- Fixed processing multiple JPEG EXIF markers
- Do not preserve EXIFIFD tag by default when saving TIFF images
- Added ImageFont.load_default_imagefont()
- Added Image.WARN_POSSIBLE_FORMATS
- Remove zero-byte end padding when parsing any XMP data
- Do not detect Ultra HDR images as MPO
- Raise SyntaxError specific to JP2
- Do not use first frame duration for other frames when saving APNG images
- Consider I;16 pixel size when using a 1 mode mask
- When saving multiple PNG frames, convert to mode rather than raw mode
- Added byte support to FreeTypeFont
- Allow float center for rotate operations
- Do not read layers immediately when opening PSD images
- Restore original thread state
- Read IM and TIFF images as RGB, rather than RGBX
- Only preserve TIFF IPTC_NAA_CHUNK tag if type is BYTE or UNDEFINED
- Clarify ImageDraw2 error message when size is missing
- Support unpacking more rawmodes to RGBA palettes
- Removed support for Qt 5
- Improve ImageFont.freetype support for XDG directories on Linux
- Improved consistency of XMP handling
- Use pkg-config to help find libwebp and raqm
- Accept 't' suffix for libtiff version #8126,
- Deprecate ImageDraw.getdraw hints parameter
- Added ImageDraw circle()
- Add mypy target to Makefile
- Added more modes to Image.MODES
- Deprecate BGR;15, BGR;16 and BGR;24 modes
- Fix ImagingAccess for I;16N on big-endian
- Support reading P mode TIFF images with padding
- Deprecate support for libtiff < 4
- Corrected ImageShow UnixViewer command
- Use functools.cached_property in ImageStat
- Add support for reading BITMAPV2INFOHEADER and BITMAPV3INFOHEADER
- Support reading CMYK JPEG2000 images

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 72 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pillow_10.4.0.bb b/meta-python/recipes-devtools/python/python3-pillow_10.4.0.bb
new file mode 100644
index 0000000000..71159ba500
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pillow_10.4.0.bb
@@ -0,0 +1,72 @@
+SUMMARY = "Python Imaging Library (Fork). Pillow is the friendly PIL fork by Alex \
+Clark and Contributors. PIL is the Python Imaging Library by Fredrik Lundh and \
+Contributors."
+HOMEPAGE = "https://pillow.readthedocs.io"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c349a4b4b9ec2377a8fd6a7df87dbffe"
+
+SRC_URI = "git://github.com/python-pillow/Pillow.git;branch=main;protocol=https \
+           file://0001-support-cross-compiling.patch \
+           file://run-ptest \
+           "
+SRCREV = "9b4fae77178e827ab17118fbc89c739ffd6a0fab"
+
+inherit python_setuptools_build_meta ptest
+
+PEP517_BUILD_OPTS += " \
+    -C platform-guessing=disable \
+    -C zlib=enable \
+    -C jpeg=enable \
+    -C tiff=enable \
+    -C freetype=enable \
+    -C lcms=enable \
+    -C jpeg2000=enable \
+    -C webp=disable \
+    -C webpmux=disable \
+    -C imagequant=disable \
+"
+
+DEPENDS += " \
+    zlib \
+    jpeg \
+    tiff \
+    freetype \
+    lcms \
+    openjpeg \
+"
+
+RDEPENDS:${PN} += " \
+    python3-misc \
+    python3-logging \
+    python3-numbers \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxcb', '', d)} \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    bash \
+    ghostscript \
+    jpeg-tools \
+    libwebp \
+    python3-core \
+    python3-image \
+    python3-mmap \
+    python3-pytest \
+    python3-pytest-timeout \
+    python3-resource \
+    python3-unittest-automake-output \
+    python3-unixadmin\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'tk', '', d)} \
+"
+
+CVE_PRODUCT = "pillow"
+
+S = "${WORKDIR}/git"
+
+RPROVIDES:${PN} += "python3-imaging"
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/Tests
+    cp -rf ${S}/Tests ${D}${PTEST_PATH}/
+}
+
+BBCLASSEXTEND = "native"