python3-gevent: upgrade 23.9.1 -> 24.2.1

0001-_setuputils.py-Do-not-add-sys_inc_dir.patch
refreshed for 24.2.1

Changelog:
===========
-Add support for Python patch releases 3.11.8 and 3.12.2, which changed internal
 details of threading.
-Errors raised from subprocess.Popen may not have a filename set.
-SSLSocket.recv_into and SSLSocket.read no longer require the buffer to
 implement len and now work with buffers whose size is not 1.
-gh-108310: Fix CVE-2023-40217: Check for & avoid the ssl pre-close flaw.
-Drop setuptools to a soft test dependency.
-Drop support for very old versions of CFFI.
-Update bundled c-ares from 1.19.1 to 1.26.0.
-Locks created by gevent, but acquired from multiple different threads (not
 recommended), no longer spin to implement timeouts and interruptible blocking.
 Instead, they use the native functionality of the Python 3 lock.

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-gevent_24.2.1.bb b/meta-python/recipes-devtools/python/python3-gevent_24.2.1.bb
new file mode 100644
index 0000000000..ebde34d562
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-gevent_24.2.1.bb
@@ -0,0 +1,35 @@
+SUMMARY = "A coroutine-based Python networking library"
+DESCRIPTION = "gevent is a coroutine-based Python networking library that uses greenlet to provide \
+a high-level synchronous API on top of the libevent event loop."
+HOMEPAGE = "http://www.gevent.org"
+LICENSE = "MIT & Python-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4de99aac27b470c29c6c309e0c279b65"
+DEPENDS += "${PYTHON_PN}-greenlet libev libuv c-ares python3-cython-native"
+
+RDEPENDS:${PN} = "${PYTHON_PN}-greenlet \
+                  ${PYTHON_PN}-mime \
+                  ${PYTHON_PN}-pprint \
+                 "
+
+SRC_URI += "file://0001-_setuputils.py-Do-not-add-sys_inc_dir.patch"
+
+SRC_URI[sha256sum] = "432fc76f680acf7cf188c2ee0f5d3ab73b63c1f03114c7cd8a34cebbe5aa2056"
+
+inherit pypi setuptools3
+
+# Don't embed libraries, link to the system provided libs instead
+export GEVENTSETUP_EMBED_CARES = "0"
+export GEVENTSETUP_EMBED_LIBEV = "0"
+export GEVENTSETUP_EMBED_LIBUV = "0"
+
+do_configure:append() {
+        # Delete the embedded copies of libraries so we can't accidentally link to them
+        rm -rf ${S}/deps
+
+        # Delete the generated cython files, as they are all out of date with python 3.11
+        rm -rf ${S}/src/gevent/*.c
+}
+
+do_compile:append() {
+        sed -i -e 's#${WORKDIR}##g' ${S}/src/gevent/*.c ${S}/src/gevent/libev/*.c ${S}/src/gevent/resolver/*.c
+}