abseil-cpp: rename recipe to follow the version

We are not on a detached version, there is no reason to not use
the real version in the filename

Signed-off-by: Clément Péron <peron.clem@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 36 insertions, 0 deletions

diff --git a/meta-oe/recipes-devtools/abseil-cpp/abseil-cpp_20230802.1.bb b/meta-oe/recipes-devtools/abseil-cpp/abseil-cpp_20230802.1.bb
new file mode 100644
index 0000000000..1ce6ff3fc7
--- /dev/null
+++ b/meta-oe/recipes-devtools/abseil-cpp/abseil-cpp_20230802.1.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Abseil is a cpp library like STL"
+DESCRIPTION = "Abseil provides pieces missing from the C++ standard. Contains \
+additional useful libraries like algorithm, container, debugging, hash, memory, \
+meta, numeric, strings, synchronization, time, types and utility"
+HOMEPAGE = "https://abseil.io/"
+SECTION = "libs"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=df52c6edb7adc22e533b2bacc3bd3915"
+
+SRCREV = "fb3621f4f897824c0dbe0615fa94543df6192f30"
+BRANCH = "lts_2023_08_02"
+SRC_URI = "git://github.com/abseil/abseil-cpp;branch=${BRANCH};protocol=https \
+           file://0001-absl-always-use-asm-sgidefs.h.patch             \
+           file://0002-Remove-maes-option-from-cross-compilation.patch \
+           file://abseil-ppc-fixes.patch \
+           file://0003-Remove-neon-option-from-cross-compilation.patch \
+           file://0004-Avoid-using-both-Win32Waiter-and-PthreadWaiter-on-Mi.patch \
+          "
+
+S = "${WORKDIR}/git"
+
+ASNEEDED:class-native = ""
+ASNEEDED:class-nativesdk = ""
+
+inherit cmake
+
+EXTRA_OECMAKE = "-DBUILD_SHARED_LIBS=ON \
+                 -DBUILD_TESTING=OFF    \
+                 -DABSL_ENABLE_INSTALL=ON \
+                "
+
+BBCLASSEXTEND = "native nativesdk"
+
+SYSROOT_DIRS:append:class-nativesdk:mingw32 = " ${bindir}"
+
+FILES:${PN}-dev += "${includedir} ${libdir}/cmake ${libdir}/pkgconfig"