diff options
Diffstat (limited to 'meta/recipes-gnome/gobject-introspection/gobject-introspection_1.80.1.bb')
-rw-r--r-- | meta/recipes-gnome/gobject-introspection/gobject-introspection_1.80.1.bb | 196 |
1 files changed, 196 insertions, 0 deletions
diff --git a/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.80.1.bb b/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.80.1.bb new file mode 100644 index 0000000000..582ac248fd --- /dev/null +++ b/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.80.1.bb | |||
@@ -0,0 +1,196 @@ | |||
1 | SUMMARY = "Middleware layer between GObject-using C libraries and language bindings" | ||
2 | DESCRIPTION = "GObject Introspection is a project for providing machine \ | ||
3 | readable introspection data of the API of C libraries. This introspection \ | ||
4 | data can be used in several different use cases, for example automatic code \ | ||
5 | generation for bindings, API verification and documentation generation." | ||
6 | HOMEPAGE = "https://wiki.gnome.org/action/show/Projects/GObjectIntrospection" | ||
7 | BUGTRACKER = "https://gitlab.gnome.org/GNOME/gobject-introspection/issues" | ||
8 | SECTION = "libs" | ||
9 | LICENSE = "LGPL-2.0-or-later & GPL-2.0-or-later & MIT" | ||
10 | LIC_FILES_CHKSUM = "file://COPYING;md5=c434e8128a68bedd59b80b2ac1eb1c4a \ | ||
11 | file://tools/compiler.c;endline=20;md5=fc5007fc20022720e6c0b0cdde41fabd \ | ||
12 | file://giscanner/sourcescanner.c;endline=22;md5=194d6e0c1d00662f32d030ce44de8d39 \ | ||
13 | file://girepository/giregisteredtypeinfo.c;endline=21;md5=661847611ae6979465415f31a759ba27 \ | ||
14 | " | ||
15 | |||
16 | SRC_URI = "${GNOME_MIRROR}/${BPN}/${@oe.utils.trim_version("${PV}", 2)}/${BPN}-${PV}.tar.xz \ | ||
17 | " | ||
18 | |||
19 | SRC_URI[sha256sum] = "a1df7c424e15bda1ab639c00e9051b9adf5cea1a9e512f8a603b53cd199bc6d8" | ||
20 | |||
21 | SRC_URI:append:class-native = " file://0001-Relocate-the-repository-directory-for-native-builds.patch" | ||
22 | |||
23 | inherit meson pkgconfig gtk-doc python3targetconfig qemu gobject-introspection-data upstream-version-is-even multilib_script | ||
24 | |||
25 | GTKDOC_MESON_OPTION = "gtk_doc" | ||
26 | |||
27 | MULTILIB_SCRIPTS = "${PN}:${bindir}/g-ir-annotation-tool ${PN}:${bindir}/g-ir-scanner" | ||
28 | |||
29 | DEPENDS += " libffi zlib python3 flex-native bison-native" | ||
30 | DEPENDS:append:class-native = " glib-2.0" | ||
31 | DEPENDS:append:class-target = " glib-2.0-initial" | ||
32 | |||
33 | # target build needs qemu to run temporary introspection binaries created | ||
34 | # on the fly by g-ir-scanner and a native version of itself to run | ||
35 | # native versions of its own tools during build. | ||
36 | DEPENDS:append:class-target = " gobject-introspection-native qemu-native" | ||
37 | |||
38 | # needed for writing out the qemu wrapper script | ||
39 | export STAGING_DIR_HOST | ||
40 | export B | ||
41 | |||
42 | PACKAGECONFIG ?= "" | ||
43 | PACKAGECONFIG[doctool] = "-Ddoctool=enabled,-Ddoctool=disabled,python3-mako," | ||
44 | |||
45 | # Configure target build to use native tools of itself and to use a qemu wrapper | ||
46 | # and optionally to generate introspection data | ||
47 | EXTRA_OEMESON:class-target = " \ | ||
48 | -Dgi_cross_use_prebuilt_gi=true \ | ||
49 | -Dgi_cross_binary_wrapper=${B}/g-ir-scanner-qemuwrapper \ | ||
50 | -Dgi_cross_ldd_wrapper=${B}/g-ir-scanner-lddwrapper \ | ||
51 | -Dgi_cross_pkgconfig_sysroot_path=${PKG_CONFIG_SYSROOT_DIR} \ | ||
52 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Dbuild_introspection_data=true', '-Dbuild_introspection_data=false', d)} \ | ||
53 | ${@'-Dgir_dir_prefix=${libdir}' if d.getVar('MULTILIBS') else ''} \ | ||
54 | " | ||
55 | |||
56 | do_configure:prepend:class-native() { | ||
57 | # Tweak the native python scripts so that they don't refer to the | ||
58 | # full path of native python binary (the solution is taken from glib-2.0 recipe) | ||
59 | # This removes the risk of exceeding Linux kernel's shebang line limit (128 bytes) | ||
60 | sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in | ||
61 | } | ||
62 | |||
63 | do_configure:prepend:class-target() { | ||
64 | # Write out a qemu wrapper that will be given to gi-scanner so that it | ||
65 | # can run target helper binaries through that. | ||
66 | qemu_binary="${@qemu_wrapper_cmdline(d, '$STAGING_DIR_HOST', ['\\$GIR_EXTRA_LIBS_PATH','.libs','$STAGING_DIR_HOST/${libdir}','$STAGING_DIR_HOST/${base_libdir}'])}" | ||
67 | cat > ${B}/g-ir-scanner-qemuwrapper << EOF | ||
68 | #!/bin/sh | ||
69 | # Use a modules directory which doesn't exist so we don't load random things | ||
70 | # which may then get deleted (or their dependencies) and potentially segfault | ||
71 | export GIO_MODULE_DIR=${STAGING_LIBDIR}/gio/modules-dummy | ||
72 | |||
73 | $qemu_binary "\$@" | ||
74 | if [ \$? -ne 0 ]; then | ||
75 | echo "If the above error message is about missing .so libraries, then setting up GIR_EXTRA_LIBS_PATH in the recipe should help." | ||
76 | echo "(typically like this: GIR_EXTRA_LIBS_PATH=\"$""{B}/something/.libs\" )" | ||
77 | exit 1 | ||
78 | fi | ||
79 | EOF | ||
80 | chmod +x ${B}/g-ir-scanner-qemuwrapper | ||
81 | |||
82 | # Write out a wrapper for g-ir-scanner itself, which will be used when building introspection files | ||
83 | # for glib-based packages. This wrapper calls the native version of the scanner, and tells it to use | ||
84 | # a qemu wrapper for running transient target binaries produced by the scanner, and an include directory | ||
85 | # from the target sysroot. | ||
86 | cat > ${B}/g-ir-scanner-wrapper << EOF | ||
87 | #!/bin/sh | ||
88 | # This prevents g-ir-scanner from writing cache data to user's HOME dir | ||
89 | export GI_SCANNER_DISABLE_CACHE=1 | ||
90 | |||
91 | g-ir-scanner --lib-dirs-envvar=GIR_EXTRA_LIBS_PATH --use-binary-wrapper=${STAGING_BINDIR}/g-ir-scanner-qemuwrapper --use-ldd-wrapper=${STAGING_BINDIR}/g-ir-scanner-lddwrapper --add-include-path=${STAGING_DATADIR}/gir-1.0 --add-include-path=${STAGING_LIBDIR}/gir-1.0 "\$@" | ||
92 | EOF | ||
93 | chmod +x ${B}/g-ir-scanner-wrapper | ||
94 | |||
95 | # Write out a wrapper for g-ir-compiler, which runs the target version of it through qemu. | ||
96 | # g-ir-compiler writes out the raw content of a C struct to disk, and therefore is architecture dependent. | ||
97 | cat > ${B}/g-ir-compiler-wrapper << EOF | ||
98 | #!/bin/sh | ||
99 | ${STAGING_BINDIR}/g-ir-scanner-qemuwrapper ${STAGING_BINDIR}/g-ir-compiler "\$@" | ||
100 | EOF | ||
101 | chmod +x ${B}/g-ir-compiler-wrapper | ||
102 | |||
103 | # Write out a wrapper to use instead of ldd, which does not work when a binary is built | ||
104 | # for a different architecture | ||
105 | cat > ${B}/g-ir-scanner-lddwrapper << EOF | ||
106 | #!/bin/sh | ||
107 | \$OBJDUMP -p "\$@" | ||
108 | EOF | ||
109 | chmod +x ${B}/g-ir-scanner-lddwrapper | ||
110 | |||
111 | # Also tweak the target python scripts so that they don't refer to the | ||
112 | # native version of python binary (the solution is taken from glib-2.0 recipe) | ||
113 | sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in | ||
114 | } | ||
115 | |||
116 | do_compile:prepend() { | ||
117 | # Needed to run g-ir unit tests, which won't be able to find the built libraries otherwise | ||
118 | export GIR_EXTRA_LIBS_PATH=$B/.libs | ||
119 | } | ||
120 | |||
121 | do_install:prepend() { | ||
122 | # This prevents g-ir-scanner from writing cache data to $HOME | ||
123 | export GI_SCANNER_DISABLE_CACHE=1 | ||
124 | } | ||
125 | |||
126 | # Our wrappers need to be available system-wide, because they will be used | ||
127 | # to build introspection files for all other gobject-based packages | ||
128 | do_install:append:class-target() { | ||
129 | install -d ${D}${bindir}/ | ||
130 | install ${B}/g-ir-scanner-qemuwrapper ${D}${bindir}/ | ||
131 | install ${B}/g-ir-scanner-wrapper ${D}${bindir}/ | ||
132 | install ${B}/g-ir-compiler-wrapper ${D}${bindir}/ | ||
133 | install ${B}/g-ir-scanner-lddwrapper ${D}${bindir}/ | ||
134 | } | ||
135 | |||
136 | # we need target versions of introspection tools in sysroot so that they can be run via qemu | ||
137 | # when building introspection files in other packages | ||
138 | SYSROOT_DIRS:append:class-target = " ${bindir}" | ||
139 | |||
140 | SYSROOT_PREPROCESS_FUNCS:append:class-target = " gi_binaries_sysroot_preprocess" | ||
141 | gi_binaries_sysroot_preprocess() { | ||
142 | # Tweak the binary names in the introspection pkgconfig file, so that it | ||
143 | # picks up our wrappers which do the cross-compile and qemu magic. | ||
144 | sed -i \ | ||
145 | -e "s|g_ir_scanner=.*|g_ir_scanner=${bindir}/g-ir-scanner-wrapper|" \ | ||
146 | -e "s|g_ir_compiler=.*|g_ir_compiler=${bindir}/g-ir-compiler-wrapper|" \ | ||
147 | ${SYSROOT_DESTDIR}${libdir}/pkgconfig/gobject-introspection-1.0.pc | ||
148 | } | ||
149 | |||
150 | SYSROOT_PREPROCESS_FUNCS:append = " gi_ldsoconf_sysroot_preprocess" | ||
151 | gi_ldsoconf_sysroot_preprocess () { | ||
152 | mkdir -p ${SYSROOT_DESTDIR}${bindir} | ||
153 | dest=${SYSROOT_DESTDIR}${bindir}/postinst-ldsoconf-${PN} | ||
154 | echo "#!/bin/sh" > $dest | ||
155 | echo "mkdir -p ${STAGING_DIR_TARGET}${sysconfdir}" >> $dest | ||
156 | echo "echo ${base_libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest | ||
157 | echo "echo ${libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest | ||
158 | chmod 755 $dest | ||
159 | } | ||
160 | |||
161 | # Remove wrapper files from the package, only used for cross-compiling | ||
162 | PACKAGE_PREPROCESS_FUNCS += "gi_package_preprocess" | ||
163 | gi_package_preprocess() { | ||
164 | rm -f ${PKGD}${bindir}/g-ir-scanner-qemuwrapper | ||
165 | rm -f ${PKGD}${bindir}/g-ir-scanner-wrapper | ||
166 | rm -f ${PKGD}${bindir}/g-ir-compiler-wrapper | ||
167 | rm -f ${PKGD}${bindir}/g-ir-scanner-lddwrapper | ||
168 | } | ||
169 | |||
170 | SSTATE_SCAN_FILES += "g-ir-scanner-qemuwrapper g-ir-scanner-wrapper g-ir-compiler-wrapper g-ir-scanner-lddwrapper Gio-2.0.gir postinst-ldsoconf-${PN}" | ||
171 | |||
172 | # .typelib files are needed at runtime and so they go to the main package | ||
173 | FILES:${PN}:append = " ${libdir}/girepository-*/*.typelib" | ||
174 | |||
175 | # .gir files go to dev package, as they're needed for developing (but not for running) | ||
176 | # things that depends on introspection. | ||
177 | FILES:${PN}-dev:append = " ${datadir}/gir-*/*.gir ${libdir}/gir-*/*.gir" | ||
178 | FILES:${PN}-dev:append = " ${datadir}/gir-*/*.rnc" | ||
179 | |||
180 | # These are used by gobject-based packages | ||
181 | # to generate transient introspection binaries | ||
182 | FILES:${PN}-dev:append = " ${datadir}/gobject-introspection-1.0/gdump.c \ | ||
183 | ${datadir}/gobject-introspection-1.0/Makefile.introspection" | ||
184 | |||
185 | # These are used by dependent packages (e.g. pygobject) to build their | ||
186 | # testsuites. | ||
187 | FILES:${PN}-dev:append = " ${datadir}/gobject-introspection-1.0/tests/*.c \ | ||
188 | ${datadir}/gobject-introspection-1.0/tests/*.h" | ||
189 | |||
190 | FILES:${PN}-dbg += "${libdir}/gobject-introspection/giscanner/.debug/" | ||
191 | FILES:${PN}-staticdev += "${libdir}/gobject-introspection/giscanner/*.a" | ||
192 | |||
193 | # setuptools can be removed when upstream removes all uses of distutils | ||
194 | RDEPENDS:${PN} = "python3-pickle python3-xml python3-setuptools glib-2.0" | ||
195 | |||
196 | BBCLASSEXTEND = "native" | ||