1 files changed, 70 insertions, 0 deletions

diff --git a/recipes-support/memcached/memcached_1.6.41.bb b/recipes-support/memcached/memcached_1.6.41.bb
new file mode 100644
index 0000000..b030ef1
--- /dev/null
+++ b/recipes-support/memcached/memcached_1.6.41.bb
@@ -0,0 +1,70 @@
+SUMMARY = "A high-performance memory object caching system"
+DESCRIPTION = "\
+ memcached optimizes specific high-load serving applications that are designed \
+ to take advantage of its versatile no-locking memory access system. Clients \
+ are available in several different programming languages, to suit the needs \
+ of the specific application. Traditionally this has been used in mod_perl \
+ apps to avoid storing large chunks of data in Apache memory, and to share \
+ this burden across several machines."
+SECTION = "web"
+HOMEPAGE = "http://memcached.org/"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
+
+inherit autotools pkgconfig systemd
+
+DEPENDS += "libevent"
+RDEPENDS:${PN} += "\
+    bash \
+    perl \
+    perl-module-posix \
+    perl-module-autoloader \
+    perl-module-tie-hash \
+    "
+
+SRC_URI = "http://www.memcached.org/files/${BP}.tar.gz \
+           file://memcached-add-hugetlbfs-check.patch \
+           file://memcached-config.txt \
+           "
+
+SRC_URI[md5sum] = "a9eb0848f052a5c0d18b4a314807dd5c"
+SRC_URI[sha256sum] = "e097073c156eeff9e12655b054f446d57374cfba5c132dcdbe7fac64e728286a"
+
+# set the same COMPATIBLE_HOST as libhugetlbfs
+COMPATIBLE_HOST = '(i.86|x86_64|powerpc|powerpc64|arm).*-linux'
+
+python __anonymous () {
+    endianness = d.getVar('SITEINFO_ENDIANNESS', True)
+    if endianness == 'le':
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=little")
+    else:
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=big")
+}
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[hugetlbfs] = "--enable-hugetlbfs, --disable-hugetlbfs, libhugetlbfs"
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "memcached"
+INITSCRIPT_PARAMS = "defaults"
+
+SYSTEMD_PACKAGES = "memcached"
+SYSTEMD_SERVICE:${PN} = "memcached.service"
+
+do_install:append() {
+    install -D -m 755 ${S}/scripts/memcached-init ${D}${sysconfdir}/init.d/memcached
+    
+    mkdir -p ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/memcached-tool ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/start-memcached ${D}/usr/share/memcached/scripts
+
+    install -d ${D}/${sysconfdir}/default
+    install -m 600 ${UNPACKDIR}/memcached-config.txt ${D}/${sysconfdir}/default/memcached
+
+    install -d ${D}/${systemd_system_unitdir}
+    install -m 644 ${S}/scripts/memcached.service ${D}/${systemd_system_unitdir}/.
+    sed -e "s@^EnvironmentFile=.*@EnvironmentFile=${sysconfdir}/default/memcached@" \
+        -i ${D}/${systemd_system_unitdir}/memcached.service
+}