python3-pendulum: add at v3.2.0

Python datetimes made easy.

* Add patch to not strip .so
* Enable ptests
* Use git fetcher so we have tests/

Testsuite summary
TOTAL: 1835
PASS: 1832
SKIP: 3
XFAIL: 0
FAIL: 0
XPASS: 0
ERROR: 0
DURATION: 102

Dependency for python3-orjson ptest.

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pendulum_3.2.0.bb b/meta-python/recipes-devtools/python/python3-pendulum_3.2.0.bb
new file mode 100644
index 0000000000..a2dc7e7d9e
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pendulum_3.2.0.bb
@@ -0,0 +1,35 @@
+SUMMARY = "Python datetimes made easy"
+DESCRIPTION = "Pendulum is a Python package to ease datetimes manipulation. \
+It provides classes that are drop-in replacements for the native ones (they \
+inherit from them). \
+Special care has been taken to ensure timezones are handled correctly, and \
+are based on the underlying tzinfo implementation. For example, all \
+comparisons are done in UTC or in the timezone of the datetime being used. \
+The default timezone, except when using the now(), method will always be UTC. \
+"
+HOMEPAGE = "https://pendulum.eustace.io"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=869e1c364438f234f09673c4039ed114"
+
+DEPENDS = "python3-maturin-native"
+
+SRCREV = "aea611d7a1c15ed0da56505c3f370fe4446ba733"
+PYPI_SRC_URI = "git://github.com/python-pendulum/pendulum;protocol=https;branch=master;tag=${PV};destsuffix=pendulum-${PV}"
+
+SRC_URI += "file://0001-rust-Cargo.toml-inhibit-strip.patch"
+
+require ${BPN}-crates.inc
+
+inherit pypi python_maturin cargo-update-recipe-crates ptest-python-pytest
+
+do_install_ptest:append() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+
+RDEPENDS:${PN} += "python3-dateutil python3-tzdata"
+
+RDEPENDS:${PN}-ptest += "\
+    python3-dateutil-zoneinfo \
+    python3-time-machine \
+    "