Merge pull request #2468 from nxp-upstream/smw-enclave-upgrade

Update imx-secure-enclave to 6.18.2-1.0.0

6 files changed, 166 insertions, 20 deletions

diff --git a/recipes-bsp/imx-secure-enclave/imx-secure-enclave-prime_git.bb b/recipes-bsp/imx-secure-enclave/imx-secure-enclave-prime_git.bb
new file mode 100644
index 000000000..1bd72d118
--- /dev/null
+++ b/recipes-bsp/imx-secure-enclave/imx-secure-enclave-prime_git.bb
@@ -0,0 +1,13 @@
+require imx-secure-enclave.inc
+
+SUMMARY += "PRIME"
+DESCRIPTION += "PRIME"
+
+PLAT = "prime"
+
+do_install:append() {
+    # Remove common content that is to be installed by imx-secure-enclave
+    rm ${D}${datadir}/se/README
+}
+
+COMPATIBLE_MACHINE = "(mx943-nxp-bsp|mx952-nxp-bsp)"
diff --git a/recipes-bsp/imx-secure-enclave/imx-secure-enclave-seco_git.bb b/recipes-bsp/imx-secure-enclave/imx-secure-enclave-seco_git.bb
new file mode 100644
index 000000000..803cbeffe
--- /dev/null
+++ b/recipes-bsp/imx-secure-enclave/imx-secure-enclave-seco_git.bb
@@ -0,0 +1,20 @@
+require imx-secure-enclave.inc
+
+SUMMARY += "SECO"
+DESCRIPTION += "SECO"
+
+PLAT = "seco"
+
+EXTRA_OEMAKE:append:mx8x-nxp-bsp = " COMPATIBLE_MACHINE=mx8dxl-nxp-bsp"
+
+do_install:append:mx9-nxp-bsp() {
+    # Remove common content that is to be installed by imx-secure-enclave
+    for i in common hsm nvm.h; do
+        rm -rf ${D}${includedir}/$i
+    done
+    rm ${D}${datadir}/se/README
+    rm ${D}${bindir}/nvmd_conf_setup.sh
+    rm ${D}${bindir}/se_tools
+}
+
+COMPATIBLE_MACHINE = "(mx8x-nxp-bsp|mx943-nxp-bsp|mx95-nxp-bsp|mx952-nxp-bsp)"
diff --git a/recipes-bsp/imx-secure-enclave/imx-secure-enclave.inc b/recipes-bsp/imx-secure-enclave/imx-secure-enclave.inc
new file mode 100644
index 000000000..bb045b6fb
--- /dev/null
+++ b/recipes-bsp/imx-secure-enclave/imx-secure-enclave.inc
@@ -0,0 +1,29 @@
+# Copyright 2021-2025 NXP
+
+SUMMARY = "NXP i.MX SECURE ENCLAVE library"
+DESCRIPTION = "NXP IMX SECURE ENCLAVE library"
+SECTION = "base"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8636bd68fc00cc6a3809b7b58b45f982"
+
+DEPENDS = " mbedtls openssl"
+
+SRC_URI = "${SECURE_ENCLAVE_LIB_SRC};branch=${SRCBRANCH}"
+SECURE_ENCLAVE_LIB_SRC ?= "git://github.com/NXP/imx-secure-enclave.git;protocol=https"
+SRCBRANCH = "lf-6.18.2_1.0.0"
+SRCREV = "24fdfb728fff1644878f5ab4a5557decf0769959"
+
+PLAT ?= "UNDEFINED"
+
+EXTRA_OEMAKE = "PLAT=${PLAT} OPENSSL_PATH=${STAGING_INCDIR} MBEDTLS_PATH=${STAGING_DIR_HOST}${datadir}/mbedtls-source"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_install() {
+        oe_runmake -C ${S} DESTDIR=${D} install_tests
+}
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+FILES:${PN} += "${datadir}/se"
+RDEPENDS:${PN}:append = " bash"
diff --git a/recipes-bsp/imx-secure-enclave/imx-secure-enclave_git.bb b/recipes-bsp/imx-secure-enclave/imx-secure-enclave_git.bb
index 525824f79..647a9d768 100644
--- a/recipes-bsp/imx-secure-enclave/imx-secure-enclave_git.bb
+++ b/recipes-bsp/imx-secure-enclave/imx-secure-enclave_git.bb
@@ -1,29 +1,18 @@
-SUMMARY = "NXP i.MX Secure Enclave Userspace Library"
-DESCRIPTION = "NXP i.MX Secure Enclave Userspace Library"
-SECTION = "base"
-
-LICENSE = "BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=8636bd68fc00cc6a3809b7b58b45f982"
-
-DEPENDS = "openssl"
+require imx-secure-enclave.inc
 
 inherit systemd
 
-SRC_URI = "git://github.com/NXP/imx-secure-enclave.git;protocol=https;branch=lf-6.6.52_2.2.0"
-SRCREV = "dffbb844e86f4a49058ffbb40548474059969c27"
-
-PV = "lf-6.6.52_2.2.0"
+SYSTEMD_AUTO_ENABLE = "disable"
+SYSTEMD_SERVICE:${PN} = "nvm_daemon.service"
 
-EXTRA_OEMAKE += "PLAT=ele"
+PLAT = "ele"
 
-TARGET_CC_ARCH += "${LDFLAGS}"
+PACKAGES =+ "${PN}-crrm"
 
-do_install () {
-    oe_runmake DESTDIR=${D} install
-    rm -rf ${D}/usr/share
-}
+RDEPENDS:${PN} = "${@bb.utils.contains('UBOOT_CONFIG', 'crrm', '${PN}-crrm', '', d)}"
 
