python3-orjson: Upgrade to 3.11.9

Depends on rust 1.95 and fix building with rust 1.95

Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 46 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-orjson_3.11.9.bb b/meta-python/recipes-devtools/python/python3-orjson_3.11.9.bb
new file mode 100644
index 0000000000..2e9392fab9
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-orjson_3.11.9.bb
@@ -0,0 +1,46 @@
+SUMMARY = "orjson is a fast, correct JSON library for Python"
+HOMEPAGE = "https://pypi.org/project/orjson/"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
+
+SRCREV = "705515d77b28429d0b7c30c3d781abe52e8a1e5a"
+PYPI_SRC_URI = "git://github.com/ijl/orjson;protocol=https;branch=master;tag=${PV};destsuffix=orjson-${PV}"
+
+CVE_PRODUCT = "orjson"
+
+require ${BPN}-crates.inc
+
+inherit pypi python_maturin cargo-update-recipe-crates ptest-python-pytest
+
+SRC_URI += " \
+    file://0001-Guard-avx512-module-with-x86-target-cfg.patch \
+    file://0002-Guard-x86-feature-detection-macro-in-pystrref-object.patch \
+"
+DEPENDS = "python3-maturin-native"
+
+RDEPENDS:${PN} += "python3-maturin python3-mypy"
+
+do_compile:prepend() {
+    sed -i "/panic = \"abort\"/d" ${S}/Cargo.toml
+}
+
+do_install_ptest:append() {
+    install -d ${D}${PTEST_PATH}/data
+    cp -rf ${S}/data/* ${D}${PTEST_PATH}/data/
+    install -d ${D}${PTEST_PATH}/test
+    cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
+}
+
+RDEPENDS:${PN}-ptest += "\
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-faker \
+    python3-numpy \
+    python3-pandas \
+    python3-pendulum \
+    python3-psutil \
+    python3-pytz \
+    python3-tzdata \
+"
+
+BBCLASSEXTEND = "native nativesdk"