diff options
Diffstat (limited to 'meta/recipes-gnome/librsvg/librsvg_2.56.1.bb')
-rw-r--r-- | meta/recipes-gnome/librsvg/librsvg_2.56.1.bb | 77 |
1 files changed, 77 insertions, 0 deletions
diff --git a/meta/recipes-gnome/librsvg/librsvg_2.56.1.bb b/meta/recipes-gnome/librsvg/librsvg_2.56.1.bb new file mode 100644 index 0000000000..5649ed7d17 --- /dev/null +++ b/meta/recipes-gnome/librsvg/librsvg_2.56.1.bb | |||
@@ -0,0 +1,77 @@ | |||
1 | SUMMARY = "Library for rendering SVG files" | ||
2 | DESCRIPTION = "A small library to render Scalable Vector Graphics (SVG), \ | ||
3 | associated with the GNOME Project. It renders SVG files to Cairo surfaces. \ | ||
4 | Cairo is the 2D, antialiased drawing library that GNOME uses to draw things to \ | ||
5 | the screen or to generate output for printing." | ||
6 | HOMEPAGE = "https://gitlab.gnome.org/GNOME/librsvg" | ||
7 | BUGTRACKER = "https://gitlab.gnome.org/GNOME/librsvg/issues" | ||
8 | |||
9 | LICENSE = "LGPL-2.1-or-later" | ||
10 | LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \ | ||
11 | " | ||
12 | |||
13 | SECTION = "x11/utils" | ||
14 | DEPENDS = "cairo gdk-pixbuf glib-2.0 libxml2 pango python3-docutils-native" | ||
15 | BBCLASSEXTEND = "native nativesdk" | ||
16 | |||
17 | inherit cargo_common gnomebase pixbufcache upstream-version-is-even gobject-introspection rust vala gi-docgen cargo-update-recipe-crates | ||
18 | |||
19 | require ${BPN}-crates.inc | ||
20 | |||
21 | SRC_URI += "file://0001-Makefile.am-pass-rust-target-to-cargo-also-when-not-.patch \ | ||
22 | " | ||
23 | |||
24 | SRC_URI[archive.sha256sum] = "1685aeacae9a441dcb12c0c3ec63706172a2f52705dafbefb8e7311d4d5e430b" | ||
25 | |||
26 | # librsvg is still autotools-based, but is calling cargo from its automake-driven makefiles | ||
27 | # so we cannot use cargo class directly, but still need bits and pieces from it | ||
28 | # for cargo to be happy | ||
29 | BASEDEPENDS:append = " cargo-native" | ||
30 | |||
31 | export RUST_BACKTRACE = "full" | ||
32 | export RUSTFLAGS | ||
33 | |||
34 | export RUST_TARGET = "${RUST_HOST_SYS}" | ||
35 | |||
36 | RUSTFLAGS:append:mips = " --cfg crossbeam_no_atomic_64" | ||
37 | RUSTFLAGS:append:mipsel = " --cfg crossbeam_no_atomic_64" | ||
38 | RUSTFLAGS:append:powerpc = " --cfg crossbeam_no_atomic_64" | ||
39 | RUSTFLAGS:append:riscv32 = " --cfg crossbeam_no_atomic_64" | ||
40 | |||
41 | do_configure[postfuncs] += "cargo_common_do_configure" | ||
42 | |||
43 | inherit rust-target-config | ||
44 | |||
45 | # rust-cross writes the target linker binary into target json definition without any flags. | ||
46 | # This breaks here because the linker isn't going to work without at least knowing where | ||
47 | # the sysroot is. So copy the json to workdir, and patch in the path to wrapper from rust class | ||
48 | # which supplies the needed flags. | ||
49 | do_compile:prepend() { | ||
50 | sed -ie 's,"linker": ".*","linker": "${RUST_TARGET_CC}",g' ${RUST_TARGETS_DIR}/${RUST_HOST_SYS}.json | ||
51 | } | ||
52 | |||
53 | # Issue only on windows | ||
54 | CVE_CHECK_IGNORE += "CVE-2018-1000041" | ||
55 | |||
56 | CACHED_CONFIGUREVARS = "ac_cv_path_GDK_PIXBUF_QUERYLOADERS=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders" | ||
57 | |||
58 | PACKAGECONFIG ??= "gdkpixbuf" | ||
59 | PACKAGECONFIG:append:class-target = " ${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'vala', '', d)}" | ||
60 | # The gdk-pixbuf loader | ||
61 | PACKAGECONFIG[gdkpixbuf] = "--enable-pixbuf-loader,--disable-pixbuf-loader,gdk-pixbuf-native" | ||
62 | PACKAGECONFIG[vala] = "--enable-vala,--disable-vala" | ||
63 | |||
64 | do_install:append() { | ||
65 | # Loadable modules don't need .a or .la on Linux | ||
66 | rm -f ${D}${libdir}/gdk-pixbuf-2.0/*/loaders/*.a ${D}${libdir}/gdk-pixbuf-2.0/*/loaders/*.la | ||
67 | } | ||
68 | |||
69 | PACKAGES =+ "librsvg-gtk rsvg" | ||
70 | FILES:rsvg = "${bindir}/rsvg* \ | ||
71 | ${datadir}/pixmaps/svg-viewer.svg \ | ||
72 | ${datadir}/themes" | ||
73 | FILES:librsvg-gtk = "${libdir}/gdk-pixbuf-2.0/*/*/*.so \ | ||
74 | ${datadir}/thumbnailers/librsvg.thumbnailer" | ||
75 | RRECOMMENDS:librsvg-gtk = "gdk-pixbuf-bin" | ||
76 | |||
77 | PIXBUF_PACKAGES = "librsvg-gtk" | ||