thermald: upgrade 2.2 -> 2.4.2

Fixed new dependencies failure.

| automake: error: cannot open < gtk-doc.make: No such file or directory
| autoreconf: error: automake failed with exit status: 1

| checking for upower-glib... no
| configure: error: Package requirements (upower-glib) were not met:
|
| No package 'upower-glib' found

| checking for libevdev... no
| configure: error: Package requirements (libevdev) were not met:
|
| No package 'libevdev' found

upower library recipe comes from meta-openembedded/meta-oe layer, so
moved recipe to dyanmic-layer.

Dropped patch, which is not requried anymore.

Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 42 insertions, 0 deletions

diff --git a/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.4.2.bb b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.4.2.bb
new file mode 100644
index 00000000..c8482286
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.4.2.bb
@@ -0,0 +1,42 @@
+SUMMARY = "Linux thermal daemon"
+
+DESCRIPTION = "Thermal Daemon is a Linux daemon used to prevent the \
+overheating of platforms. This daemon monitors temperature and applies \
+compensation using available cooling methods."
+
+HOMEPAGE = "https://github.com/01org/thermal_daemon"
+
+DEPENDS = "dbus dbus-glib dbus-glib-native libxml2 glib-2.0 glib-2.0-native upower libevdev"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea8831610e926e2e469075b52bf08848"
+
+SRC_URI = "git://github.com/intel/thermal_daemon/ \
+           "
+
+SRCREV = "86d6634b7e648ad5a3304e8dcf4eee613fa07fac"
+S = "${WORKDIR}/git"
+
+inherit pkgconfig autotools systemd gtk-doc
+
+# gtkdocsize runs before autotools do_configure and it copies gtk-doc.m4 and fails
+# to copy becuase there is no m4 dir yet.
+do_configure_prepend () {
+        mkdir -p ${S}/m4
+}
+
+EXTRA_OECONF = " \
+                 --with-systemdsystemunitdir=${systemd_system_unitdir} \
+                 "
+
+FILES_${PN} += "${datadir}/dbus-1/system-services/*.service"
+
+SYSTEMD_SERVICE_${PN} = "thermald.service"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+CONFFILES_${PN} = " \
+                   ${sysconfdir}/thermald/thermal-conf.xml \
+                   ${sysconfdir}/thermald/thermal-cpu-cdev-order.xml \
+                  "
+
+UPSTREAM_CHECK_URI = "https://github.com/01org/thermal_daemon/releases"