python3-gpiod: update to v2.4.2

Bug-fix release addressing a buffer overflow bug discovered during an
AI-augmented security audit as well as another minor issue with
unnecessarily duplicated code.

Signed-off-by: Bartosz Golaszewski <bartosz.golaszewski@oss.qualcomm.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 43 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-gpiod_2.4.2.bb b/meta-python/recipes-devtools/python/python3-gpiod_2.4.2.bb
new file mode 100644
index 0000000000..87765c2482
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-gpiod_2.4.2.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Python bindings for libgpiod."
+
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4b54a1fd55a448865a0b32d41598759d"
+
+SRC_URI += "file://run-ptest"
+
+SRC_URI[sha256sum] = "602aae17ff365bb8e2a30ce65c6bbf2d8e7a7e64bf016e82e4fd4c730ef69ab7"
+
+inherit python_setuptools_build_meta python_pep517 ptest pypi
+
+DEPENDS += " \
+    libgpiod \
+    python3-setuptools-native \
+"
+RDEPENDS:${PN} += " \
+    libgpiod (>= 2.1) \
+    python3-datetime \
+    python3-profile \
+"
+RDEPENDS:${PN}-ptest += " \
+    libgpiod-gpiosim \
+    python3-setuptools \
+"
+
+export LINK_SYSTEM_LIBGPIOD = "1"
+
+do_compile_ptest() {
+    setup_target_config
+    nativepython3 build_tests.py
+}
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/gpiod-test/gpiosim
+    install -d ${D}${PTEST_PATH}/gpiod-test/system
+    install -m 0644 ${S}/tests/*.py ${D}${PTEST_PATH}/gpiod-test/
+    install -m 0644 ${B}/tests/gpiosim/_ext* ${D}${PTEST_PATH}/gpiod-test/gpiosim
+    install -m 0644 ${S}/tests/gpiosim/*.py ${D}${PTEST_PATH}/gpiod-test/gpiosim
+    install -m 0644 ${B}/tests/system/_ext* ${D}${PTEST_PATH}/gpiod-test/system
+    install -m 0644 ${S}/tests/system/*.py ${D}${PTEST_PATH}/gpiod-test/system
+}
+
+INSANE_SKIP:${PN}-ptest += "buildpaths"