fsl-image-multimedia: import from meta-freescale-distro

Move the recipe into meta-freescale as part of consolidating all
recipe content into a single layer. meta-freescale-distro is becoming a
thin backward-compatibility layer that only keeps the distro definitions
for the wrynose LTS lifetime and is no longer used for recipe development.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 30 insertions, 0 deletions

diff --git a/recipes-fsl/images/fsl-image-multimedia.bb b/recipes-fsl/images/fsl-image-multimedia.bb
new file mode 100644
index 000000000..3a3ce28b8
--- /dev/null
+++ b/recipes-fsl/images/fsl-image-multimedia.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "A console-only image that includes gstreamer packages and \
+Freescale's multimedia packages (VPU and GPU) when available for the specific \
+machine."
+
+IMAGE_FEATURES += "\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'weston', \
+       bb.utils.contains('DISTRO_FEATURES',     'x11', 'x11-base', \
+                                                       '', d), d)} \
+"
+
+LICENSE = "MIT"
+
+inherit core-image
+
+CORE_IMAGE_EXTRA_INSTALL += " \
+    packagegroup-fsl-tools-gpu \
+    packagegroup-fsl-gstreamer1.0 \
+    packagegroup-imx-tools-audio \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', \
+                         'weston weston-init weston-examples \
+                          gtk+3-demo', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', \
+                         'weston-xwayland xterm', '', d)} \
+"
+
+PACKAGE_IMX_TO_REMOVE = ""
+PACKAGE_IMX_TO_REMOVE:imxgpu2d = "gtk+3-demo"
+PACKAGE_IMX_TO_REMOVE:imxgpu3d = ""
+
+CORE_IMAGE_EXTRA_INSTALL:remove = "${PACKAGE_IMX_TO_REMOVE}"