poppler: upgrade 25.08.0 -> 25.10.0

This upgrade includes fix for CVE-2025-52885

Poppler 25.10.0 Changelog:
=========================
core:
* Fix image signature getting lost
* Don't embed substitutions for base14 fonts
* Form font improvements
* Handle signatures padded with random data
* Add feature to Ink annotation to render with multiply blend mode
* Internal code improvements
* Fix crashes in malformed documents

glib:
* Fix signature text
* Add feature to Ink annotation to render with multiply blend mode

cpp:
* Added embedded_file::unicodeName function

Poppler 25.09.1 Changelog:
==========================
core:
* Internal code improvements

build system:
* Fix generated .pc files when using old gpgme

Poppler 25.09.0 Changelog:
=========================
core:
* Speed improvements when reusing the same document with different output devices
* Speed improvements when reading from network file systems
* Internal code improvements
* Fix crashes in malformed documents

glib:
* fix ODR issue with enum

utils:
* pdftohtml: Fix text positioning. (Regressed in 25.07.0)

build system:
* Better pkgconfig support for static builds

Signed-off-by: Yogita Urade <yogita.urade@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 57 insertions, 0 deletions

diff --git a/meta-oe/recipes-support/poppler/poppler_25.10.0.bb b/meta-oe/recipes-support/poppler/poppler_25.10.0.bb
new file mode 100644
index 0000000000..29a5f33e81
--- /dev/null
+++ b/meta-oe/recipes-support/poppler/poppler_25.10.0.bb
@@ -0,0 +1,57 @@
+SUMMARY = "Poppler is a PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE = "https://poppler.freedesktop.org/"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+SRC_URI = "http://poppler.freedesktop.org/${BP}.tar.xz \
+           file://0001-Do-not-overwrite-all-our-build-flags.patch \
+           file://basename-include.patch \
+           file://0001-cmake-Do-not-use-isystem.patch \
+           "
+SRC_URI[sha256sum] = "6b5e9bb64dabb15787a14db1675291c7afaf9387438cc93a4fb7f6aec4ee6fe0"
+
+DEPENDS = "fontconfig zlib cairo lcms glib-2.0 glib-2.0-native"
+
+inherit cmake pkgconfig gobject-introspection
+
+PACKAGECONFIG ??= "boost jpeg nss openjpeg png tiff"
+PACKAGECONFIG[boost] = "-DENABLE_BOOST=ON,-DENABLE_BOOST=OFF,boost"
+PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON -DENABLE_DCTDECODER=libjpeg,-DWITH_JPEG=OFF -DENABLE_DCTDECODER=none,jpeg"
+PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng"
+PACKAGECONFIG[tiff] = "-DENABLE_LIBTIFF=ON,-DENABLE_LIBTIFF=OFF,tiff"
+PACKAGECONFIG[curl] = "-DENABLE_LIBCURL=ON,-DENABLE_LIBCURL=OFF,curl"
+PACKAGECONFIG[openjpeg] = "-DENABLE_LIBOPENJPEG=openjpeg2,-DENABLE_LIBOPENJPEG=none,openjpeg"
+PACKAGECONFIG[qt5] = "-DENABLE_QT5=ON,-DENABLE_QT5=OFF,qtbase qttools-native"
+PACKAGECONFIG[nss] = "-DENABLE_NSS3=ON,-DENABLE_NSS3=OFF,nss"
+PACKAGECONFIG[gpgme] = "-DENABLE_GPGME=ON,-DENABLE_GPGME=OFF,gpgme"
+PACKAGECONFIG[qt6] = "-DENABLE_QT6=ON,-DENABLE_QT6=OFF,qtbase"
+
+# surprise - did not expect this to work :)
+inherit ${@bb.utils.contains('PACKAGECONFIG', 'qt5', 'cmake_qt5', '', d)}
+
+SECURITY_CFLAGS = "${SECURITY_NO_PIE_CFLAGS}"
+
+EXTRA_OECMAKE += " \
+    -DENABLE_LCMS=ON \
+    -DENABLE_UNSTABLE_API_ABI_HEADERS=ON \
+    -DBUILD_GTK_TESTS=OFF \
+    -DRUN_GPERF_IF_PRESENT=OFF \
+    -DCMAKE_CXX_IMPLICIT_INCLUDE_DIRECTORIES:PATH='${STAGING_INCDIR}' \
+    ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_GOBJECT_INTROSPECTION=ON', '-DENABLE_GOBJECT_INTROSPECTION=OFF', d)} \
+"
+EXTRA_OECMAKE:append:class-native = " -DENABLE_CPP=OFF"
+
+do_configure:append() {
+    # poppler macro uses pkg-config to check for g-ir runtimes. Something
+    # makes them point to /usr/bin. Align them to sysroot - that's where the
+    # gir-wrappers are:
+    sed -i 's: ${bindir}/g-ir: ${STAGING_BINDIR}/g-ir:' ${B}/build.ninja
+}
+
+PACKAGES =+ "libpoppler libpoppler-glib"
+FILES:libpoppler = "${libdir}/libpoppler.so.*"
+FILES:libpoppler-glib = "${libdir}/libpoppler-glib.so.*"
+
+RDEPENDS:libpoppler = "poppler-data"
+
+BBCLASSEXTEND = "native"