add recipe for arm-trusted-firmware

Signed-off-by: Chang Rebecca Swee Fun <rebecca.swee.fun.chang@intel.com>

2 files changed, 48 insertions, 0 deletions

diff --git a/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware.inc b/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware.inc
new file mode 100644
index 0000000..43d412d
--- /dev/null
+++ b/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware.inc
@@ -0,0 +1,45 @@
+DESCRIPTION = "ARM Trusted Firmware"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://docs/license.rst;md5=189505435dbcdcc8caa63c46fe93fa89"
+
+PROVIDES += "arm-trusted-firmware"
+
+DEPENDS += "u-boot-tools"
+
+inherit deploy
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+PROT ?= "https"
+BRANCH ?= "socfpga_v2.3"
+SRC_URI ?= "git://github.com/altera-opensource/arm-trusted-firmware.git;protocol=${PROT};branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+COMPATIBLE_MACHINE = "(agilex|stratix10)"
+ATFPLAT = "${MACHINE}"
+
+# Let the Makefile handle setting up the CFLAGS and LDFLAGS as it is a standalone application
+EXTRA_OEMAKE = 'CROSS_COMPILE="${TARGET_PREFIX}" PLAT="${ATFPLAT}" DEPRECATED=1 HANDLE_EA_EL3_FIRST=1'
+CFLAGS[unexport] = "1"
+LDFLAGS[unexport] = "1"
+AS[unexport] = "1"
+LD[unexport] = "1"
+PARALLEL_MAKE = ""
+
+ALLOW_EMPTY_${PN} = "1"
+
+do_configure[noexec] = "1"
+
+do_compile() {
+        oe_runmake -C ${S} bl31
+}
+
+do_deploy() {
+        install -d ${DEPLOYDIR}
+        install -m 0644 ${S}/build/${ATFPLAT}/release/bl31.bin ${DEPLOYDIR}/bl31.bin-${MACHINE}-${PV}-${PR}
+        ln -sf bl31.bin-${MACHINE}-${PV}-${PR} ${DEPLOYDIR}/bl31.bin
+}
+
+addtask deploy after do_compile
diff --git a/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb b/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb
new file mode 100644
index 0000000..509c8a4
--- /dev/null
+++ b/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb
@@ -0,0 +1,3 @@
+require arm-trusted-firmware.inc
+
+SRCREV = "a124a308dc3125480ca9c746afb48007d9a7ffce"