spir: Downgrade to 1.3.239.0.imx

Latest spir is not compatible with downgraded vulkan, so downgrade
spir to match.

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>

3 files changed, 62 insertions, 0 deletions

diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
index 8db97110d..0bff766be 100644
--- a/conf/machine/include/imx-base.inc
+++ b/conf/machine/include/imx-base.inc
@@ -584,6 +584,8 @@ PREFERRED_VERSION_libdrm:mx7-nxp-bsp ??= "2.4.115.imx"
 PREFERRED_VERSION_libdrm:mx8-nxp-bsp ??= "2.4.115.imx"
 PREFERRED_VERSION_libdrm:mx9-nxp-bsp ??= "2.4.115.imx"
 
+PREFERRED_VERSION_spirv-headers:imxvulkan            ??= "1.3.239.0.imx"
+PREFERRED_VERSION_spirv-tools:imxvulkan              ??= "1.3.239.0.imx"
 PREFERRED_VERSION_vulkan-headers:imxvulkan           ??= "1.3.239.0.imx"
 PREFERRED_VERSION_vulkan-loader:imxvulkan            ??= "1.3.239.0.imx"
 PREFERRED_VERSION_vulkan-tools:imxvulkan             ??= "1.3.239.0.imx"
diff --git a/recipes-downgrade/spir/spirv-headers_1.3.239.0.imx.bb b/recipes-downgrade/spir/spirv-headers_1.3.239.0.imx.bb
new file mode 100644
index 000000000..afd59cbcb
--- /dev/null
+++ b/recipes-downgrade/spir/spirv-headers_1.3.239.0.imx.bb
@@ -0,0 +1,18 @@
+SUMMARY = "Machine-readable files for the SPIR-V Registry"
+DESCRIPTION = "Headers are provided in the include directory, with up-to-date \
+headers in the unified1 subdirectory. Older headers are provided according to \
+their version."
+SECTION = "graphics"
+HOMEPAGE = "https://www.khronos.org/registry/spir-v"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c938b85bceb8fb26c1a807f28a52ae2d"
+
+SRCREV = "d13b52222c39a7e9a401b44646f0ca3a640fbd47"
+SRC_URI = "git://github.com/KhronosGroup/SPIRV-Headers;protocol=https;branch=main"
+PE = "1"
+UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/recipes-downgrade/spir/spirv-tools_1.3.239.0.imx.bb b/recipes-downgrade/spir/spirv-tools_1.3.239.0.imx.bb
new file mode 100644
index 000000000..5109bb533
--- /dev/null
+++ b/recipes-downgrade/spir/spirv-tools_1.3.239.0.imx.bb
@@ -0,0 +1,42 @@
+SUMMARY  = "The SPIR-V Tools project provides an API and commands for \
+processing SPIR-V modules"
+DESCRIPTION = "The project includes an assembler, binary module parser, \
+disassembler, validator, and optimizer for SPIR-V."
+HOMEPAGE = "https://github.com/KhronosGroup/SPIRV-Tools"
+SECTION = "graphics"
+LICENSE  = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRCREV = "63de608daeb7e91fbea6d7477a50debe7cac57ce"
+SRC_URI = "git://github.com/KhronosGroup/SPIRV-Tools.git;branch=main;protocol=https"
+PE = "1"
+UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
+S = "${WORKDIR}/git"
+
+inherit cmake python3native
+
+DEPENDS = "spirv-headers"
+
+EXTRA_OECMAKE += "\
+    -DSPIRV-Headers_SOURCE_DIR=${STAGING_EXECPREFIXDIR} \
+    -DSPIRV_TOOLS_BUILD_STATIC=OFF \
+    -DBUILD_SHARED_LIBS=ON \
+    -DSPIRV_SKIP_TESTS=ON \
+"
+
+do_install:append:class-target() {
+    # Properly set _IMPORT_PREFIX in INTERFACE_LINK_LIBRARIES so that dependent
+    # tools can find the right library
+    sed -i ${D}${libdir}/cmake/SPIRV-Tools/SPIRV-ToolsTarget.cmake \
+        -e 's:INTERFACE_LINK_LIBRARIES.*$:INTERFACE_LINK_LIBRARIES "\$\{_IMPORT_PREFIX\}/lib":'
+}
+
+# all the libraries are unversioned, so don't pack it on PN-dev
+SOLIBS = ".so"
+FILES_SOLIBSDEV = ""
+
+PACKAGES =+ "${PN}-lesspipe"
+FILES:${PN}-lesspipe = "${base_bindir}/spirv-lesspipe.sh"
+RDEPENDS:${PN}-lesspipe += "${PN} bash"
+
+BBCLASSEXTEND = "native nativesdk"