intel-microcode: upgrade 20251111 -> 20260210

Update for functional issues. Refer to processor specification updates for details.

Updated Platforms:
  - Core Gen12
  - Core i3-N305/N300, N50/N97/N100/N200, Atom x7211E/x7213E/x7425E
  - Core Ultra Processor (Series 2) (ARL-H, ARL-S/HX (8P), ARL-U)
  - Atom C1100
  - Xeon Scalable Gen5
  - Xeon 6900/6700/6500 Series Processors with P-Cores
  - Xeon 6700P-B/6500P-B Series SoC with P-Cores
  - Xeon 6700/6500-Series Processors with P-Cores
  - Xeon D-17xx, D-27xx
  - Core Gen10 Mobile
  - Xeon Scalable Gen3
  - Core Ultra Processor
  - Core Gen11
  - Core Gen13/Gen14 (RPL-E/HX/S, RPL-S, RPL-HX/S)
  - Core Gen13 (RPL-H/P/PX 6+8, RPL-U 2+8)
  - Xeon Max
  - Xeon Scalable Gen4
  - Core Gen11 Mobile (TGL, TGL-H, TGL-R)
  - Core i3-N305/N300, N50/N97/N100/N200, Atom x7211E/x7213E/x7425E

Release notes:
https://github.com/intel/Intel-Linux-Processor-Microcode-Data-Files/releases/tag/microcode-20260210-rev1

Signed-off-by: Adam Duskett <adam.duskett@amarulasolutions.com>
Signed-off-by: Yogesh Tyagi <yogesh.tyagi@intel.com>

1 files changed, 62 insertions, 0 deletions

diff --git a/recipes-core/microcode/intel-microcode_20260210.bb b/recipes-core/microcode/intel-microcode_20260210.bb
new file mode 100644
index 00000000..92cb7ef8
--- /dev/null
+++ b/recipes-core/microcode/intel-microcode_20260210.bb
@@ -0,0 +1,62 @@
+SUMMARY = "Intel Processor Microcode Datafile for Linux"
+HOMEPAGE = "http://www.intel.com/"
+DESCRIPTION = "The microcode data file contains the latest microcode\
+ definitions for all Intel processors. Intel releases microcode updates\
+ to correct processor behavior as documented in the respective processor\
+ specification updates. While the regular approach to getting this microcode\
+ update is via a BIOS upgrade, Intel realizes that this can be an\
+ administrative hassle. The Linux operating system and VMware ESX\
+ products have a mechanism to update the microcode after booting.\
+ For example, this file will be used by the operating system mechanism\
+ if the file is placed in the /etc/firmware directory of the Linux system."
+
+LICENSE = "Intel-Microcode-License"
+LIC_FILES_CHKSUM = "file://license;md5=d8405101ec6e90c1d84b082b0c40c721"
+
+SRC_URI = "git://github.com/intel/Intel-Linux-Processor-Microcode-Data-Files.git;protocol=https;branch=main \
+           "
+
+SRCREV = "439ddde999b07b28877a60e874f753e72ec2cd59"
+
+DEPENDS = "iucode-tool-native"
+
+COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+
+# Use any of the iucode_tool parameters to filter specific microcodes from the data file
+# For further information, check the iucode-tool's manpage : http://manned.org/iucode-tool
+UCODE_FILTER_PARAMETERS ?= ""
+
+do_compile() {
+        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+                ${UCODE_FILTER_PARAMETERS} \
+                --overwrite \
+                --write-earlyfw=${WORKDIR}/microcode_${PV}.cpio \
+                ${S}/intel-ucode/* ${S}/intel-ucode-with-caveats/*
+}
+
+do_install() {
+        install -d ${D}${nonarch_base_libdir}/firmware/intel-ucode/
+        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+        ${UCODE_FILTER_PARAMETERS} \
+        --write-firmware=${D}${nonarch_base_libdir}/firmware/intel-ucode \
+        ${S}/intel-ucode/* ${S}/intel-ucode-with-caveats/*
+}
+
+do_deploy() {
+        install -d ${DEPLOYDIR}
+        install ${WORKDIR}/microcode_${PV}.cpio ${DEPLOYDIR}/
+        cd ${DEPLOYDIR}
+        rm -f microcode.cpio
+        ln -sf microcode_${PV}.cpio microcode.cpio
+}
+
+addtask deploy before do_build after do_compile
+
+PACKAGES = "${PN}"
+
+FILES:${PN} = "${nonarch_base_libdir}"
+
+UPSTREAM_CHECK_GITTAGREGEX = "^microcode-(?P<pver>(\d+)[a-z]*)$"