smarty: update 4.5.5 -> 5.4.2

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

2 files changed, 40 insertions, 28 deletions

diff --git a/meta-oe/recipes-support/smarty/smarty_4.5.5.bb b/meta-oe/recipes-support/smarty/smarty_4.5.5.bb
deleted file mode 100644
index e8a63a74a7..0000000000
--- a/meta-oe/recipes-support/smarty/smarty_4.5.5.bb
+++ /dev/null
@@ -1,28 +0,0 @@
-DESCRIPTION = "the compiling PHP template engine"
-SECTION = "console/network"
-HOMEPAGE = "https://www.smarty.net/"
-
-LICENSE = "GPL-3.0-only"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=2c0f216b2120ffc367e20f2b56df51b3"
-
-DEPENDS += "php"
-
-SRC_URI = "git://github.com/smarty-php/smarty.git;protocol=https;branch=support/4"
-
-SRCREV = "c4851c12e34ff80073ddeb7d98b059d57dea9de2"
-
-S = "${WORKDIR}/git"
-
-do_install() {
-        install -d ${D}${datadir}/php/smarty3/libs/
-        install -m 0644 ${S}/libs/*.php ${D}${datadir}/php/smarty3/libs/
-
-        install -d ${D}${datadir}/php/smarty3/libs/plugins
-        install -m 0644 ${S}/libs/plugins/*.php ${D}${datadir}/php/smarty3/libs/plugins/
-
-        install -d ${D}${datadir}/php/smarty3/libs/sysplugins
-        install -m 0644 ${S}/libs/sysplugins/*.php ${D}${datadir}/php/smarty3/libs/sysplugins/
-}
-FILES:${PN} = "${datadir}/php/smarty3/"
-
-CVE_STATUS[CVE-2020-10375] = "cpe-incorrect: The recipe used in the meta-openembedded is a different smarty package compared to the one which has the CVE issue."
diff --git a/meta-oe/recipes-support/smarty/smarty_5.4.2.bb b/meta-oe/recipes-support/smarty/smarty_5.4.2.bb
new file mode 100644
index 0000000000..95673e2bb9
--- /dev/null
+++ b/meta-oe/recipes-support/smarty/smarty_5.4.2.bb
@@ -0,0 +1,40 @@
+SUMMARY = "Template engine for PHP"
+DESCRIPTION = "\
+    Smarty facilitates the separation of presentation (HTML/CSS) from \
+    application logic. This implies that PHP code is application logic, and is \
+    separated from the presentation. \
+"
+HOMEPAGE = "https://smarty-php.github.io/smarty/"
+BUGTRACKER = "https://github.com/smarty-php/smarty/issues"
+
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=2c0f216b2120ffc367e20f2b56df51b3"
+
+SRC_URI = "git://github.com/smarty-php/smarty.git;protocol=https;branch=master"
+
+SRCREV = "642a97adcc2bf6c1b2458d6afeeb36ae001c1c2f"
+
+S = "${UNPACKDIR}/git"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+inherit allarch
+
+# `make clean` removes files, they can't be rebuild with `make all` 
+CLEANBROKEN = "1"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+do_install() {
+        install -d ${D}${datadir}/php/smarty3/libs/
+        install -m 0644 ${S}/libs/*.php ${D}${datadir}/php/smarty3/libs/
+
+        install -d ${D}${datadir}/php/smarty3/src/
+        cp -rf ${S}/src/* ${D}${datadir}/php/smarty3/src/
+}
+FILES:${PN} += "${datadir}/php/smarty3/"
+
+RDEPENDS:${PN} = "php"
+
+CVE_STATUS[CVE-2020-10375] = "cpe-incorrect: The recipe used in the meta-openembedded is a different smarty package compared to the one which has the CVE issue."