imx-sw-pdm: Migrate from pre-built binary to git source

Use Clang toolchain required by SIMD PDM-to-PCM code
Extend support to mx9 platforms (previously mx8 only)

Signed-off-by: Flora Hu <flora.hu@nxp.com>

2 files changed, 41 insertions, 23 deletions

diff --git a/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_1.0.3.bb b/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_1.0.3.bb
deleted file mode 100644
index 63cd397f8..000000000
--- a/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_1.0.3.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-# Copyright 2020,2023 NXP
-
-SUMMARY = "i.MX PDM-to-PCM software decimation library"
-DESCRIPTION = "NXP PDM to PCM Software Decimation SIMD Library"
-HOMEPAGE = "https://www.nxp.com/"
-SECTION = "multimedia"
-LICENSE = "LicenseRef-Proprietary"
-LIC_FILES_CHKSUM = "file://COPYING;md5=63a38e9f392d8813d6f1f4d0d6fbe657"
-
-SRC_URI = "${FSL_MIRROR}/${BP}.bin;fsl-eula=true"
-SRC_URI[sha256sum] = "f778a7b785fc500df5573f5b810a190ddc561267b47ca54b9ddf4ae12571cfe3"
-
-inherit fsl-eula-unpack autotools pkgconfig
-
-INSANE_SKIP:${PN} = "already-stripped"
-
-FILES:${PN} += "${datadir}/imx-mm"
-
-COMPATIBLE_MACHINE = "(mx8-nxp-bsp)"
-
-INSANE_SKIP:append:libc-musl = " file-rdeps"
-
-RDEPENDS:${PN}:append:libc-musl = " gcompat"
diff --git a/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_git.bb b/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_git.bb
new file mode 100644
index 000000000..442f35007
--- /dev/null
+++ b/recipes-multimedia/imx-sw-pdm/imx-sw-pdm_git.bb
@@ -0,0 +1,41 @@
+# Copyright 2020,2023,2026 NXP
+
+SUMMARY = "i.MX PDM-to-PCM software decimation library"
+DESCRIPTION = "NXP PDM to PCM Software Decimation SIMD Library"
+HOMEPAGE = "https://www.nxp.com/"
+SECTION = "multimedia"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0858ec9c7a80c4a2cf16e4f825a2cc91"
+
+PV = "1.0.3+git"
+
+SRCBRANCH = "MM_04.11.00_2605_L6.18.20"
+PDM_SRC ?= "git://github.com/nxp-imx/imx-sw-pdm.git;protocol=https"
+SRC_URI = "${PDM_SRC};branch=${SRCBRANCH}"
+SRCREV = "60c4e8f3fd9d2ae67518ea2b9486834c2d49309f"
+
+inherit pkgconfig
+
+TOOLCHAIN = "clang"
+EXTRA_OEMAKE += "CLANGCC='${CC}' CLANGCXX='${CXX}' SDKTARGETSYSROOT='${STAGING_DIR_NATIVE}'"
+
+do_install() {
+    install -d ${D}${bindir}/imx-mm
+    install -m 0755 ${S}/release/imx-sw-pdm ${D}${bindir}/imx-mm
+
+    install -d ${D}${libdir}
+    install -m 0644 ${S}/release/libimxswpdm.so* ${D}${libdir}
+    ln -sf -r ${D}${libdir}/libimxswpdm.so.* ${D}${libdir}/libimxswpdm.so
+
+    install -d ${D}${libdir}/pkgconfig
+    install -m 0644 ${S}/libimxswpdm.pc ${D}${libdir}/pkgconfig
+
+    install -d ${D}${includedir}/imx-mm/audio-codec/swpdm
+    install -m 0644 ${S}/include/imx-swpdm.h ${D}${includedir}/imx-mm/audio-codec/swpdm
+}
+
+INSANE_SKIP:${PN} = "already-stripped"
+
+FILES:${PN} += "${datadir}/imx-mm ${libdir}/*"
+
+COMPATIBLE_MACHINE = "(mx8-nxp-bsp|mx9-nxp-bsp)"