asio: upgrade 1.30.2 -> 1.36.0

License-Update: copyright years refreshed

Changelogs:

Asio 1.36.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_36_0

- Fixed an issue, introduced in Asio 1.35.0, that prevented the creation of internal threads required for running some asynchronous operations on a thread_pool.
- Fixed co_spawn to adhere to the asynchronous operation requirement for non-reentrant invocation of the completion handler.
- Added the [[noreturn]] attribute to asio::detail::throw_exception.
- Fixed compilation errors in channel<void(error_code)> and concurrent_channel<void(error_code)>.
- Fixed a compilation issue with the Bullseye compiler.
- Fixed an awaitable coroutine compile error with the clang shipped with MSVC.
- Fixed support for platforms that don't define SA_NOCLDWAIT.
- Worked around a warning that occurs when building with _FORTIFY_SOURCE on recent g++.
- Added a documentation note on basic_signal_set async signal safety.

Asio 1.35.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_35_0

Asio 1.34.2:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_34_2

Asio 1.34.1:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_34_1

Asio 1.34.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_34_0

Asio 1.33.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_33_0

Asio 1.32.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_32_0

Asio 1.31.0:
  https://think-async.com/Asio/asio-1.36.0/doc/asio/history.html#asio.history.asio_1_31_0

Signed-off-by: Andrej Kozemcak <andrej.kozemcak@siemens.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 40 insertions, 0 deletions

diff --git a/meta-oe/recipes-support/asio/asio_1.36.0.bb b/meta-oe/recipes-support/asio/asio_1.36.0.bb
new file mode 100644
index 0000000000..d196a35c69
--- /dev/null
+++ b/meta-oe/recipes-support/asio/asio_1.36.0.bb
@@ -0,0 +1,40 @@
+SUMMARY = "Asio is C++ library for network and low-level I/O programming"
+DESCRIPTION = "Asio is a cross-platform C++ library for network and low-level \
+        I/O programming that provides developers with a consistent asynchronous \
+        model using a modern C++ approach."
+HOMEPAGE = "http://think-async.com/Asio"
+SECTION = "libs"
+LICENSE = "BSL-1.0"
+
+DEPENDS = "openssl"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/asio/${BP}.tar.bz2 \
+           file://0001-tests-Remove-blocking_adaptation.cpp.patch \
+           file://run-ptest \
+"
+
+inherit autotools ptest
+
+ALLOW_EMPTY:${PN} = "1"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=92db288d8a7d89bb9c5821c447c3052c"
+
+SRC_URI[sha256sum] = "7bf4dbe3c1ccd9cc4c94e6e6be026dcc2110f9201d286bb9500dc85d69825524"
+
+PACKAGECONFIG ??= "boost"
+
+PACKAGECONFIG[boost] = "--with-boost=${STAGING_LIBDIR},--without-boost,boost"
+
+TESTDIR = "src/tests"
+do_compile_ptest() {
+    echo 'buildtest-TESTS: $(check_PROGRAMS)' >> ${TESTDIR}/Makefile
+    oe_runmake -C ${TESTDIR} buildtest-TESTS
+}
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    # copy executables
+    find ${B}/${TESTDIR}/unit -type f -executable -exec cp {} ${D}${PTEST_PATH}/tests/ \;
+}
+
+BBCLASSEXTEND = "native nativesdk"