intel-media-driver: upgrade 23.4.3 -> 24.1.5

Drops list of patches already merged:
 - 0004-Add-device-ID-for-ARL.patch
 - 0005-Add-XR24-support-to-DMABuf.patch
 - 0006-add-INTEL-MEDIA-ALLOC-refineE-to-specify-the-memory-.patch
 - 0007-Skip-report-keys.patch
 - 0008-Limit-INTEL-MEDIA-ALLOC-MODE-to-MTL-and-ARL-only.patch
 - 0009-Skip-cache-bucket-realloc-for-default-mode-0.patch
 - 0010-Fix-failed-4k-video-wall-test-case-and-color-corrupt.patch
 - 0011-Disable-422H-format-output.patch
 - 0012-Decode-Fix-AVC-decode-SFC-4K-hang-issue.patch

Backport a patch to fix build errors:

| error: comparing the result of pointer addition ‘(avcDirectmodeParams._MHW_VDBOX_AVC_DIRECTMODE_PARAMS::presAvcDmvBuffers + ((((sizetype)n) + 1) * 328))’ and NULL [-Werror=address]
| 592 | if (&avcDirectmodeParams.presAvcDmvBuffers[n+1] != nullptr)
| | ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^~~~~~~~~~

Signed-off-by: Lim Siew Hoon <siew.hoon.lim@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 53 insertions, 0 deletions

diff --git a/recipes-multimedia/libva/intel-media-driver_24.1.5.bb b/recipes-multimedia/libva/intel-media-driver_24.1.5.bb
new file mode 100644
index 00000000..79f9887d
--- /dev/null
+++ b/recipes-multimedia/libva/intel-media-driver_24.1.5.bb
@@ -0,0 +1,53 @@
+SUMMARY = "VA driver for Intel Gen based graphics hardware"
+DESCRIPTION = "Intel Media Driver for VAAPI is a new VA-API (Video Acceleration API) \
+user mode driver supporting hardware accelerated decoding, encoding, \
+and video post processing for GEN based graphics hardware."
+
+HOMEPAGE = "https://github.com/intel/media-driver"
+BUGTRACKER = "https://github.com/intel/media-driver/issues"
+
+LICENSE = "MIT & BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=6aab5363823095ce682b155fef0231f0 \
+                    file://media_driver/media_libvpx.LICENSE;md5=d5b04755015be901744a78cc30d390d4 \
+                    "
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+inherit features_check
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+DEPENDS += "libva gmmlib"
+
+SRC_URI = "git://github.com/intel/media-driver.git;protocol=https;nobranch=1 \
+           file://0001-Disable-vp9-padding-on-mtl.patch \
+           file://0002-Force-ARGB-surface-to-tile4-for-ACM.patch \
+           file://8aa866dc650e6b0e0b7425bafc7b1039232c377a.patch \
+          "
+
+SRCREV = "8068c2e119ba16c017e5a5f443fac5a55edbee65"
+S = "${WORKDIR}/git"
+
+COMPATIBLE_HOST:x86-x32 = "null"
+
+UPSTREAM_CHECK_GITTAGREGEX = "^intel-media-(?P<pver>(?!600\..*)\d+(\.\d+)+)$"
+
+inherit cmake pkgconfig
+
+MEDIA_DRIVER_ARCH:x86    = "32"
+MEDIA_DRIVER_ARCH:x86-64 = "64"
+
+EXTRA_OECMAKE += " \
+                   -DMEDIA_RUN_TEST_SUITE=OFF \
+                   -DARCH=${MEDIA_DRIVER_ARCH} \
+                   -DMEDIA_BUILD_FATAL_WARNINGS=OFF \
+                  "
+
+CXXFLAGS:append:x86 = " -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE"
+
+do_configure:prepend:toolchain-clang() {
+    sed -i -e '/-fno-tree-pre/d' ${S}/media_driver/cmake/linux/media_compile_flags_linux.cmake
+}
+
+FILES:${PN} += " \
+                 ${libdir}/dri/ \
+                 "