python3-pillow: Upgrade 10.1.0 -> 10.3.0 and fix ptest

License-Update: Updated copyright year and clean up authors, contributors

* 0001-explicitly-set-compile-options.patch dropped because setup.cfg moved to pyproject.toml -> (https://github.com/python-pillow/Pillow/pull/7484)

        Also, we can give the build option parameters as described in the documentation -> https://pillow.readthedocs.io/en/stable/installation/building-from-source.html#build-options
		Added build options to pass to build with using the variable PEP517_BUILD_OPTS so no need to create patch again.

* "python setup.py" and the use of "setup.py" as a command line tool are deprecated and upstream added a custom build backend to translate -C feature=disable style flags to the old --disable-feature style flags by prepending the build command (typically bdist_wheel) with a build_ext --disable-feature command which builds the extension modules before being added to a wheel. That backend uses the build_meta module of setuptools. The _CustomBuildMetaBackend class is a subclass of this module, adding custom behaviors and enabling settings specific to a particular project.

        https://github.com/python-pillow/Pillow/blob/10.3.0/_custom_build/backend.py

* Ptest tested on qemux86-64 and qemuarm64 with x11.

* Since no ptest error was encountered, python3-pillow has been moved from PTESTS_PROBLEMS_META_PYTHON to PTESTS_SLOW_META_PYTHON.

        Tests with SKIP are related to packages with explicitly disabled build options.

qemux86-64:

Testsuite summary
TOTAL: 4502
PASS: 4152
SKIP: 347
XFAIL: 2
FAIL: 0
XPASS: 1
ERROR: 0
DURATION: 904
END: /usr/lib/python3-pillow/ptest
2024-04-06T15:56
STOP: ptest-runner
TOTAL: 1 FAIL: 0

qemuarm64:

Testsuite summary
TOTAL: 4502
PASS: 4152
SKIP: 347
XFAIL: 2
FAIL: 0
XPASS: 1
ERROR: 0
DURATION: 674
END: /usr/lib/python3-pillow/ptest
2024-04-06T16:40
STOP: ptest-runner
TOTAL: 1 FAIL: 0

Changelog:

https://pillow.readthedocs.io/en/stable/releasenotes/10.3.0.html
https://pillow.readthedocs.io/en/stable/releasenotes/10.2.0.html

Signed-off-by: alperak <alperyasinak1@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 72 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pillow_10.3.0.bb b/meta-python/recipes-devtools/python/python3-pillow_10.3.0.bb
new file mode 100644
index 0000000000..debf488154
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pillow_10.3.0.bb
@@ -0,0 +1,72 @@
+SUMMARY = "Python Imaging Library (Fork). Pillow is the friendly PIL fork by Alex \
+Clark and Contributors. PIL is the Python Imaging Library by Fredrik Lundh and \
+Contributors."
+HOMEPAGE = "https://pillow.readthedocs.io"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c349a4b4b9ec2377a8fd6a7df87dbffe"
+
+SRC_URI = "git://github.com/python-pillow/Pillow.git;branch=main;protocol=https \
+           file://0001-support-cross-compiling.patch \
+           file://run-ptest \
+           "
+SRCREV = "5c89d88eee199ba53f64581ea39b6a1bc52feb1a"
+
+inherit python_setuptools_build_meta ptest
+
+PEP517_BUILD_OPTS += " \
+    -C platform-guessing=disable \
+    -C zlib=enable \
+    -C jpeg=enable \
+    -C tiff=enable \
+    -C freetype=enable \
+    -C lcms=enable \
+    -C jpeg2000=enable \
+    -C webp=disable \
+    -C webpmux=disable \
+    -C imagequant=disable \
+"
+
+DEPENDS += " \
+    zlib \
+    jpeg \
+    tiff \
+    freetype \
+    lcms \
+    openjpeg \
+"
+
+RDEPENDS:${PN} += " \
+    python3-misc \
+    python3-logging \
+    python3-numbers \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxcb', '', d)} \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    bash \
+    ghostscript \
+    jpeg-tools \
+    libwebp \
+    python3-core \
+    python3-image \
+    python3-mmap \
+    python3-pytest \
+    python3-pytest-timeout \
+    python3-resource \
+    python3-unittest-automake-output \
+    python3-unixadmin\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'tk', '', d)} \
+"
+
+CVE_PRODUCT = "pillow"
+
+S = "${WORKDIR}/git"
+
+RPROVIDES:${PN} += "python3-imaging"
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/Tests
+    cp -rf ${S}/Tests ${D}${PTEST_PATH}/
+}
+
+BBCLASSEXTEND = "native"