diff options
Diffstat (limited to 'meta/recipes-graphics/cairo/cairo_1.18.0.bb')
-rw-r--r-- | meta/recipes-graphics/cairo/cairo_1.18.0.bb | 86 |
1 files changed, 86 insertions, 0 deletions
diff --git a/meta/recipes-graphics/cairo/cairo_1.18.0.bb b/meta/recipes-graphics/cairo/cairo_1.18.0.bb new file mode 100644 index 0000000000..4c97e973d0 --- /dev/null +++ b/meta/recipes-graphics/cairo/cairo_1.18.0.bb | |||
@@ -0,0 +1,86 @@ | |||
1 | SUMMARY = "The Cairo 2D vector graphics library" | ||
2 | DESCRIPTION = "Cairo is a multi-platform library providing anti-aliased \ | ||
3 | vector-based rendering for multiple target backends. Paths consist \ | ||
4 | of line segments and cubic splines and can be rendered at any width \ | ||
5 | with various join and cap styles. All colors may be specified with \ | ||
6 | optional translucence (opacity/alpha) and combined using the \ | ||
7 | extended Porter/Duff compositing algebra as found in the X Render \ | ||
8 | Extension." | ||
9 | HOMEPAGE = "http://cairographics.org" | ||
10 | BUGTRACKER = "https://gitlab.freedesktop.org/cairo/cairo/-/issues" | ||
11 | SECTION = "libs" | ||
12 | |||
13 | LICENSE = "(MPL-1.1 | LGPL-2.1-only) & GPL-3.0-or-later" | ||
14 | LICENSE:${PN} = "MPL-1.1 | LGPL-2.1-only" | ||
15 | LICENSE:${PN}-dev = "MPL-1.1 | LGPL-2.1-only" | ||
16 | LICENSE:${PN}-doc = "MPL-1.1 | LGPL-2.1-only" | ||
17 | LICENSE:${PN}-gobject = "MPL-1.1 | LGPL-2.1-only" | ||
18 | LICENSE:${PN}-script-interpreter = "MPL-1.1 | LGPL-2.1-only" | ||
19 | LICENSE:${PN}-perf-utils = "GPL-3.0-or-later" | ||
20 | # Adapt the licenses for cairo-dbg and cairo-src depending on whether | ||
21 | # cairo-trace is being built. | ||
22 | LICENSE:${PN}-dbg = "(MPL-1.1 | LGPL-2.1-only)${@bb.utils.contains('PACKAGECONFIG', 'trace', ' & GPL-3.0-or-later', '', d)}" | ||
23 | LICENSE:${PN}-src = "(MPL-1.1 | LGPL-2.1-only)${@bb.utils.contains('PACKAGECONFIG', 'trace', ' & GPL-3.0-or-later', '', d)}" | ||
24 | |||
25 | LIC_FILES_CHKSUM = "file://COPYING;md5=e73e999e0c72b5ac9012424fa157ad77 \ | ||
26 | ${@bb.utils.contains('PACKAGECONFIG', 'trace', 'file://util/cairo-trace/COPYING-GPL-3;md5=d32239bcb673463ab874e80d47fae504', '', d)}" | ||
27 | |||
28 | |||
29 | DEPENDS = "fontconfig freetype glib-2.0 libpng pixman zlib" | ||
30 | |||
31 | SRC_URI = "http://cairographics.org/releases/cairo-${PV}.tar.xz \ | ||
32 | file://cairo-get_bitmap_surface-bsc1036789-CVE-2017-7475.diff \ | ||
33 | " | ||
34 | |||
35 | SRC_URI[sha256sum] = "243a0736b978a33dee29f9cca7521733b78a65b5418206fef7bd1c3d4cf10b64" | ||
36 | |||
37 | inherit meson pkgconfig upstream-version-is-even gtk-doc multilib_script | ||
38 | |||
39 | # if qemu usermode isn't available, this value needs to be set statically | ||
40 | # (otherwise it's determinted by running a small target executable with qemu) | ||
41 | do_write_config:append() { | ||
42 | cat >${WORKDIR}/cairo.cross <<EOF | ||
43 | [properties] | ||
44 | ipc_rmid_deferred_release = 'true' | ||
45 | EOF | ||
46 | } | ||
47 | EXTRA_OEMESON:append:class-nativesdk = "${@' --cross-file ${WORKDIR}/cairo.cross' if d.getVar('EXEWRAPPER_ENABLED') == 'False' else ''}" | ||
48 | EXTRA_OEMESON:append:class-target = "${@' --cross-file ${WORKDIR}/cairo.cross' if d.getVar('EXEWRAPPER_ENABLED') == 'False' else ''}" | ||
49 | |||
50 | GTKDOC_MESON_OPTION = "gtk_doc" | ||
51 | |||
52 | MULTILIB_SCRIPTS = "${PN}-perf-utils:${bindir}/cairo-trace" | ||
53 | |||
54 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xlib xcb', '', d)} trace" | ||
55 | PACKAGECONFIG[xlib] = "-Dxlib=enabled,-Dxlib=disabled,virtual/libx11 libxrender libxext" | ||
56 | PACKAGECONFIG[xcb] = "-Dxcb=enabled,-Dxcb=disabled,libxcb" | ||
57 | # cairo-trace is GPLv3 so add an option to remove it | ||
58 | PACKAGECONFIG[trace] = "" | ||
59 | |||
60 | do_install:append () { | ||
61 | if ! ${@bb.utils.contains('PACKAGECONFIG', 'trace', 'true', 'false', d)}; then | ||
62 | rm ${D}${bindir}/cairo-trace ${D}${libdir}/cairo/libcairo-trace.so | ||
63 | rmdir --ignore-fail-on-non-empty ${D}${bindir} ${D}${libdir}/cairo | ||
64 | fi | ||
65 | } | ||
66 | |||
67 | PACKAGES =+ "cairo-gobject cairo-script-interpreter cairo-perf-utils" | ||
68 | |||
69 | SUMMARY:cairo-gobject = "The Cairo library GObject wrapper library" | ||
70 | DESCRIPTION:cairo-gobject = "A GObject wrapper library for the Cairo API." | ||
71 | |||
72 | SUMMARY:cairo-script-interpreter = "The Cairo library script interpreter" | ||
73 | DESCRIPTION:cairo-script-interpreter = "The Cairo script interpreter implements \ | ||
74 | CairoScript. CairoScript is used by tracing utilities to enable the ability \ | ||
75 | to replay rendering." | ||
76 | |||
77 | DESCRIPTION:cairo-perf-utils = "The Cairo library performance utilities" | ||
78 | |||
79 | FILES:${PN} = "${libdir}/libcairo.so.*" | ||
80 | FILES:${PN}-gobject = "${libdir}/libcairo-gobject.so.*" | ||
81 | FILES:${PN}-script-interpreter = "${libdir}/libcairo-script-interpreter.so.*" | ||
82 | FILES:${PN}-perf-utils = "${bindir}/cairo-* ${libdir}/cairo/libcairo-trace.so ${libdir}/cairo/libcairo-fdr.so" | ||
83 | |||
84 | BBCLASSEXTEND = "native nativesdk" | ||
85 | |||
86 | UPSTREAM_CHECK_REGEX = "cairo-(?P<pver>\d+(\.\d+)+).tar.xz" | ||