flatpak: update 1.15.1 -> 1.15.3

1.15.3
Released: 2023-02-21

Build system:

    Building this version of Flatpak with Meson is recommended. The source release flatpak-1.15.3.tar.xz no longer contains Autotools-generated files, although this version can still be built using Autotools after running ./autogen.sh. Future versions are likely to remove the Autotools build system.

Bug fixes:

    When splitting an upgrade into two steps (download without installing, and then upgrade without allowing further downloads) like GNOME Software does, if an app is marked EOL and superseded by a replacement, don't remove the superseded app in the first step, which would result in the replacement incorrectly not being installed (#5172)
    Fix a crash when --socket=gpg-agent is used (#5095)
    Fix a crash when listing apps if one of them is broken or misconfigured (#5293)
    If an app has invalid syntax in its overrides or metadata, mention the filename in the error message (#5293)
    Unset $GDK_BACKEND for apps, ensuring GTK apps with --socket=fallback-x11 can work (#5303)
    Fix a deprecation warning when compiled with curl >= 7.85 (#5284)
    Translation updates: es, ru (#5266, #5312, #5313)

Internal changes:

    Better diagnostic messages for why runtimes are or are not considered unused (#5237)

1.15.2
Released: 2023-02-06

Bug fixes:

    Never try to export a parent of reserved directories as a --filesystem,
    for example /run, which would prevent the app from starting (#5205, #5207)
    Never try to export a --filesystem below /run/flatpak or /run/host,
    which could similarly prevent the app from starting
    The above change also fixes apps not starting if a --filesystem is a
    symlink to the root directory (#1357)
    Show a warning when the --filesystem exists but cannot be shared with
    the sandbox (#1357, #5035, #5205, #5207)
    Display the intended messages for flatpak repair (#5204)
    Exporting an app to an existing repository on a CIFS filesystem
    now works as intended (#5257)
    Unset $GIO_EXTRA_MODULES for apps, avoiding misbehaviour in some GLib
    apps when set to a path on the host (#5206)
    Unset $XKB_CONFIG_ROOT for apps, avoiding crashes in GTK and Qt apps
    under Wayland when this variable is set to a path not available in the
    sandbox (#5194)
    When using the fish shell, avoid duplicate XDG_DATA_DIRS entries if the
    profile script is sourced more than once (#5198)
    Update included copy of bubblewrap to 0.7.0 for better error messages
    Install SELinux files correctly when building with Meson
    Translation updates: ru, tr (#5256, #5262)

Internal changes:

    Update included copy of libglnx
    flatpak -v now uses the INFO log level, and flatpak -vv uses the
    DEBUG log level in the flatpak log domain. Previously, the extra
    messages that were logged by flatpak -vv were in a separate "flatpak2"
    log domain. G_MESSAGES_DEBUG=flatpak previously had an effect similar to
    flatpak -v, and is now more similar to flatpak -vv.

Signed-off-by: Markus Volk <f_l_k@t-online.de>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 65 insertions, 0 deletions

diff --git a/meta-oe/recipes-extended/flatpak/flatpak_1.15.3.bb b/meta-oe/recipes-extended/flatpak/flatpak_1.15.3.bb
new file mode 100644
index 0000000000..3aafa3f0d2
--- /dev/null
+++ b/meta-oe/recipes-extended/flatpak/flatpak_1.15.3.bb
@@ -0,0 +1,65 @@
+DESCRIPTION = "Desktop containment framework."
+HOMEPAGE = "http://flatpak.org"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+SRC_URI = " \
+    gitsm://github.com/flatpak/flatpak;protocol=https;nobranch=1 \
+    file://0001-flatpak-pc-add-pc_sysrootdir.patch \
+"
+
+SRCREV = "756994b5c433dad9786f9fad736667c4f524aeac"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig gettext systemd gobject-introspection python3native useradd mime features_check
+
+REQUIRED_DISTRO_FEATURES = "polkit"
+
+DEPENDS = " \
+    appstream \
+    bison-native \
+    curl \
+    dconf \
+    fuse3 \
+    gdk-pixbuf \
+    glib-2.0 \
+    gpgme \
+    json-glib \
+    libarchive \
+    libcap \
+    libxslt-native \
+    ostree \
+    polkit \
+    python3-pyparsing-native \
+    xmlto-native \
+"
+
+RDEPENDS:${PN} = " \
+    bubblewrap \
+    ca-certificates \
+    dconf \
+    flatpak-xdg-utils \
+"
+
+GIR_MESON_OPTION = ""
+
+PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,xauth"
+PACKAGECONFIG[xauth] = "-Dxauth=enabled,-Dxauth=disabled,xauth"
+PACKAGECONFIG[seccomp] = "-Dseccomp=enabled,-Dseccomp=disabled,libseccomp"
+
+PACKAGECONFIG ?= " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xauth', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'security', 'seccomp', '', d)} \
+"
+
+FILES:${PN} += "${libdir} ${datadir}"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/polkit-1 polkitd"
+
+do_install:append() {
+    chmod 0700 ${D}/${datadir}/polkit-1/rules.d
+    chown polkitd ${D}/${datadir}/polkit-1/rules.d
+    chgrp root ${D}/${datadir}/polkit-1/rules.d
+}