python3-cmake: upgrade 4.2.0 -> 4.2.1

Changelog:
==========
- fix: add missing f-string prefix for --parallel bootstrap arg
- fix: workaround issue in lastversion with OpenSSL
- chore(deps): update clang to 21.1.8.0

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-cmake_4.2.1.bb b/meta-python/recipes-devtools/python/python3-cmake_4.2.1.bb
new file mode 100644
index 0000000000..88f9ff38a0
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-cmake_4.2.1.bb
@@ -0,0 +1,38 @@
+SUMMARY = "CMake is an open-source, cross-platform family of tools designed to build, test and package software"
+LICENSE = "BSD-3-Clause & Apache-2.0"
+LIC_FILES_CHKSUM = " \
+        file://LICENSE_BSD_3;md5=9134cb61aebbdd79dd826ccb9ae6afcd \
+        file://LICENSE_Apache_20;md5=19cbd64715b51267a47bf3750cc6a8a5 \
+"
+
+DEPENDS = "ninja-native cmake-native python3-scikit-build-native python3-scikit-build-core-native"
+
+PYPI_PACKAGE = "cmake"
+PYPI_ARCHIVE_NAME_PREFIX = "pypi-"
+
+inherit pypi python_setuptools_build_meta
+SRC_URI[sha256sum] = "a07a790ca65946667c0fb286549e8e0b5a850e2f8170ae60d3418573011ca218"
+
+SRC_URI += " \
+        file://CMakeLists.txt \
+        file://run-cmake-from-path.patch \
+"
+
+addtask do_patchbuild after do_patch before do_configure
+
+do_patchbuild () {
+        rm -f ${S}/CMakeLists.txt
+        cp ${UNPACKDIR}/CMakeLists.txt ${S}/
+}
+
+do_install:append () {
+        rm -rf ${D}${bindir}
+}
+
+RDEPENDS:${PN} = " \
+        cmake \
+        python3-scikit-build \
+        python3-scikit-build-core \
+"
+
+BBCLASSEXTEND = "native nativesdk"