redis-plus-plus: upgrade 1.3.8 -> 1.3.9

0001-CMakeLists.txt-fix-substitution-for-static-libs.patch
refresh for new version

Changelog:
===========
    Fix async interface bug
    More built-in commands support for AsyncRedis
    Fix incorrect hiredis static lib dependency when building with TSL
    Breaking change: make HSET related methods return long long instead of bool

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 26 insertions, 0 deletions

diff --git a/meta-oe/recipes-extended/redis-plus-plus/redis-plus-plus_1.3.9.bb b/meta-oe/recipes-extended/redis-plus-plus/redis-plus-plus_1.3.9.bb
new file mode 100644
index 0000000000..a8a93868e8
--- /dev/null
+++ b/meta-oe/recipes-extended/redis-plus-plus/redis-plus-plus_1.3.9.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "C++ client for Redis based on hiredis"
+HOMEPAGE = "https://github.com/sewenew/redis-plus-plus"
+SECTION = "libs"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+
+DEPENDS += "hiredis"
+
+SRC_URI = "git://github.com/sewenew/redis-plus-plus;branch=master;protocol=https \
+           file://0001-CMakeLists.txt-fix-substitution-for-static-libs.patch"
+SRCREV = "0c4ba0370e46c3d0d443c0368d02195faa791219"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+# if ssl is enabled for redis-plus-plus it must also be enabled for hiredis
+PACKAGECONFIG ??= "ssl"
+PACKAGECONFIG[ssl] = "-DREDIS_PLUS_PLUS_USE_TLS=ON, -DREDIS_PLUS_PLUS_USE_TLS=OFF, openssl"
+PACKAGECONFIG[test] = "-DREDIS_PLUS_PLUS_BUILD_TEST=ON, -DREDIS_PLUS_PLUS_BUILD_TEST=OFF"
+
+do_install:append() {
+    # To remove absolute path in .cmake found by QA warning [buildpaths]
+    sed -i -e 's|${STAGING_LIBDIR}/libcrypto.so|crypto|g' ${D}${datadir}/cmake/redis++/redis++-targets.cmake
+    sed -i -e 's|${STAGING_LIBDIR}/libssl.so|ssl|g' ${D}${datadir}/cmake/redis++/redis++-targets.cmake
+}