python3-faker: upgrade 40.8.0 -> 40.11.0

Changelog:
=============
- Add major Swiss banks to de_CH bank provider.
- Fix: mixed-gender names in es_MX locale.
- Fix pt_PT postalcode format in address provider.
- Fix mutable default providers.

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 48 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-faker_40.11.0.bb b/meta-python/recipes-devtools/python/python3-faker_40.11.0.bb
new file mode 100644
index 0000000000..c163bbb16d
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-faker_40.11.0.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Faker is a Python package that generates fake data for you."
+DESCRIPTION = "Faker is a Python package that generates fake data for you. \
+Whether you need to bootstrap your database, create good-looking XML documents, \
+fill-in your persistence to stress test it, or anonymize data taken from a \
+production service, Faker is for you."
+HOMEPAGE = "https://github.com/joke2k/faker"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=53360c4126f7d03b63cb79b0dab9e9e1"
+
+SRC_URI[sha256sum] = "7c419299103b13126bd02ec14bd2b47b946edb5a5eedf305e66a193b25f9a734"
+
+inherit pypi setuptools3 ptest-python-pytest
+
+SRC_URI += "file://pytest.ini"
+
+PACKAGECONFIG ?= "tzdata"
+PACKAGECONFIG[tzdata] = ",,,python3-tzdata"
+
+RDEPENDS:${PN} += "\
+    python3-compression \
+    python3-core \
+    python3-crypt \
+    python3-datetime \
+    python3-image \
+    python3-json \
+    python3-logging \
+    python3-math \
+    python3-netclient \
+    python3-numbers \
+    python3-pickle \
+    python3-pytest \
+    python3-stringold \
+    python3-unittest \
+    python3-xml \
+    python3-zoneinfo \
+    "
+
+RDEPENDS:${PN}-ptest += "\
+    python3-freezegun \
+    python3-validators \
+"
+
+do_install_ptest:append() {
+    install ${UNPACKDIR}/pytest.ini ${D}${PTEST_PATH}/
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+