Upgrade dbus-cxx to 2.5.2

In addition, allow for other configuration options for dbus-cxx and split
into different packages.

SDK can now also be built with dbus-cxx tools, generally used to generate
C++ interface code from DBus introspection files.  This required adding
cppgenerate in a new recipe for dependency purposes.

Signed-off-by: Khem Raj <raj.khem@gmail.com>

2 files changed, 49 insertions, 25 deletions

diff --git a/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.1.bb b/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.1.bb
deleted file mode 100644
index e89d1327e8..0000000000
--- a/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.1.bb
+++ /dev/null
@@ -1,25 +0,0 @@
-SUMMARY = "D-Bus wrapper in C++ for dbus"
-HOMEPAGE = "https://dbus-cxx.github.io/"
-BUGTRACKER = "https://github.com/libsigcplusplus/libsigcplusplus/issues"
-SECTION = "base"
-LICENSE = "LGPL-3.0-or-later | BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://COPYING;md5=24594f493407a4cd401ce9794e0b9308"
-
-SRC_URI = "git://github.com/dbus-cxx/dbus-cxx.git;branch=master;protocol=https"
-SRCREV = "732a5becb4349e02ffce407a3fd4d75cc3d82421"
-
-DEPENDS = "\
-        dbus \
-        libsigc++-3 \
-"
-
-RDEPENDS:${PN} = "\
-        dbus \
-        libsigc++-3 \
-"
-
-S = "${WORKDIR}/git"
-
-inherit pkgconfig cmake
-
-OECMAKE_FIND_ROOT_PATH_MODE_PROGRAM = "BOTH"
diff --git a/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.2.bb b/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.2.bb
new file mode 100644
index 0000000000..fbe1e34751
--- /dev/null
+++ b/meta-oe/recipes-core/dbus-cxx/dbus-cxx_2.5.2.bb
@@ -0,0 +1,49 @@
+SUMMARY = "D-Bus implementation in C++"
+HOMEPAGE = "https://dbus-cxx.github.io/"
+BUGTRACKER = "https://github.com/dbus-cxx/dbus-cxx/issues"
+SECTION = "base"
+LICENSE = "LGPL-3.0-or-later | BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=24594f493407a4cd401ce9794e0b9308"
+
+SRC_URI = "git://github.com/dbus-cxx/dbus-cxx.git;branch=master;protocol=https"
+SRCREV = "f2637e726207ecfbdaaf02744e1b36e54f929c9d"
+
+DEPENDS = "\
+        dbus \
+        libsigc++-3 \
+"
+
+RDEPENDS:${PN} = "\
+        dbus \
+        libsigc++-3 \
+"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig cmake
+
+OECMAKE_FIND_ROOT_PATH_MODE_PROGRAM = "BOTH"
+EXTRA_OECMAKE = "-DBUILD_TESTING=OFF -DTOOLS_BUNDLED_CPPGENERATE=OFF"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG:class-native ?= "tools"
+PACKAGECONFIG:class-nativesdk ?= "tools"
+
+PACKAGECONFIG[tools] = "-DENABLE_TOOLS=ON,-DENABLE_TOOS=OFF,popt cppgenerate"
+PACKAGECONFIG[glib] = "-DENABLE_GLIB_SUPPORT=ON,-DENABLE_GLIB_SUPPORT=OFF,glib-2.0"
+PACKAGECONFIG[uv] = "-DENABLE_UV_SUPPORT=ON,-DENABLE_UV_SUPPORT=OFF,libuv"
+
+PACKAGES =+ " ${PN}-tools ${PN}-glib ${PN}-uv ${PN}-glib-dev ${PN}-uv-dev "
+FILES:${PN}-tools = "${bindir}/dbus-cxx-xml2cpp ${bindir}/dbus-cxx-introspect"
+FILES:${PN}-glib = "${libdir}/libdbus-cxx-glib.so.* "
+FILES:${PN}-glib-dev = "${includedir}/dbus-cxx-glib-2.0/* \
+  ${libdir}/pkgconfig/dbus-cxx-glib-2.0.pc \
+  ${libdir}/libdbus-cxx-glib.so \
+  "
+FILES:${PN}-uv = "${libdir}/libdbus-cxx-uv.so.* "
+FILES:${PN}-uv-dev = "${includedir}/dbus-cxx-uv-2.0/* \
+  ${libdir}/pkgconfig/dbus-cxx-uv-2.0.pc\
+  ${libdir}/libdbus-cxx-uv.so \
+  "
+
+BBCLASSEXTEND="native nativesdk"