summaryrefslogtreecommitdiffstats
path: root/meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb
diff options
context:
space:
mode:
authorPeter Kjellerstedt <pkj@axis.com>2026-01-06 17:56:12 +0100
committerKhem Raj <raj.khem@gmail.com>2026-01-06 23:33:06 -0800
commit254f1285e8332f9c81bf1441f0098b0de4d2d745 (patch)
tree3ee1e3889c9dffd43ace9ca15b2edac33aeb58c0 /meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb
parentbc8066fd7fa213f128c45bcb94e1fd6a4a229cbd (diff)
downloadmeta-openembedded-254f1285e8332f9c81bf1441f0098b0de4d2d745.tar.gz
net-snmp: Update to 5.9.5.2
5.9.5.1: * Only a version numbering fix. 5.9.5.2: * Fix an issue with needing limits.h included. Signed-off-by: Peter Kjellerstedt <peter.kjellerstedt@axis.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
Diffstat (limited to 'meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb')
-rw-r--r--meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb305
1 files changed, 305 insertions, 0 deletions
diff --git a/meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb b/meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb
new file mode 100644
index 0000000000..b7c9607b3b
--- /dev/null
+++ b/meta-networking/recipes-protocols/net-snmp/net-snmp_5.9.5.2.bb
@@ -0,0 +1,305 @@
1SUMMARY = "Various tools relating to the Simple Network Management Protocol"
2HOMEPAGE = "http://www.net-snmp.org/"
3SECTION = "net"
4LICENSE = "BSD-3-Clause & MIT"
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=9d100a395a38584f2ec18a8275261687"
7
8DEPENDS = "openssl"
9DEPENDS:append:class-target = " pciutils"
10
11SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.tar.gz \
12 file://init \
13 file://snmpd.conf \
14 file://snmptrapd.conf \
15 file://snmpd.service \
16 file://snmptrapd.service \
17 file://run-ptest \
18 file://0001-net-snmp-add-knob-whether-nlist.h-are-checked.patch \
19 file://0002-net-snmp-fix-libtool-finish.patch \
20 file://0003-testing-add-the-output-format-for-ptest.patch \
21 file://0004-config_os_headers-Error-Fix.patch \
22 file://0006-get_pid_from_inode-Include-limit.h.patch \
23 file://0007-configure-fix-incorrect-variable.patch \
24 file://0009-net-snmp-fix-for-disable-des.patch \
25 file://0010-net-snmp-Reproducibility-Don-t-check-build-host-for.patch \
26 file://0011-ac_add_search_path.m4-keep-consistent-between-32bit-.patch \
27 file://netsnmp-swinst-crash.patch \
28 "
29SRC_URI[sha256sum] = "16707719f833184a4b72835dac359ae188123b06b5e42817c00790d7dc1384bf"
30
31UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/net-snmp/files/net-snmp/"
32UPSTREAM_CHECK_REGEX = "/net-snmp/(?P<pver>\d+(\.\d+)+)/"
33
34CVE_PRODUCT = "net-snmp:net-snmp"
35
36inherit autotools-brokensep update-rc.d siteinfo systemd pkgconfig perlnative ptest multilib_script multilib_header
37
38EXTRA_OEMAKE = "INSTALL_PREFIX=${D} OTHERLDFLAGS='${LDFLAGS}' HOST_CPPFLAGS='${BUILD_CPPFLAGS}'"
39
40PARALLEL_MAKE = ""
41CCACHE = ""
42CLEANBROKEN = "1"
43
44PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6 systemd', d)} des smux"
45PACKAGECONFIG[des] = "--enable-des, --disable-des"
46PACKAGECONFIG[elfutils] = "--with-elf, --without-elf, elfutils"
47PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6"
48PACKAGECONFIG[libnl] = "--with-nl, --without-nl, libnl"
49PACKAGECONFIG[perl] = "--enable-embedded-perl --with-perl-modules=yes, --disable-embedded-perl --with-perl-modules=no, perl"
50PACKAGECONFIG[smux] = ""
51PACKAGECONFIG[systemd] = "--with-systemd, --without-systemd"
52
53SYSCONTACT_DISTRO ?= "no-contact-set@example.com"
54
55EXTRA_OECONF = " \
56 --enable-shared \
57 --disable-manuals \
58 --with-defaults \
59 --with-install-prefix=${D} \
60 --with-persistent-directory=${localstatedir}/lib/net-snmp \
61 --with-endianness=${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
62 --with-mib-modules='${MIB_MODULES}' \
63 --with-sys-contact='${SYSCONTACT_DISTRO}' \
64"
65
66MIB_MODULES = ""
67MIB_MODULES:append = " ${@bb.utils.filter('PACKAGECONFIG', 'smux', d)}"
68
69CACHED_CONFIGUREVARS = " \
70 ac_cv_header_valgrind_valgrind_h=no \
71 ac_cv_header_valgrind_memcheck_h=no \
72 ac_cv_ETC_MNTTAB=/etc/mtab \
73 lt_cv_shlibpath_overrides_runpath=yes \
74 ac_cv_path_UNAMEPROG=${base_bindir}/uname \
75 ac_cv_path_PSPROG=${base_bindir}/ps \
76 ac_cv_ps_flags="-e" \
77 ac_cv_file__etc_printcap=no \
78 NETSNMP_CONFIGURE_OPTIONS= \
79"
80PERLPROG = "${bindir}/env perl"
81PERLPROG:class-native = "${bindir_native}/env perl"
82PERLPROG:append = "${@bb.utils.contains('PACKAGECONFIG', 'perl', ' -I${WORKDIR}', '', d)}"
83export PERLPROG
84
85HAS_PERL = "${@bb.utils.contains('PACKAGECONFIG', 'perl', '1', '0', d)}"
86
87PTEST_BUILD_HOST_FILES += "net-snmp-config gen-variables"
88
89do_configure:prepend() {
90 sed -i -e "s|I/usr/include|I${STAGING_INCDIR}|g" \
91 "${S}"/configure \
92 "${S}"/configure.d/config_os_libs2
93
94 if [ "${HAS_PERL}" = "1" ]; then
95 # this may need to be changed when package perl has any change.
96 cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl?/*/Config.pm ${WORKDIR}/
97 cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl?/*/*/Config_heavy.pl ${WORKDIR}/
98 sed -e "s@libpth => '/usr/lib.*@libpth => '${STAGING_DIR_TARGET}/${libdir} ${STAGING_DIR_TARGET}/${base_libdir}',@g" \
99 -e "s@privlibexp => '/usr@privlibexp => '${STAGING_DIR_TARGET}/usr@g" \
100 -e "s@scriptdir => '/usr@scriptdir => '${STAGING_DIR_TARGET}/usr@g" \
101 -e "s@sitearchexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
102 -e "s@sitelibexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
103 -e "s@vendorarchexp => '/usr@vendorarchexp => '${STAGING_DIR_TARGET}/usr@g" \
104 -e "s@vendorlibexp => '/usr@vendorlibexp => '${STAGING_DIR_TARGET}/usr@g" \
105 -i ${WORKDIR}/Config.pm
106 fi
107
108}
109
110do_configure:append() {
111 sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=${STAGING_DIR_TARGET}\$\{includedir\}@g" \
112 -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L${STAGING_DIR_TARGET}\$\{libdir\}@g" \
113 -e "s@^NSC_LDFLAGS=\"-L.* @NSC_LDFLAGS=\"-L${STAGING_DIR_TARGET}\$\{libdir\} @g" \
114 -i ${B}/net-snmp-config
115
116 # Make libtool inject -Wl,--as-needed so that it is specified before any lib
117 # dependencies. This is needed due to libtools' reordering of the arguments.
118 [ -z "${ASNEEDED}" ] || sed -e "s@CC -shared@\0 ${ASNEEDED}@" -i ${B}/libtool
119}
120
121do_install:append() {
122 install -d ${D}${sysconfdir}/snmp
123 install -d ${D}${sysconfdir}/init.d
124 install -m 755 ${UNPACKDIR}/init ${D}${sysconfdir}/init.d/snmpd
125 install -m 644 ${UNPACKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
126 install -m 644 ${UNPACKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
127 install -d ${D}${systemd_unitdir}/system
128 install -m 0644 ${UNPACKDIR}/snmpd.service ${D}${systemd_unitdir}/system
129 install -m 0644 ${UNPACKDIR}/snmptrapd.service ${D}${systemd_unitdir}/system
130 sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
131 -i ${D}${bindir}/net-snmp-create-v3-user
132 sed -e 's@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g' \
133 -e 's@[^ ]*-ffile-prefix-map=[^ "]*@@g' \
134 -e 's@[^ ]*-fdebug-prefix-map=[^ "]*@@g' \
135 -e 's@[^ ]*-fmacro-prefix-map=[^ "]*@@g' \
136 -e 's@[^ ]*--sysroot=[^ "]*@@g' \
137 -e 's@[^ ]*--with-libtool-sysroot=[^ "]*@@g' \
138 -e 's@[^ ]*--with-install-prefix=[^ "]*@@g' \
139 -e 's@[^ ]*PKG_CONFIG_PATH=[^ "]*@@g' \
140 -e 's@[^ ]*PKG_CONFIG_LIBDIR=[^ "]*@@g' \
141 -i ${D}${bindir}/net-snmp-config
142
143 sed -e 's@[^ ]*-ffile-prefix-map=[^ "]*@@g' \
144 -e 's@[^ ]*-fdebug-prefix-map=[^ "]*@@g' \
145 -e 's@[^ ]*-fmacro-prefix-map=[^ "]*@@g' \
146 -i ${D}${libdir}/pkgconfig/netsnmp*.pc
147
148 # ${STAGING_DIR_HOST} is empty for native builds, and the sed command below
149 # will result in errors if run for native.
150 if [ "${STAGING_DIR_HOST}" ]; then
151 sed -e 's@${STAGING_DIR_HOST}@@g' \
152 -i ${D}${bindir}/net-snmp-config ${D}${libdir}/pkgconfig/netsnmp*.pc
153 fi
154
155 sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=\$\{includedir\}@g" \
156 -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L\$\{libdir\}@g" \
157 -e "s@^NSC_LDFLAGS=\"-L.* @NSC_LDFLAGS=\"-L\$\{libdir\} @g" \
158 -i ${D}${bindir}/net-snmp-config
159
160 sed -i -e 's:${HOSTTOOLS_DIR}/::g' ${D}${bindir}/net-snmp-create-v3-user
161
162 oe_multilib_header net-snmp/net-snmp-config.h
163
164 if [ "${HAS_PERL}" = "1" ]; then
165 find ${D}${libdir}/ -type f -name "perllocal.pod" | xargs rm -f
166 fi
167}
168
169do_install_ptest() {
170 install -d ${D}${PTEST_PATH}
171 for i in ${S}/dist ${S}/include ${B}/include ${S}/mibs ${S}/configure \
172 ${B}/net-snmp-config ${S}/testing; do
173 if [ -e "$i" ]; then
174 cp -R --no-dereference --preserve=mode,links -v "$i" ${D}${PTEST_PATH}
175 fi
176 done
177 echo `autoconf -V|awk '/autoconf/{print $NF}'` > ${D}${PTEST_PATH}/dist/autoconf-version
178
179 rmdlist="${D}${PTEST_PATH}/dist/net-snmp-solaris-build"
180 for i in $rmdlist; do
181 if [ -d "$i" ]; then
182 rm -rf "$i"
183 fi
184 done
185}
186
187SYSROOT_PREPROCESS_FUNCS += "net_snmp_sysroot_preprocess"
188SNMP_DBGDIR = "${TARGET_DBGSRC_DIR}"
189
190net_snmp_sysroot_preprocess () {
191 if [ -e ${D}${bindir}/net-snmp-config ]; then
192 install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
193 install -m 755 ${D}${bindir}/net-snmp-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
194 sed -e "s@-I/usr/include@-I${STAGING_INCDIR}@g" \
195 -e "s@^prefix=.*@prefix=${STAGING_DIR_HOST}${prefix}@g" \
196 -e "s@^exec_prefix=.*@exec_prefix=${STAGING_EXECPREFIXDIR}@g" \
197 -e "s@^includedir=.*@includedir=${STAGING_INCDIR}@g" \
198 -e "s@^libdir=.*@libdir=${STAGING_LIBDIR}@g" \
199 -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=${S}@g" \
200 -e "s@-ffile-prefix-map=${SNMP_DBGDIR}@-ffile-prefix-map=${WORKDIR}=${SNMP_DBGDIR}@g" \
201 -e "s@-fdebug-prefix-map=${SNMP_DBGDIR}@-fdebug-prefix-map=${WORKDIR}=${SNMP_DBGDIR}@g" \
202 -e "s@-fdebug-prefix-map= -fdebug-prefix-map=@-fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
203 -fdebug-prefix-map=${STAGING_DIR_HOST}=@g" \
204 -e "s@--sysroot=@--sysroot=${STAGING_DIR_HOST}@g" \
205 -e "s@--with-libtool-sysroot=@--with-libtool-sysroot=${STAGING_DIR_HOST}@g" \
206 -e "s@--with-install-prefix=@--with-install-prefix=${D}@g" \
207 -i ${SYSROOT_DESTDIR}${bindir_crossscripts}/net-snmp-config
208 fi
209}
210
211PACKAGES += "${PN}-libs ${PN}-mibs ${PN}-server ${PN}-client \
212 ${PN}-server-snmpd ${PN}-server-snmptrapd \
213 ${PN}-lib-netsnmp ${PN}-lib-agent ${PN}-lib-helpers \
214 ${PN}-lib-mibs ${PN}-lib-trapd"
215
216# perl module
217PACKAGES += "${@bb.utils.contains('PACKAGECONFIG', 'perl', '${PN}-perl-modules', '', d)}"
218
219ALLOW_EMPTY:${PN} = "1"
220ALLOW_EMPTY:${PN}-server = "1"
221ALLOW_EMPTY:${PN}-libs = "1"
222
223FILES:${PN}-perl-modules = "${libdir}/perl?/*"
224RDEPENDS:${PN}-perl-modules = "perl"
225
226FILES:${PN}-libs = ""
227FILES:${PN}-mibs = "${datadir}/snmp/mibs"
228FILES:${PN}-server-snmpd = "${sbindir}/snmpd \
229 ${sysconfdir}/snmp/snmpd.conf \
230 ${sysconfdir}/init.d \
231 ${systemd_unitdir}/system/snmpd.service \
232"
233
234FILES:${PN}-server-snmptrapd = "${sbindir}/snmptrapd \
235 ${sysconfdir}/snmp/snmptrapd.conf \
236 ${systemd_unitdir}/system/snmptrapd.service \
237"
238
239FILES:${PN}-lib-netsnmp = "${libdir}/libnetsnmp${SOLIBS}"
240FILES:${PN}-lib-agent = "${libdir}/libnetsnmpagent${SOLIBS}"
241FILES:${PN}-lib-helpers = "${libdir}/libnetsnmphelpers${SOLIBS}"
242FILES:${PN}-lib-mibs = "${libdir}/libnetsnmpmibs${SOLIBS}"
243FILES:${PN}-lib-trapd = "${libdir}/libnetsnmptrapd${SOLIBS}"
244
245FILES:${PN} = ""
246FILES:${PN}-client = "${bindir}/* ${datadir}/snmp/"
247FILES:${PN}-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
248FILES:${PN}-dev += "${bindir}/mib2c \
249 ${bindir}/mib2c-update \
250 ${bindir}/net-snmp-config \
251 ${bindir}/net-snmp-create-v3-user \
252"
253
254CONFFILES:${PN}-server-snmpd = "${sysconfdir}/snmp/snmpd.conf"
255CONFFILES:${PN}-server-snmptrapd = "${sysconfdir}/snmp/snmptrapd.conf"
256
257INITSCRIPT_PACKAGES = "${PN}-server-snmpd"
258INITSCRIPT_NAME:${PN}-server-snmpd = "snmpd"
259INITSCRIPT_PARAMS:${PN}-server-snmpd = "start 90 2 3 4 5 . stop 60 0 1 6 ."
260
261SYSTEMD_PACKAGES = "${PN}-server-snmpd \
262 ${PN}-server-snmptrapd"
263
264SYSTEMD_SERVICE:${PN}-server-snmpd = "snmpd.service"
265SYSTEMD_SERVICE:${PN}-server-snmptrapd = "snmptrapd.service"
266
267RDEPENDS:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'perl', 'net-snmp-perl-modules', '', d)}"
268RDEPENDS:${PN} += "net-snmp-client"
269RDEPENDS:${PN}-server-snmpd += "net-snmp-mibs"
270RDEPENDS:${PN}-server-snmptrapd += "net-snmp-server-snmpd ${PN}-lib-trapd"
271RDEPENDS:${PN}-server += "net-snmp-server-snmpd net-snmp-server-snmptrapd"
272RDEPENDS:${PN}-client += "net-snmp-mibs net-snmp-libs"
273RDEPENDS:${PN}-libs += "${PN}-lib-netsnmp \
274 ${PN}-lib-agent \
275 ${PN}-lib-helpers \
276 ${PN}-lib-mibs \
277"
278RDEPENDS:${PN}-libs:append:class-target = " libpci"
279RDEPENDS:${PN}-ptest += "${PN}-server-snmpd \
280 ${PN}-server-snmptrapd \
281 net-tools \
282 perl \
283 perl-module-test \
284 perl-module-socket \
285 perl-module-file-basename \
286 perl-module-getopt-long \
287 perl-module-file-temp \
288 perl-module-data-dumper \
289"
290RDEPENDS:${PN}-dev = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
291RRECOMMENDS:${PN}-dbg = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
292
293RPROVIDES:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
294RREPLACES:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
295RCONFLICTS:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
296
297RPROVIDES:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
298RREPLACES:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
299RCONFLICTS:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
300
301LEAD_SONAME = "libnetsnmp.so"
302
303MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/net-snmp-config"
304
305BBCLASSEXTEND = "native"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-02-27 05:36:09 +0000