12 files changed, 382 insertions, 0 deletions

diff --git a/recipes-graphics/devil/devil_1.8.0.bb b/recipes-graphics/devil/devil_1.8.0.bb
new file mode 100644
index 000000000..dcbdf3ac1
--- /dev/null
+++ b/recipes-graphics/devil/devil_1.8.0.bb
@@ -0,0 +1,21 @@
+DESCRIPTION = "A full featured cross-platform image library"
+SECTION = "libs"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/LGPL-2.1-only;md5=1a6d268fd218675ffea8be556788b780"
+PR = "r0"
+
+DEPENDS = "libpng jpeg tiff xz"
+
+SRC_URI = "http://sourceforge.net/projects/openil/files/DevIL/${PV}/DevIL-${PV}.zip"
+SRC_URI[sha256sum] = "451337f392c65bfb83698a781370534dc63d7bafca21e9b37178df0518f7e895"
+
+S = "${UNPACKDIR}/DevIL/DevIL"
+
+inherit cmake
+
+TARGET_CFLAGS += "-Dpng_set_gray_1_2_4_to_8=png_set_expand_gray_1_2_4_to_8"
+
+SOLIBS = ".so"
+FILES_SOLIBSDEV = ""
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-graphics/gli/gli_0.8.4.0.bb b/recipes-graphics/gli/gli_0.8.4.0.bb
new file mode 100644
index 000000000..14d6a75ed
--- /dev/null
+++ b/recipes-graphics/gli/gli_0.8.4.0.bb
@@ -0,0 +1,22 @@
+SUMMARY = "OpenGL Image Library"
+DESCRIPTION = "OpenGL Image (GLI) is a header only C++ \
+image library for graphics software."
+HOMEPAGE = "http://gli.g-truc.net"
+BUGTRACKER = "https://github.com/g-truc/gli/issues"
+
+SECTION = "libs"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://readme.md;beginline=19;endline=20;md5=ab03b667ee630c1abb1add70365a50fb"
+
+SRC_URI = " \
+    git://github.com/g-truc/gli;protocol=https;branch=master \
+"
+SRCREV = "0c171ee87fcfe35a7e0e0445adef06f92e0b6a91"
+
+inherit cmake
+
+# This is a header-only library, so the main package will be empty.
+ALLOW_EMPTY:${PN} = "1"
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-graphics/glm/glm_%.bbappend b/recipes-graphics/glm/glm_%.bbappend
new file mode 100644
index 000000000..88a16cb9d
--- /dev/null
+++ b/recipes-graphics/glm/glm_%.bbappend
@@ -0,0 +1,2 @@
+# This is a header-only library, so the main package will be empty.
+ALLOW_EMPTY:${PN} = "1"
diff --git a/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk-src.inc b/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk-src.inc
new file mode 100644
index 000000000..3c927b587
--- /dev/null
+++ b/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk-src.inc
@@ -0,0 +1,4 @@
+SRC_URI = "${GPU_SDK_SRC};branch=${GPU_SDK_SRC_BRANCH}"
+GPU_SDK_SRC ?= "git://github.com/nxp-imx/gtec-demo-framework.git;protocol=https"
+GPU_SDK_SRC_BRANCH ?= "master"
+SRCREV = "35bbd45ed6eac169a778bd154283771b9bf39be7"
diff --git a/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk_6.1.1.bb b/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk_6.1.1.bb
new file mode 100644
index 000000000..e1510baf3
--- /dev/null
+++ b/recipes-graphics/imx-gpu-sdk/imx-gpu-sdk_6.1.1.bb
@@ -0,0 +1,145 @@
+SUMMARY = "i.MX GPU SDK Samples"
+DESCRIPTION = "Set of sample applications for i.MX GPU"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://License.md;md5=9d58a2573275ce8c35d79576835dbeb8"
+
+DEPENDS_BACKEND = \
+    "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', ' libxdg-shell wayland', \
+        bb.utils.contains('DISTRO_FEATURES',     'x11',               ' xrandr', \
+                                                                             '', d), d)}"
+DEPENDS_MX8       = ""
+DEPENDS_MX8:mx8-nxp-bsp   = " \
+    glslang-native \
+    opencv \
+    rapidopencl \
+    rapidopenvx \
+    rapidvulkan \
+    vulkan-headers \
+    vulkan-loader \
+"
+DEPENDS_MX8:mx8mm-nxp-bsp = " \
+    opencv \
+"
+DEPENDS = " \
+    assimp \
+    cmake-native \
+    devil \
+    fmt \
+    gli \
+    glm \
+    gstreamer1.0 \
+    gstreamer1.0-plugins-base \
+    gtest \
+    half \
+    ninja-native \
+    nlohmann-json \
+    rapidjson \
+    stb \
+    zlib \
+    ${DEPENDS_BACKEND} \
+    ${DEPENDS_MX8} \
+"
+DEPENDS:append:imxgpu2d = " virtual/libg2d virtual/libopenvg"
+DEPENDS:append:imxgpu3d = " virtual/libgles2"
+
+require imx-gpu-sdk-src.inc
+
+
+WINDOW_SYSTEM = \
+    "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'Wayland_XDG', \
+        bb.utils.contains('DISTRO_FEATURES',     'x11',         'X11', \
+                                                                 'FB', d), d)}"
+
+FEATURES                  = "ConsoleHost,EarlyAccess,EGL,GoogleUnitTest,Lib_NlohmannJson,OpenVG,Test_RequireUserInputToExit,WindowHost"
+FEATURES:append:imxgpu    = ",HW_GPU_VIVANTE"
+FEATURES:append:imxgpu2d  = ",G2D"
+FEATURES:append:imxgpu3d  = ",OpenGLES2"
+FEATURES:append           = "${FEATURES_SOC}"
+
+FEATURES_SOC              = ""
+FEATURES_SOC:mx6q-nxp-bsp         = ",OpenGLES3"
+FEATURES_SOC:mx6dl-nxp-bsp        = ",OpenGLES3"
+FEATURES_SOC:mx8-nxp-bsp          = ",OpenCV4,Vulkan1.2,OpenGLES3.2,OpenCL1.2,OpenVX1.2"
+FEATURES_SOC:mx8mm-nxp-bsp        = ",OpenCV4"
+
+EXTENSIONS               = "*"
+EXTENSIONS:mx6q-nxp-bsp  = "OpenGLES:GL_VIV_direct_texture,OpenGLES3:GL_EXT_geometry_shader,OpenGLES3:GL_EXT_tessellation_shader"
+EXTENSIONS:mx6dl-nxp-bsp = "OpenGLES:GL_VIV_direct_texture,OpenGLES3:GL_EXT_geometry_shader,OpenGLES3:GL_EXT_tessellation_shader"
+EXTENSIONS:mx8m-nxp-bsp  = "OpenGLES:GL_VIV_direct_texture,OpenGLES3:GL_EXT_color_buffer_float"
+EXTENSIONS:mx8mm-nxp-bsp = "*"
+
+do_compile () {
+    export FSL_PLATFORM_NAME=Yocto
+    export ROOTFS=${STAGING_DIR_HOST}
+    . ./prepare.sh
+    FslBuild.py -vvvvv -t sdk --UseFeatures [${FEATURES}] --UseExtensions [${EXTENSIONS}] --Variants [WindowSystem=${WINDOW_SYSTEM}] --BuildThreads ${@oe.utils.parallel_make(d)} -c install --CMakeInstallPrefix ${S}
+}
+
+REMOVALS = " \
+    GLES2/DeBayer \
+    GLES2/DirectMultiSamplingVideoYUV \
+    GLES3/DirectMultiSamplingVideoYUV \
+"
+REMOVALS:append:imxdpu = " \
+    G2D/EightLayers \
+"
+REMOVALS:append:mx6q-nxp-bsp = " \
+    GLES3/HDR02_FBBasicToneMapping \
+    GLES3/HDR03_SkyboxTonemapping \
+    GLES3/HDR04_HDRFramebuffer \
+"
+REMOVALS:append:mx6dl-nxp-bsp = " \
+    GLES3/HDR02_FBBasicToneMapping \
+    GLES3/HDR03_SkyboxTonemapping \
+    GLES3/HDR04_HDRFramebuffer \
+"
+
+do_install () {
+    install -d "${D}/opt/${PN}"
+    cp -r ${S}/bin/* ${D}/opt/${PN}
+    for removal in ${REMOVALS}; do
+        rm -rf ${D}/opt/${PN}/$removal
+    done
+}
+
+FILES:${PN} += "/opt/${PN}"
+FILES:${PN}-dbg += "/opt/${PN}/*/*/.debug /usr/src/debug"
+INSANE_SKIP:${PN} += "already-stripped rpaths"
+
+# Unfortunately recipes with an empty main package, like header-only libraries,
+# are not included in the SDK. Use RDEPENDS as a workaround.
+RDEPENDS_EMPTY_MAIN_PACKAGE = " \
+    fmt \
+    gli \
+    glm \
+    googletest \
+    half \
+    nlohmann-json \
+    rapidjson \
+    stb \
+"
+RDEPENDS_EMPTY_MAIN_PACKAGE_MX8       = ""
+RDEPENDS_EMPTY_MAIN_PACKAGE_MX8:mx8-nxp-bsp   = " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'libxdg-shell', '', d)} \
+    rapidopencl \
+    rapidopenvx \
+    rapidvulkan \
+"
+RDEPENDS_EMPTY_MAIN_PACKAGE_MX8:mx8mm-nxp-bsp = ""
+# vulkan-loader is dynamically loaded, so need to add an explicit
+# dependency
+RDEPENDS_VULKAN_LOADER       = ""
+RDEPENDS_VULKAN_LOADER:mx8-nxp-bsp   = "vulkan-validation-layers vulkan-loader"
+RDEPENDS_VULKAN_LOADER:mx8mm-nxp-bsp = ""
+RDEPENDS:${PN} += " \
+    ${RDEPENDS_EMPTY_MAIN_PACKAGE} \
+    ${RDEPENDS_EMPTY_MAIN_PACKAGE_MX8} \
+    ${RDEPENDS_VULKAN_LOADER} \
+"
+
+# For backwards compatibility
+RPROVIDES:${PN} = "fsl-gpu-sdk"
+RREPLACES:${PN} = "fsl-gpu-sdk"
+RCONFLICTS:${PN} = "fsl-gpu-sdk"
+
+COMPATIBLE_MACHINE = "(imxgpu)"
diff --git a/recipes-graphics/imx-gpu-sdk/libxdg-shell.bb b/recipes-graphics/imx-gpu-sdk/libxdg-shell.bb
new file mode 100644
index 000000000..a5637869a
--- /dev/null
+++ b/recipes-graphics/imx-gpu-sdk/libxdg-shell.bb
@@ -0,0 +1,21 @@
+SUMMARY = "Provides XDG shell header and glue code library"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${UNPACKDIR}/${BP}/License.md;md5=9d58a2573275ce8c35d79576835dbeb8"
+
+DEPENDS = "wayland-native wayland wayland-protocols"
+
+require imx-gpu-sdk-src.inc
+
+SRC_URI += "file://0001-xdg-shell-Add-CMake-minimum.patch"
+
+S = "${UNPACKDIR}/${BP}/ThirdParty/Recipe/xdg-shell"
+
+inherit cmake pkgconfig
+
+EXTRA_OECMAKE = " \
+    -DWAYLAND_SCANNER=${STAGING_BINDIR_NATIVE}/wayland-scanner \
+    -DWAYLAND_PROTOCOLS_DIR=${STAGING_DATADIR}/wayland-protocols \
+"
+
+ALLOW_EMPTY:${PN} = "1"
+RDEPENDS:${PN}-dev = "${PN}-staticdev"
diff --git a/recipes-graphics/imx-gpu-sdk/libxdg-shell/0001-xdg-shell-Add-CMake-minimum.patch b/recipes-graphics/imx-gpu-sdk/libxdg-shell/0001-xdg-shell-Add-CMake-minimum.patch
new file mode 100644
index 000000000..9ece7d8f7
--- /dev/null
+++ b/recipes-graphics/imx-gpu-sdk/libxdg-shell/0001-xdg-shell-Add-CMake-minimum.patch
@@ -0,0 +1,38 @@
+From 6e38ee09378bfa7edc97528967f0dd0bd810f2c6 Mon Sep 17 00:00:00 2001
+From: Tom Hochstein <tom.hochstein@nxp.com>
+Date: Thu, 9 Oct 2025 08:29:44 -0500
+Subject: [PATCH] xdg-shell: Add CMake minimum
+
+The build is broken:
+```
+| CMake Error in CMakeLists.txt:
+|   No cmake_minimum_required command is present.  A line of code such as
+|
+|     cmake_minimum_required(VERSION 4.1)
+|
+|   should be added at the top of the file.  The version specified may be lower
+|   if you wish to support older CMake versions for this project.  For more
+|   information run "cmake --help-policy CMP0000".
+```
+
+Upstream-Status: Pending
+Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
+---
+ CMakeLists.txt | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 8d39c6c5..5cb52e32 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -1,5 +1,7 @@
+ # Generate the client header and glue library from xdg-shell.xml
+ 
++cmake_minimum_required(VERSION 3.5)
++
+ include(FindPkgConfig)
+ 
+ if (NOT DEFINED WAYLAND_PROTOCOLS_DIR)
+-- 
+2.34.1
+
diff --git a/recipes-graphics/rapidopencl/rapidopencl_1.1.0.1.bb b/recipes-graphics/rapidopencl/rapidopencl_1.1.0.1.bb
new file mode 100644
index 000000000..d4200d394
--- /dev/null
+++ b/recipes-graphics/rapidopencl/rapidopencl_1.1.0.1.bb
@@ -0,0 +1,16 @@
+SUMMARY = "Experimental low level header only C++11 RAII wrapper classes for the OpenCL API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidOpenCL;protocol=https;branch=master \
+"
+SRCREV = "21254804a56ae96e8385c2652733c338d62da04f"
+
+# RapidOpenCL is a header-only C++11 RAII wrapper class, so the main package will be empty.
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY:${PN} = "1"
diff --git a/recipes-graphics/rapidopenvx/rapidopenvx_1.1.0.bb b/recipes-graphics/rapidopenvx/rapidopenvx_1.1.0.bb
new file mode 100644
index 000000000..049fca0fd
--- /dev/null
+++ b/recipes-graphics/rapidopenvx/rapidopenvx_1.1.0.bb
@@ -0,0 +1,14 @@
+SUMMARY = "Low level header only C++11 RAII wrapper classes for the OpenVX API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidOpenVX;protocol=https;branch=master \
+"
+SRCREV = "909c7abbff0ee35610f07f6fadeaf3a2eadce36e"
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY:${PN} = "1"
diff --git a/recipes-graphics/rapidvulkan/rapidvulkan_1.2.162.0.bb b/recipes-graphics/rapidvulkan/rapidvulkan_1.2.162.0.bb
new file mode 100644
index 000000000..86ec697d2
--- /dev/null
+++ b/recipes-graphics/rapidvulkan/rapidvulkan_1.2.162.0.bb
@@ -0,0 +1,13 @@
+SUMMARY = "Low level header only C++11 RAII wrapper classes for the Vulkan API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+DEPENDS = "vulkan-loader"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidVulkan;protocol=https;branch=master"
+SRCREV = "e39a407c5ae880792d8843ada65a19dd26b3dca7"
+
+
+inherit cmake
+
+ALLOW_EMPTY:${PN} = "1"
diff --git a/recipes-graphics/vulkan/assimp/0001-X3D-Fix-invalid-vector-back-usage-6283.patch b/recipes-graphics/vulkan/assimp/0001-X3D-Fix-invalid-vector-back-usage-6283.patch
new file mode 100644
index 000000000..1b2bb5b1a
--- /dev/null
+++ b/recipes-graphics/vulkan/assimp/0001-X3D-Fix-invalid-vector-back-usage-6283.patch
@@ -0,0 +1,52 @@
+From 59bc03d931270b6354690512d0c881eec8b97678 Mon Sep 17 00:00:00 2001
+From: Kim Kulling <kimkulling@users.noreply.github.com>
+Date: Fri, 25 Jul 2025 15:01:16 +0200
+Subject: [PATCH] X3D: Fix invalid vector::back usage (#6283)
+
+* X3D: Fix invalid vector::back usage
+
+Upstream-Status: Backport [https://github.com/assimp/assimp/commit/59bc03d931270b6354690512d0c881eec8b97678]
+---
+ code/AssetLib/X3D/X3DGeoHelper.cpp | 14 ++++++++++----
+ 1 file changed, 10 insertions(+), 4 deletions(-)
+
+diff --git a/code/AssetLib/X3D/X3DGeoHelper.cpp b/code/AssetLib/X3D/X3DGeoHelper.cpp
+index 1c962a460..b90956d2c 100644
+--- a/code/AssetLib/X3D/X3DGeoHelper.cpp
++++ b/code/AssetLib/X3D/X3DGeoHelper.cpp
+@@ -128,13 +128,17 @@ void X3DGeoHelper::rect_parallel_epiped(const aiVector3D &pSize, std::list<aiVec
+ 
+ #undef MESH_RectParallelepiped_CREATE_VERT
+ 
++static constexpr int InvalidIndex = -1;
++
+ void X3DGeoHelper::coordIdx_str2faces_arr(const std::vector<int32_t> &pCoordIdx, std::vector<aiFace> &pFaces, unsigned int &pPrimitiveTypes) {
+     std::vector<int32_t> f_data(pCoordIdx);
+     std::vector<unsigned int> inds;
+     unsigned int prim_type = 0;
+ 
+-    if (f_data.back() != (-1)) {
+-        f_data.push_back(-1);
++    if (!f_data.empty()) {
++        if (f_data.back() != InvalidIndex) {
++            f_data.push_back(InvalidIndex);
++        }
+     }
+ 
+     // reserve average size.
+@@ -191,8 +195,10 @@ mg_m_err:
+ void X3DGeoHelper::coordIdx_str2lines_arr(const std::vector<int32_t> &pCoordIdx, std::vector<aiFace> &pFaces) {
+     std::vector<int32_t> f_data(pCoordIdx);
+ 
+-    if (f_data.back() != (-1)) {
+-        f_data.push_back(-1);
++    if (!f_data.empty()) {
++        if (f_data.back() != InvalidIndex) {
++            f_data.push_back(InvalidIndex);
++        }
+     }
+ 
+     // reserve average size.
+-- 
+2.34.1
+
diff --git a/recipes-graphics/vulkan/assimp_5.4.3.bb b/recipes-graphics/vulkan/assimp_5.4.3.bb
new file mode 100644
index 000000000..ff4fb7719
--- /dev/null
+++ b/recipes-graphics/vulkan/assimp_5.4.3.bb
@@ -0,0 +1,34 @@
+DESCRIPTION = "Open Asset Import Library is a portable Open Source library to import \
+               various well-known 3D model formats in a uniform manner."
+HOMEPAGE = "http://www.assimp.org/"
+SECTION = "devel"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d9d5275cab4fb13ae624d42ce64865de"
+
+DEPENDS = "zlib"
+
+SRC_URI = "git://github.com/assimp/assimp.git;protocol=https;branch=master \
+           file://0001-X3D-Fix-invalid-vector-back-usage-6283.patch"
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>(\d+(\.\d+)+))"
+
+SRCREV = "c35200e38ea8f058812b83de2ef32c6093b0ece2"
+
+inherit cmake
+
+do_unpack:append() {
+    bb.build.exec_func('remove_non_compliant_source', d)
+}
+
+remove_non_compliant_source() {
+    # Remove non-compliant files manually. A patch file cannot be used
+    # since many of the files are binary.
+    rm -rf ${S}/test/models-nonbsd ${S}/scripts/StepImporter/schema_ifc2x3.exp
+}
+
+EXTRA_OECMAKE = "-DASSIMP_BUILD_ASSIMP_TOOLS=OFF -DASSIMP_BUILD_TESTS=OFF -DASSIMP_LIB_INSTALL_DIR=${baselib}"
+
+BBCLASSEXTEND = "native nativesdk"
+
+# Work around do_package_qa error
+INSANE_SKIP:${PN}-dev += "buildpaths"