diff options
Diffstat (limited to 'meta/recipes-support/gnupg/gnupg_2.4.4.bb')
-rw-r--r-- | meta/recipes-support/gnupg/gnupg_2.4.4.bb | 89 |
1 files changed, 89 insertions, 0 deletions
diff --git a/meta/recipes-support/gnupg/gnupg_2.4.4.bb b/meta/recipes-support/gnupg/gnupg_2.4.4.bb new file mode 100644 index 0000000000..5b9869b4f3 --- /dev/null +++ b/meta/recipes-support/gnupg/gnupg_2.4.4.bb | |||
@@ -0,0 +1,89 @@ | |||
1 | SUMMARY = "GNU Privacy Guard - encryption and signing tools (2.x)" | ||
2 | DESCRIPTION = "A complete and free implementation of the OpenPGP standard \ | ||
3 | as defined by RFC4880 (also known as PGP). GnuPG allows you to encrypt \ | ||
4 | and sign your data and communications; it features a versatile key \ | ||
5 | management system, along with access modules for all kinds of public \ | ||
6 | key directories." | ||
7 | HOMEPAGE = "http://www.gnupg.org/" | ||
8 | LICENSE = "GPL-3.0-only & LGPL-3.0-only" | ||
9 | LIC_FILES_CHKSUM = "file://COPYING;md5=189af8afca6d6075ba6c9e0aa8077626 \ | ||
10 | file://COPYING.LGPL3;md5=a2b6bf2cb38ee52619e60f30a1fc7257" | ||
11 | |||
12 | DEPENDS = "npth libassuan libksba zlib bzip2 readline libgcrypt" | ||
13 | |||
14 | inherit autotools gettext texinfo pkgconfig | ||
15 | |||
16 | UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html" | ||
17 | SRC_URI = "${GNUPG_MIRROR}/${BPN}/${BPN}-${PV}.tar.bz2 \ | ||
18 | file://0002-use-pkgconfig-instead-of-npth-config.patch \ | ||
19 | file://0004-autogen.sh-fix-find-version-for-beta-checking.patch \ | ||
20 | file://0001-Woverride-init-is-not-needed-with-gcc-9.patch \ | ||
21 | " | ||
22 | SRC_URI:append:class-native = " file://0001-configure.ac-use-a-custom-value-for-the-location-of-.patch \ | ||
23 | file://relocate.patch" | ||
24 | SRC_URI:append:class-nativesdk = " file://relocate.patch" | ||
25 | |||
26 | SRC_URI[sha256sum] = "67ebe016ca90fa7688ce67a387ebd82c6261e95897db7b23df24ff335be85bc6" | ||
27 | |||
28 | EXTRA_OECONF = "--disable-ldap \ | ||
29 | --disable-ccid-driver \ | ||
30 | --with-zlib=${STAGING_LIBDIR}/.. \ | ||
31 | --with-bzip2=${STAGING_LIBDIR}/.. \ | ||
32 | --with-readline=${STAGING_LIBDIR}/.. \ | ||
33 | --with-mailprog=${sbindir}/sendmail \ | ||
34 | --enable-gpg-is-gpg2 \ | ||
35 | " | ||
36 | # yat2m can be found from recipe-sysroot-native non-deterministically with different versioning otherwise | ||
37 | CACHED_CONFIGUREVARS += "ac_cv_path_YAT2M=./yat2m" | ||
38 | |||
39 | # A minimal package containing just enough to run gpg+gpgagent (E.g. use gpgme in opkg) | ||
40 | PACKAGES =+ "${PN}-gpg" | ||
41 | FILES:${PN}-gpg = " \ | ||
42 | ${bindir}/gpg \ | ||
43 | ${bindir}/gpg2 \ | ||
44 | ${bindir}/gpg-agent \ | ||
45 | " | ||
46 | |||
47 | # Normal package (gnupg) should depend on minimal package (gnupg-gpg) | ||
48 | # to ensure all tools are included. This is done only in non-native | ||
49 | # builds. Native builds don't have sub-packages, so appending RDEPENDS | ||
50 | # in this case breaks recipe parsing. | ||
51 | RDEPENDS:${PN} += "${@ "" if ("native" in d.getVar("PN")) else (d.getVar("PN") + "-gpg")}" | ||
52 | |||
53 | RRECOMMENDS:${PN} = "pinentry" | ||
54 | |||
55 | do_configure:prepend () { | ||
56 | # Else these could be used in prefernce to those in aclocal-copy | ||
57 | rm -f ${S}/m4/gpg-error.m4 | ||
58 | rm -f ${S}/m4/libassuan.m4 | ||
59 | rm -f ${S}/m4/ksba.m4 | ||
60 | rm -f ${S}/m4/libgcrypt.m4 | ||
61 | } | ||
62 | |||
63 | do_install:append() { | ||
64 | ln -sf gpg2 ${D}${bindir}/gpg | ||
65 | ln -sf gpgv2 ${D}${bindir}/gpgv | ||
66 | } | ||
67 | |||
68 | do_install:append:class-native() { | ||
69 | create_wrappers ${STAGING_BINDIR_NATIVE} | ||
70 | } | ||
71 | |||
72 | do_install:append:class-nativesdk() { | ||
73 | create_wrappers ${SDKPATHNATIVE}${bindir_nativesdk} | ||
74 | } | ||
75 | |||
76 | create_wrappers() { | ||
77 | for i in gpg2 gpgconf gpg-agent gpg-connect-agent; do | ||
78 | create_wrapper ${D}${bindir}/$i GNUPG_BINDIR=$1 | ||
79 | done | ||
80 | } | ||
81 | |||
82 | PACKAGECONFIG ??= "gnutls" | ||
83 | PACKAGECONFIG[gnutls] = "--enable-gnutls, --disable-gnutls, gnutls" | ||
84 | PACKAGECONFIG[sqlite3] = "--enable-sqlite, --disable-sqlite, sqlite3" | ||
85 | |||
86 | BBCLASSEXTEND = "native nativesdk" | ||
87 | |||
88 | lcl_maybe_fortify:mipsarch = "" | ||
89 | |||