2 files changed, 72 insertions, 0 deletions

diff --git a/recipes-core/dnn/files/run-ptest b/recipes-core/dnn/files/run-ptest
new file mode 100755
index 00000000..82d4df58
--- /dev/null
+++ b/recipes-core/dnn/files/run-ptest
@@ -0,0 +1,15 @@
+#!/bin/sh
+
+cd tests
+./api-c
+if [ $? -eq 0 ]; then
+  echo 'PASS: api-c'
+else
+  echo 'FAIL: api-c'
+fi
+./test_c_symbols-c
+if [ $? -eq 0 ]; then
+  echo 'PASS: test_c_symbols-c'
+else
+  echo 'FAIL: test_c_symbols-c'
+fi
diff --git a/recipes-core/dnn/onednn_3.5.3.bb b/recipes-core/dnn/onednn_3.5.3.bb
new file mode 100644
index 00000000..531f80c6
--- /dev/null
+++ b/recipes-core/dnn/onednn_3.5.3.bb
@@ -0,0 +1,57 @@
+HOMEPAGE = "https://www.oneapi.com"
+SUMMARY  = "Deep Neural Network Library"
+DESCRIPTION = "This software is a user mode library that accelerates\
+deep-learning applications and frameworks on Intel architecture."
+LICENSE  = "Apache-2.0 & BSD-3-Clause & BSL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b64000f6e7d52516017622a37a94ce9 \
+                    file://tests/gtests/gtest/LICENSE;md5=cbbd27594afd089daa160d3a16dd515a \
+                    file://src/cpu/x64/xbyak/COPYRIGHT;md5=3b9bf048d063d54cdb28964db558bcc7 \
+                    file://src/common/ittnotify/LICENSE.BSD;md5=e671ff178b24a95a382ba670503c66fb \
+                    "
+SECTION = "lib"
+
+inherit pkgconfig cmake ptest
+
+DNN_BRANCH = "rls-v${@'.'.join(d.getVar('PV').split('.')[0:2])}"
+
+SRCREV = "66f0cb9eb66affd2da3bf5f8d897376f04aae6af"
+SRC_URI = "git://github.com/oneapi-src/oneDNN.git;branch=${DNN_BRANCH};protocol=https \
+           file://run-ptest \
+           "
+
+UPSTREAM_CHECK_GITTAGREGEX = "^v(?P<pver>(\d+(\.\d+)+))$"
+
+CVE_PRODUCT = "intel:math_kernel_library"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:libc-musl = 'null'
+
+EXTRA_OECMAKE += " \
+                   -DDNNL_LIBRARY_TYPE=SHARED \
+                   -DDNNL_BUILD_EXAMPLES=ON \
+                   -DDNNL_BUILD_TESTS=ON \
+                   -DDNNL_CPU_RUNTIME=OMP \
+                   -DDNNL_ARCH_OPT_FLAGS="" \
+                   -DCMAKE_SKIP_RPATH=ON \
+                   -DONEDNN_BUILD_GRAPH=OFF \
+                   -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
+                   "
+
+PACKAGECONFIG ??= "gpu"
+PACKAGECONFIG[gpu] = "-DDNNL_GPU_RUNTIME=OCL, , opencl-headers virtual/opencl-icd, intel-compute-runtime"
+
+do_install:append () {
+    install -d ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+    install -m 0755 ${B}/tests/benchdnn/benchdnn ${D}${bindir}/mkl-dnn/tests/benchdnn
+    cp -r ${B}/tests/benchdnn/inputs/* ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+}
+
+do_install_ptest () {
+    install -d ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/api-c ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/test_c_symbols-c ${D}${PTEST_PATH}/tests
+}
+
+PACKAGES =+ "${PN}-test"
+
+FILES:${PN}-test = "${bindir}/mkl-dnn/*"