1 files changed, 49 insertions, 0 deletions

diff --git a/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.14.bb b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.14.bb
new file mode 100644
index 000000000..23168ae16
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.14.bb
@@ -0,0 +1,49 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX DPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=10c0fda810c63b052409b15a5445671a" 
+
+DEPENDS = "libdrm ${LIBGAL_IMX}"
+LIBGAL_IMX              = "libgal-imx"
+LIBGAL_IMX:mx95-nxp-bsp = ""
+
+PROVIDES += "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;fsl-eula=true;name=${IMX_SRC_URI_NAME}"
+IMX_BIN_NAME = "${BPN}-${IMX_SRC_URI_NAME}-${PV}-${IMX_SRCREV_ABBREV}"
+
+IMX_SRCREV_ABBREV = "6a00326"
+IMX_SRC_URI_NAME = "v1"
+SRC_URI[v1.md5sum] = "470ad0bdef7dec171395991d47b39e2c"
+SRC_URI[v1.sha256sum] = "4d8e4b536bd24eedfbce375a06c19ab74603291b8b5a5be36b03fbf6e016e940"
+
+IMX_SRCREV_ABBREV:mx95-nxp-bsp = "6a00326"
+IMX_SRC_URI_NAME:mx95-nxp-bsp = "v2"
+SRC_URI[v2.md5sum] = "cf807c38a110763c19a12d6d595b4b09"
+SRC_URI[v2.sha256sum] = "1b86d4fecd5026e871da0de8ed6382c962460468d8151ae2f95b72d00bca17ee"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+INSANE_SKIP:append:libc-musl = " file-rdeps"
+RDEPENDS:${PN}:append:libc-musl = " gcompat"
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxdpu)"