python3-pandas: upgrade 3.0.2 -> 3.0.3

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 48 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-pandas_3.0.3.bb b/meta-python/recipes-devtools/python/python3-pandas_3.0.3.bb
new file mode 100644
index 0000000000..132a0acee7
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pandas_3.0.3.bb
@@ -0,0 +1,48 @@
+SUMMARY  = "pandas library for high-performance data analysis tools"
+DESCRIPTION = "pandas is an open source, BSD-licensed library providing \
+high-performance, easy-to-use data structures and data analysis tools for \
+the Python programming language."
+HOMEPAGE = "https://pandas.pydata.org/"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e98642e1210ade884e5254ab18d55b7d"
+
+SRC_URI:append:class-target = " file://0001-BLD-add-option-to-specify-numpy-header-location.patch "
+
+SRC_URI[sha256sum] = "696a4a00a2a2a35d4e5deb3fc946641b96c944f02230e4f76137fe35d806c4fc"
+
+CVE_PRODUCT = "pandas"
+
+inherit pkgconfig pypi python_mesonpy cython
+
+DEPENDS += " \
+    python3-numpy \
+    python3-versioneer-native \
+"
+
+CFLAGS:append:toolchain-clang = " -Wno-error=deprecated-declarations"
+
+RDEPENDS:${PN} += " \
+    python3-json \
+    python3-numpy \
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-pytz \
+    python3-profile \
+"
+
+PYTHONPATH:prepend:class-target = "${RECIPE_SYSROOT}${PYTHON_SITEPACKAGES_DIR}:"
+export PYTHONPATH
+
+do_compile:append() {
+    # Fix absolute paths in generated files
+    find ${B} -name "*.c" -o -name "*.cpp" | xargs -r \
+        sed -i 's|${WORKDIR}/pandas-${PV}/|${TARGET_DBGSRC_DIR}/|g'
+}
+
+do_install:prepend() {
+        sed -i -e 's;${S};;g' ${B}/pandas/_libs/sparse.cpython-*/pandas/_libs/sparse.pyx.c
+}
+
+EXTRA_OEMESON:append:class-target = " -Dnumpy_inc_dir=${RECIPE_SYSROOT}${PYTHON_SITEPACKAGES_DIR}/numpy/_core/include "
+
+BBCLASSEXTEND = "native"