python3-cmake: upgrade 3.31.1 -> 3.31.2

Changelog:
=========
- [Bot] Update to CMake 3.31.2
- fix: tests
- chore: align minimum cmake version with the one of scikit-build-core
- fix: bootstrap build

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-cmake_3.31.2.bb b/meta-python/recipes-devtools/python/python3-cmake_3.31.2.bb
new file mode 100644
index 0000000000..2c2cd02627
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-cmake_3.31.2.bb
@@ -0,0 +1,38 @@
+SUMMARY = "CMake is an open-source, cross-platform family of tools designed to build, test and package software"
+LICENSE = "BSD-3-Clause & Apache-2.0"
+LIC_FILES_CHKSUM = " \
+        file://LICENSE_BSD_3;md5=9134cb61aebbdd79dd826ccb9ae6afcd \
+        file://LICENSE_Apache_20;md5=19cbd64715b51267a47bf3750cc6a8a5 \
+"
+
+DEPENDS = "ninja-native cmake-native python3-scikit-build-native python3-scikit-build-core-native"
+
+PYPI_PACKAGE = "cmake"
+PYPI_ARCHIVE_NAME_PREFIX = "pypi-"
+
+inherit pypi python_setuptools_build_meta
+SRC_URI[sha256sum] = "16a323fcbb86cf8a10aea82cd4deecb33edb3ed7e8907be8a06933ce04f6e6d1"
+
+SRC_URI += " \
+        file://CMakeLists.txt \
+        file://run-cmake-from-path.patch \
+"
+
+addtask do_patchbuild after do_patch before do_configure
+
+do_patchbuild () {
+        rm -f ${S}/CMakeLists.txt
+        cp ${UNPACKDIR}/CMakeLists.txt ${S}/
+}
+
+do_install:append () {
+        rm -rf ${D}${bindir}
+}
+
+RDEPENDS:${PN} = " \
+        cmake \
+        python3-scikit-build \
+        python3-scikit-build-core \
+"
+
+BBCLASSEXTEND = "native nativesdk"