gjs: upgrade 1.84.1 -> 1.84.2

Version 1.84.2
--------------

- Closed bugs and merge requests:
  * GtkNotebook.pages GListModel is inaccessible from GJS [#686, !992, Philip
    Chimento]

Signed-off-by: Liu Yiding <liuyd.fnst@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta-gnome/recipes-gnome/gjs/gjs_1.84.2.bb b/meta-gnome/recipes-gnome/gjs/gjs_1.84.2.bb
new file mode 100644
index 0000000000..c41fa6e93a
--- /dev/null
+++ b/meta-gnome/recipes-gnome/gjs/gjs_1.84.2.bb
@@ -0,0 +1,45 @@
+SUMMARY = "Javascript bindings for GNOME"
+LICENSE = "MIT & LGPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8dcea832f6acf45d856abfeb2d51ec48"
+
+
+DEPENDS = "mozjs-128 cairo"
+
+inherit gnomebase gobject-introspection gettext features_check upstream-version-is-even pkgconfig multilib_script
+
+SRC_URI[archive.sha256sum] = "35142edf345705636300291ec3a7d583f14969ff3fae0ff30f4a95b1e6740166"
+SRC_URI += " \
+    file://0001-Support-cross-builds-a-bit-better.patch \
+    file://0002-meson.build-Do-not-add-dir-installed-tests-when-inst.patch \
+"
+
+# gobject-introspection is mandatory and cannot be configured
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+GIR_MESON_OPTION = ""
+
+EXTRA_OEMESON = " \
+    -Dinstalled_tests=false \
+    -Dskip_dbus_tests=true \
+    -Dskip_gtk_tests=true \
+"
+
+LDFLAGS:append:mipsarch = " -latomic"
+LDFLAGS:append:powerpc = " -latomic"
+LDFLAGS:append:powerpc64 = " -latomic"
+LDFLAGS:append:riscv32 = " -latomic"
+
+FILES:${PN} += "${datadir}/gjs-1.0/lsan"
+
+PACKAGES =+ "${PN}-valgrind"
+FILES:${PN}-valgrind = "${datadir}/gjs-1.0/valgrind"
+RDEPENDS:${PN}-valgrind += "valgrind"
+
+# Valgrind not yet available on rv32/rv64
+RDEPENDS:${PN}-valgrind:remove:riscv32 = "valgrind"
+RDEPENDS:${PN}-valgrind:remove:riscv64 = "valgrind"
+
+MULTILIB_SCRIPTS:append = "${PN}:${libexecdir}/installed-tests/gjs/GIMarshallingTests-1.0.typelib \
+                    ${PN}:${libexecdir}/installed-tests/gjs/Regress-1.0.typelib \
+                    ${PN}:${libexecdir}/installed-tests/gjs/Utility-1.0.typelib \
+                    ${PN}:${libexecdir}/installed-tests/gjs/WarnLib-1.0.typelib \
+                    "