python3-m2crypto: upgrade 0.44.0 -> 0.45.0

python3-m2crypto/0001-setup.py-Make-the-cmd-available.patch
refreshed for 0.45.0

Changelog:
===========
- chore: build Windows builds with Python 3.13 as well
- fix: remove support for Engine
- chore: mark actual license of the project BSD-2-Clause instead of wrong MIT
- ci(Debian): make M2Crypto buildable on Debian
- swig: Workaround for reading sys/select.h ending with wrong types.
- ci: bump required setuptools version because of change in naming strategy
- fix: add fix for build with older GCC
- fix: remove AnyStr and Any types
- chore: add .git-blame-ignore-revs
- chore: blacken everything

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 52 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-m2crypto_0.45.0.bb b/meta-python/recipes-devtools/python/python3-m2crypto_0.45.0.bb
new file mode 100644
index 0000000000..77f1f7df89
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-m2crypto_0.45.0.bb
@@ -0,0 +1,52 @@
+SUMMARY = "A Python crypto and SSL toolkit"
+HOMEPAGE = "https://gitlab.com/m2crypto/m2crypto"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=b0e1f0b7d0ce8a62c18b1287b991800e"
+
+SRC_URI[sha256sum] = "ffc10d4d09901514f408dc74f60a4d7df21c44ebc9bf776c947bfdc7359421cf"
+
+SRC_URI += " \
+           file://0001-setup.py-Make-the-cmd-available.patch \
+"
+
+inherit pypi siteinfo python_setuptools_build_meta
+
+DEPENDS += "openssl swig-native"
+RDEPENDS:${PN} += "\
+  python3-datetime \
+  python3-setuptools \
+  python3-logging \
+  python3-netclient \
+  python3-netserver \
+  python3-numbers \
+  python3-xmlrpc \
+"
+
+DISTUTILS_BUILD_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR} -I${STAGING_INCDIR}"
+DISTUTILS_INSTALL_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR}"
+
+SWIG_FEATURES ?= "-D__${HOST_ARCH}__ ${@['-D__ILP32__','-D__LP64__'][d.getVar('SITEINFO_BITS') != '32']} -DOPENSSL_NO_FILENAMES"
+
+SWIG_FEATURES:append:riscv64 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
+SWIG_FEATURES:append:riscv32 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
+SWIG_FEATURES:append:mipsarch = " -D_MIPS_SZPTR=${SITEINFO_BITS}"
+SWIG_FEATURES:append:powerpc64le = " -D__powerpc64__"
+SWIG_FEATURES:append:x86 = " -D__i386__"
+SWIG_FEATURES:append:x32 = " -D__ILP32__"
+
+export SWIG_FEATURES
+
+export STAGING_DIR
+
+do_configure:prepend() {
+    # workaround for https://github.com/swiftlang/swift/issues/69311
+    sed -i "/sys\/types.h/d" ${RECIPE_SYSROOT}${includedir}/openssl/e_os2.h
+}
+
+do_install:append() {
+    rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/SSL/__pycache__/*.cpython-*.pyc
+    rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/__pycache__/*.cpython-*.pyc
+}
+
+BBCLASSEXTEND = "native"