ace: add new recipe

The ADAPTIVE Communication Environment library.
Sources: http://download.dre.vanderbilt.edu/
Homepage: http://www.dre.vanderbilt.edu/~schmidt/ACE-overview.html

Object-oriented (OO) framework that implements many core patterns
for concurrent communication software.

Signed-off-by: Alexander Usyskin <alexander.usyskin@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

2 files changed, 52 insertions, 0 deletions

diff --git a/meta-oe/recipes-connectivity/ace/ace_6.5.8.bb b/meta-oe/recipes-connectivity/ace/ace_6.5.8.bb
new file mode 100644
index 0000000000..24315320e4
--- /dev/null
+++ b/meta-oe/recipes-connectivity/ace/ace_6.5.8.bb
@@ -0,0 +1,40 @@
+SUMMARY = "C++ framework for implementing distributed and networked applications"
+DESCRIPTION = "C++ network programming framework that implements many core \
+patterns for concurrent communication software"
+LICENSE = "ACE-TAO-CIAO"
+HOMEPAGE = "http://www.dre.vanderbilt.edu/~schmidt/ACE.html"
+LIC_FILES_CHKSUM = "file://COPYING;md5=96ef88a5529594698e8ceabdd47df92c"
+
+DEPENDS += "openssl gperf-native"
+
+SRC_URI = "https://github.com/DOCGroup/ACE_TAO/releases/download/ACE%2BTAO-6_5_8/ACE-${PV}.tar.bz2 \
+           file://ace_config.patch \
+          "
+
+SRC_URI[md5sum] = "a6ba6a944612fe0696c90cbb5c3078ee"
+SRC_URI[sha256sum] = "cda2a960dbb9970a907663627711b2e2b14b3484a2859ae936370bcad0b16923"
+
+COMPATIBLE_HOST_libc-musl = "null"
+
+S = "${WORKDIR}/ACE_wrappers"
+B = "${WORKDIR}/ACE_wrappers/ace"
+export ACE_ROOT="${WORKDIR}/ACE_wrappers"
+
+inherit pkgconfig
+
+CXXFLAGS_append = " -fpermissive -Wnodeprecated-declarations"
+
+do_install() {
+    export D="${D}"
+    oe_runmake install
+
+    for i in $(find ${D} -name "*.pc") ; do
+        sed -i -e s:${D}::g \
+               -e s:/${TARGET_SYS}::g \
+                  $i
+    done
+
+    rm -r ${D}/usr/share
+}
+
+UPSTREAM_CHECK_URI = "https://github.com/DOCGroup/ACE_TAO/releases"
diff --git a/meta-oe/recipes-connectivity/ace/files/ace_config.patch b/meta-oe/recipes-connectivity/ace/files/ace_config.patch
new file mode 100644
index 0000000000..207b85ab9c
--- /dev/null
+++ b/meta-oe/recipes-connectivity/ace/files/ace_config.patch
@@ -0,0 +1,12 @@
+diff -ruN ACE_wrappers1/ace/config.h ACE_wrappers/ace/config.h
+--- ACE_wrappers1/ace/config.h  1970-01-01 02:00:00.000000000 +0200
++++ ACE_wrappers/ace/config.h   2019-01-10 13:36:52.698012477 +0200
+@@ -0,0 +1,1 @@
++#include "ace/config-linux.h"
+diff -ruN ACE_wrappers1/include/makeinclude/platform_macros.GNU ACE_wrappers/include/makeinclude/platform_macros.GNU
+--- ACE_wrappers1/include/makeinclude/platform_macros.GNU       1970-01-01 02:00:00.000000000 +0200
++++ ACE_wrappers/include/makeinclude/platform_macros.GNU        2018-10-31 15:11:18.265392460 +0200
+@@ -0,0 +1,3 @@
++INSTALL_PREFIX = $(D)$(exec_prefix)
++INSTALL_LIB = $(base_libdir)
++include $(ACE_ROOT)/include/makeinclude/platform_linux.GNU