-SYSTEMD_AUTO_ENABLE = "disable"
-SYSTEMD_SERVICE:${PN} = "nvm_daemon.service"
+FILES:${PN}-crrm = " \
+    ${bindir}/ele_crrm_test \
+    ${libdir}/lib*crrm${SOLIBS}"
 
 COMPATIBLE_MACHINE = "(mx8ulp-nxp-bsp|mx9-nxp-bsp)"
diff --git a/recipes-connectivity/mbedtls/mbedtls/run-ptest b/recipes-connectivity/mbedtls/mbedtls/run-ptest
new file mode 100644
index 000000000..059ab4ecb
--- /dev/null
+++ b/recipes-connectivity/mbedtls/mbedtls/run-ptest
@@ -0,0 +1,17 @@
+#!/bin/sh
+
+ptestdir=$(dirname "$(readlink -f "$0")")
+cd "$ptestdir"/tests || exit
+
+tests=$(find * -type f -name 'test_suite_*')
+
+for f in $tests
+do
+    if test -x ./"$f"; then
+        if ./"$f" > ./"$f".out 2> ./"$f".err; then
+            echo "PASS: $f"
+        else
+            echo "FAIL: $f"
+        fi
+    fi
+done
diff --git a/recipes-connectivity/mbedtls/mbedtls_3.6.5.bb b/recipes-connectivity/mbedtls/mbedtls_3.6.5.bb
new file mode 100644
index 000000000..e6dfe4309
--- /dev/null
+++ b/recipes-connectivity/mbedtls/mbedtls_3.6.5.bb
@@ -0,0 +1,78 @@
+SUMMARY = "Lightweight crypto and SSL/TLS library"
+DESCRIPTION = "mbedtls is a lean open source crypto library          \
+for providing SSL and TLS support in your programs. It offers        \
+an intuitive API and documented header files, so you can actually    \
+understand what the code does. It features:                          \
+                                                                     \
+ - Symmetric algorithms, like AES, Blowfish, Triple-DES, DES, ARC4,  \
+   Camellia and XTEA                                                 \
+ - Hash algorithms, like SHA-1, SHA-2, RIPEMD-160 and MD5            \
+ - Entropy pool and random generators, like CTR-DRBG and HMAC-DRBG   \
+ - Public key algorithms, like RSA, Elliptic Curves, Diffie-Hellman, \
+   ECDSA and ECDH                                                    \
+ - SSL v3 and TLS 1.0, 1.1 and 1.2                                   \
+ - Abstraction layers for ciphers, hashes, public key operations,    \
+   platform abstraction and threading                                \
+"
+
+HOMEPAGE = "https://tls.mbed.org/"
+
+LICENSE = "Apache-2.0 | GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=379d5819937a6c2f1ef1630d341e026d"
+
+SECTION = "libs"
+
+SRC_URI = "gitsm://github.com/Mbed-TLS/mbedtls.git;protocol=https;branch=mbedtls-3.6;tag=v${PV} \
+           file://run-ptest \
+           "
+
+SRCREV = "e185d7fd85499c8ce5ca2a54f5cf8fe7dbe3f8df"
+
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
+
+inherit cmake update-alternatives ptest
+
+PACKAGECONFIG ??= "shared-libs programs ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
+PACKAGECONFIG[shared-libs] = "-DUSE_SHARED_MBEDTLS_LIBRARY=ON,-DUSE_SHARED_MBEDTLS_LIBRARY=OFF"
+PACKAGECONFIG[programs] = "-DENABLE_PROGRAMS=ON,-DENABLE_PROGRAMS=OFF"
+PACKAGECONFIG[werror] = "-DMBEDTLS_FATAL_WARNINGS=ON,-DMBEDTLS_FATAL_WARNINGS=OFF"
+# Make X.509 and TLS calls use PSA
+# https://github.com/Mbed-TLS/mbedtls/blob/development/docs/use-psa-crypto.md
+PACKAGECONFIG[psa] = ""
+PACKAGECONFIG[tests] = "-DENABLE_TESTING=ON,-DENABLE_TESTING=OFF"
+
+# For now the only way to enable PSA is to explicitly pass a -D via CFLAGS
+CFLAGS:append = "${@bb.utils.contains('PACKAGECONFIG', 'psa', ' -DMBEDTLS_USE_PSA_CRYPTO', '', d)}"
+
+PROVIDES += "polarssl"
+RPROVIDES:${PN} = "polarssl"
+
+PACKAGES =+ "${PN}-programs"
+FILES:${PN}-programs = "${bindir}/"
+
+ALTERNATIVE:${PN}-programs = "${@bb.utils.contains('PACKAGECONFIG', 'programs', 'hello', '', d)}"
+ALTERNATIVE_LINK_NAME[hello] = "${bindir}/hello"
+
+BBCLASSEXTEND = "native nativesdk"
+
+CVE_PRODUCT = "mbed_tls"
+
+# Strip host paths from autogenerated test files
+do_compile:append() {
+        sed -i 's+${S}/++g' ${B}/tests/*.c 2>/dev/null || :
+        sed -i 's+${B}/++g' ${B}/tests/*.c 2>/dev/null || :
+}
+
+# Export source files/headers needed by Arm Trusted Firmware
+sysroot_stage_all:append() {
+        sysroot_stage_dir "${S}/library" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/library"
+        sysroot_stage_dir "${S}/include" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/include"
+}
+
+do_install_ptest () {
+        install -d ${D}${PTEST_PATH}/tests
+        install -d ${D}${PTEST_PATH}/framework
+        cp -f ${B}/tests/test_suite_* ${D}${PTEST_PATH}/tests/
+        find ${D}${PTEST_PATH}/tests/ -type f -name "*.c" -delete
+        cp -fR ${S}/framework/data_files ${D}${PTEST_PATH}/framework/
+}