blob: 320ba3017a85e4bb295fd18749cfb03879bcca1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright (C) 2016 Freescale Semiconductor
# Copyright 2017-2025 NXP
# Released under the MIT license (see COPYING.MIT for the terms)
SUMMARY = "i.MX DPU G2D library"
DESCRIPTION = "G2D library using i.MX DPU"
HOMEPAGE = "https://www.nxp.com/"
SECTION = "graphics"
LICENSE = "Proprietary"
LIC_FILES_CHKSUM = "file://COPYING;md5=bc649096ad3928ec06a8713b8d787eac"
DEPENDS = "libdrm ${LIBGAL_IMX}"
LIBGAL_IMX = ""
LIBGAL_IMX:imxviv = "libgal-imx"
PROVIDES += "virtual/libg2d"
SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;fsl-eula=true;name=${IMX_SRC_URI_NAME}"
IMX_BIN_NAME = "${BPN}-${IMX_SRC_URI_NAME}-${PV}-${IMX_SRCREV_ABBREV}"
IMX_SRCREV_ABBREV = "f126d54"
IMX_SRC_URI_NAME = "v1"
SRC_URI[v1.sha256sum] = "344116d525d98b4ec1fd9713c611c47323778245939e0a4770ad847f8965644b"
IMX_SRCREV_ABBREV:imxmali = "f126d54"
IMX_SRC_URI_NAME:imxmali = "v2"
SRC_URI[v2.sha256sum] = "baa9a48a954bcdcf7eb9a14022cf6c9daa27281c642bec2ba3c24ca428c5b952"
S = "${UNPACKDIR}/${IMX_BIN_NAME}"
inherit fsl-eula-unpack
do_install () {
install -d ${D}${libdir}
install -d ${D}${includedir}
cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
}
PACKAGE_ARCH = "${MACHINE_SOCARCH}"
INSANE_SKIP:append:libc-musl = " file-rdeps"
RDEPENDS:${PN}:append:libc-musl = " gcompat"
# The packaged binaries have been stripped of debug info, so disable
# operations accordingly.
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
INHIBIT_PACKAGE_STRIP = "1"
INHIBIT_SYSROOT_STRIP = "1"
COMPATIBLE_MACHINE = "(imxdpu)"
|
