blob: f3687352d3899e3bdfba11236eac5d4b0655e537 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
SUMMARY = "The Linux driver stack for Arm(R) Ethos(TM)-U NPU"
DESCRIPTION = "The Linux driver stack for Arm(R) Ethos(TM)-U provides \
an example of how a rich operating system like Linux can dispatch \
inferences to an Arm Cortex(R)-M subsystem, consisting of an Arm \
Cortex-M of choice and an Arm Ethos-U NPU."
HOMEPAGE = "https://github.com/nxp-imx/ethos-u-driver-stack-imx"
SECTION = "libs"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=e3fc50a88d0a364313df4b21ef20c29e"
DEPENDS = "flatbuffers python3-pybind11 python3-pybind11-native"
SRC_URI = "${ETHOS_U_SRC};branch=${SRCBRANCH} \
file://0001-ethosu.hpp-Fix-gcc15-build-issues.patch \
"
ETHOS_U_SRC ?= "git://github.com/nxp-imx/ethos-u-driver-stack-imx.git;protocol=https"
SRCBRANCH = "lf-6.18.37_2.1.0"
SRCREV = "9d50bada85fe232af1a4a52812addaba974713cd"
inherit cmake setuptools3
# CMakeLists.txt still asks for CMake 3.0.2, and CMake 4 no longer accepts a
# minimum below 3.5.
EXTRA_OECMAKE += "-DCMAKE_POLICY_VERSION_MINIMUM=3.5"
SETUPTOOLS_BUILD_ARGS = "build_ext --library-dirs ${B}/driver_library"
do_configure() {
cmake_do_configure
}
# The cmake_do_* and setuptools3_do_* helpers are all shell functions, so
# these tasks are shell and must not carry a python prefix.
# nooelint: oelint.task.pythonprefix
do_compile () {
cmake_do_compile
setuptools3_do_compile
}
# Shell task for the same reason as do_compile above.
# nooelint: oelint.task.pythonprefix
do_install () {
cmake_do_install
setuptools3_do_install
}
RDEPENDS:${PN} = "flatbuffers python3-numpy python3-pillow"
COMPATIBLE_MACHINE = "(mx93-nxp-bsp)"
|
