diff options
Diffstat (limited to 'meta/recipes-gnome/gobject-introspection/gobject-introspection_1.66.1.bb')
-rw-r--r-- | meta/recipes-gnome/gobject-introspection/gobject-introspection_1.66.1.bb | 207 |
1 files changed, 0 insertions, 207 deletions
diff --git a/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.66.1.bb b/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.66.1.bb deleted file mode 100644 index ee0ab2866b..0000000000 --- a/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.66.1.bb +++ /dev/null | |||
@@ -1,207 +0,0 @@ | |||
1 | SUMMARY = "Middleware layer between GObject-using C libraries and language bindings" | ||
2 | DESCRIPTION = "GObject Introspection is a project for providing machine \ | ||
3 | readable introspection data of the API of C libraries. This introspection \ | ||
4 | data can be used in several different use cases, for example automatic code \ | ||
5 | generation for bindings, API verification and documentation generation." | ||
6 | HOMEPAGE = "https://wiki.gnome.org/action/show/Projects/GObjectIntrospection" | ||
7 | BUGTRACKER = "https://gitlab.gnome.org/GNOME/gobject-introspection/issues" | ||
8 | SECTION = "libs" | ||
9 | LICENSE = "LGPLv2+ & GPLv2+" | ||
10 | LIC_FILES_CHKSUM = "file://COPYING;md5=c434e8128a68bedd59b80b2ac1eb1c4a \ | ||
11 | file://tools/compiler.c;endline=20;md5=fc5007fc20022720e6c0b0cdde41fabd \ | ||
12 | file://giscanner/sourcescanner.c;endline=22;md5=194d6e0c1d00662f32d030ce44de8d39 \ | ||
13 | file://girepository/giregisteredtypeinfo.c;endline=21;md5=661847611ae6979465415f31a759ba27 \ | ||
14 | " | ||
15 | |||
16 | SRC_URI = "${GNOME_MIRROR}/${BPN}/${@oe.utils.trim_version("${PV}", 2)}/${BPN}-${PV}.tar.xz \ | ||
17 | file://0001-giscanner-ignore-error-return-codes-from-ldd-wrapper.patch \ | ||
18 | file://0001-meson.build-exclude-girepo_dep-if-introspection-data.patch \ | ||
19 | " | ||
20 | |||
21 | SRC_URI[sha256sum] = "dd44a55ee5f426ea22b6b89624708f9e8d53f5cc94e5485c15c87cb30e06161d" | ||
22 | |||
23 | SRC_URI_append_class-native = " file://0001-Relocate-the-repository-directory-for-native-builds.patch" | ||
24 | |||
25 | inherit meson pkgconfig gtk-doc python3native qemu gobject-introspection-data upstream-version-is-even multilib_script | ||
26 | |||
27 | GTKDOC_MESON_OPTION = "gtk_doc" | ||
28 | |||
29 | MULTILIB_SCRIPTS = "${PN}:${bindir}/g-ir-annotation-tool ${PN}:${bindir}/g-ir-scanner" | ||
30 | |||
31 | DEPENDS_append = " libffi zlib glib-2.0 python3 flex-native bison-native autoconf-archive" | ||
32 | |||
33 | # target build needs qemu to run temporary introspection binaries created | ||
34 | # on the fly by g-ir-scanner and a native version of itself to run | ||
35 | # native versions of its own tools during build. | ||
36 | # Also prelink-rtld is used to find out library dependencies of introspection binaries | ||
37 | # (standard ldd doesn't work when cross-compiling). | ||
38 | DEPENDS_class-target_append = " gobject-introspection-native qemu-native prelink-native" | ||
39 | |||
40 | # needed for writing out the qemu wrapper script | ||
41 | export STAGING_DIR_HOST | ||
42 | export B | ||
43 | |||
44 | PACKAGECONFIG ?= "" | ||
45 | PACKAGECONFIG[doctool] = "-Ddoctool=enabled,-Ddoctool=disabled,python3-mako," | ||
46 | |||
47 | # Configure target build to use native tools of itself and to use a qemu wrapper | ||
48 | # and optionally to generate introspection data | ||
49 | EXTRA_OEMESON_class-target = " \ | ||
50 | -Dgi_cross_use_prebuilt_gi=true \ | ||
51 | -Dgi_cross_binary_wrapper=${B}/g-ir-scanner-qemuwrapper \ | ||
52 | -Dgi_cross_ldd_wrapper=${B}/g-ir-scanner-lddwrapper \ | ||
53 | -Dgi_cross_pkgconfig_sysroot_path=${PKG_CONFIG_SYSROOT_DIR} \ | ||
54 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Dbuild_introspection_data=true', '-Dbuild_introspection_data=false', d)} \ | ||
55 | ${@'-Dgir_dir_prefix=${libdir}' if d.getVar('MULTILIBS') else ''} \ | ||
56 | " | ||
57 | |||
58 | # Need to ensure ld.so.conf exists so prelink-native works | ||
59 | # both before we build and if we install from sstate | ||
60 | do_configure[prefuncs] += "gobject_introspection_preconfigure" | ||
61 | python gobject_introspection_preconfigure () { | ||
62 | oe.utils.write_ld_so_conf(d) | ||
63 | } | ||
64 | |||
65 | do_configure_prepend_class-native() { | ||
66 | # Tweak the native python scripts so that they don't refer to the | ||
67 | # full path of native python binary (the solution is taken from glib-2.0 recipe) | ||
68 | # This removes the risk of exceeding Linux kernel's shebang line limit (128 bytes) | ||
69 | sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in | ||
70 | } | ||
71 | |||
72 | do_configure_prepend_class-target() { | ||
73 | # Write out a qemu wrapper that will be given to gi-scanner so that it | ||
74 | # can run target helper binaries through that. | ||
75 | qemu_binary="${@qemu_wrapper_cmdline(d, '$STAGING_DIR_HOST', ['\\$GIR_EXTRA_LIBS_PATH','.libs','$STAGING_DIR_HOST/${libdir}','$STAGING_DIR_HOST/${base_libdir}'])}" | ||
76 | cat > ${B}/g-ir-scanner-qemuwrapper << EOF | ||
77 | #!/bin/sh | ||
78 | # Use a modules directory which doesn't exist so we don't load random things | ||
79 | # which may then get deleted (or their dependencies) and potentially segfault | ||
80 | export GIO_MODULE_DIR=${STAGING_LIBDIR}/gio/modules-dummy | ||
81 | |||
82 | $qemu_binary "\$@" | ||
83 | if [ \$? -ne 0 ]; then | ||
84 | echo "If the above error message is about missing .so libraries, then setting up GIR_EXTRA_LIBS_PATH in the recipe should help." | ||
85 | echo "(typically like this: GIR_EXTRA_LIBS_PATH=\"$""{B}/something/.libs\" )" | ||
86 | exit 1 | ||
87 | fi | ||
88 | EOF | ||
89 | chmod +x ${B}/g-ir-scanner-qemuwrapper | ||
90 | |||
91 | # Write out a wrapper for g-ir-scanner itself, which will be used when building introspection files | ||
92 | # for glib-based packages. This wrapper calls the native version of the scanner, and tells it to use | ||
93 | # a qemu wrapper for running transient target binaries produced by the scanner, and an include directory | ||
94 | # from the target sysroot. | ||
95 | cat > ${B}/g-ir-scanner-wrapper << EOF | ||
96 | #!/bin/sh | ||
97 | # This prevents g-ir-scanner from writing cache data to $HOME | ||
98 | export GI_SCANNER_DISABLE_CACHE=1 | ||
99 | |||
100 | g-ir-scanner --lib-dirs-envvar=GIR_EXTRA_LIBS_PATH --use-binary-wrapper=${STAGING_BINDIR}/g-ir-scanner-qemuwrapper --use-ldd-wrapper=${STAGING_BINDIR}/g-ir-scanner-lddwrapper --add-include-path=${STAGING_DATADIR}/gir-1.0 --add-include-path=${STAGING_LIBDIR}/gir-1.0 "\$@" | ||
101 | EOF | ||
102 | chmod +x ${B}/g-ir-scanner-wrapper | ||
103 | |||
104 | # Write out a wrapper for g-ir-compiler, which runs the target version of it through qemu. | ||
105 | # g-ir-compiler writes out the raw content of a C struct to disk, and therefore is architecture dependent. | ||
106 | cat > ${B}/g-ir-compiler-wrapper << EOF | ||
107 | #!/bin/sh | ||
108 | ${STAGING_BINDIR}/g-ir-scanner-qemuwrapper ${STAGING_BINDIR}/g-ir-compiler "\$@" | ||
109 | EOF | ||
110 | chmod +x ${B}/g-ir-compiler-wrapper | ||
111 | |||
112 | # Write out a wrapper to use instead of ldd, which does not work when a binary is built | ||
113 | # for a different architecture | ||
114 | cat > ${B}/g-ir-scanner-lddwrapper << EOF | ||
115 | #!/bin/sh | ||
116 | prelink-rtld --root=$STAGING_DIR_HOST "\$@" | ||
117 | EOF | ||
118 | chmod +x ${B}/g-ir-scanner-lddwrapper | ||
119 | |||
120 | # Also tweak the target python scripts so that they don't refer to the | ||
121 | # native version of python binary (the solution is taken from glib-2.0 recipe) | ||
122 | sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in | ||
123 | } | ||
124 | |||
125 | do_compile_prepend() { | ||
126 | # This prevents g-ir-scanner from writing cache data to $HOME | ||
127 | export GI_SCANNER_DISABLE_CACHE=1 | ||
128 | |||
129 | # Needed to run g-ir unit tests, which won't be able to find the built libraries otherwise | ||
130 | export GIR_EXTRA_LIBS_PATH=$B/.libs | ||
131 | } | ||
132 | |||
133 | do_install_prepend() { | ||
134 | # This prevents g-ir-scanner from writing cache data to $HOME | ||
135 | export GI_SCANNER_DISABLE_CACHE=1 | ||
136 | } | ||
137 | |||
138 | # Our wrappers need to be available system-wide, because they will be used | ||
139 | # to build introspection files for all other gobject-based packages | ||
140 | do_install_append_class-target() { | ||
141 | install -d ${D}${bindir}/ | ||
142 | install ${B}/g-ir-scanner-qemuwrapper ${D}${bindir}/ | ||
143 | install ${B}/g-ir-scanner-wrapper ${D}${bindir}/ | ||
144 | install ${B}/g-ir-compiler-wrapper ${D}${bindir}/ | ||
145 | install ${B}/g-ir-scanner-lddwrapper ${D}${bindir}/ | ||
146 | } | ||
147 | |||
148 | # we need target versions of introspection tools in sysroot so that they can be run via qemu | ||
149 | # when building introspection files in other packages | ||
150 | SYSROOT_DIRS_append_class-target = " ${bindir}" | ||
151 | |||
152 | SYSROOT_PREPROCESS_FUNCS_append_class-target = " gi_binaries_sysroot_preprocess" | ||
153 | gi_binaries_sysroot_preprocess() { | ||
154 | # Tweak the binary names in the introspection pkgconfig file, so that it | ||
155 | # picks up our wrappers which do the cross-compile and qemu magic. | ||
156 | sed -i \ | ||
157 | -e "s|g_ir_scanner=.*|g_ir_scanner=${bindir}/g-ir-scanner-wrapper|" \ | ||
158 | -e "s|g_ir_compiler=.*|g_ir_compiler=${bindir}/g-ir-compiler-wrapper|" \ | ||
159 | ${SYSROOT_DESTDIR}${libdir}/pkgconfig/gobject-introspection-1.0.pc | ||
160 | } | ||
161 | |||
162 | SYSROOT_PREPROCESS_FUNCS_append = " gi_ldsoconf_sysroot_preprocess" | ||
163 | gi_ldsoconf_sysroot_preprocess () { | ||
164 | mkdir -p ${SYSROOT_DESTDIR}${bindir} | ||
165 | dest=${SYSROOT_DESTDIR}${bindir}/postinst-ldsoconf-${PN} | ||
166 | echo "#!/bin/sh" > $dest | ||
167 | echo "mkdir -p ${STAGING_DIR_TARGET}${sysconfdir}" >> $dest | ||
168 | echo "echo ${base_libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest | ||
169 | echo "echo ${libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest | ||
170 | chmod 755 $dest | ||
171 | } | ||
172 | |||
173 | # Remove wrapper files from the package, only used for cross-compiling | ||
174 | PACKAGE_PREPROCESS_FUNCS += "gi_package_preprocess" | ||
175 | gi_package_preprocess() { | ||
176 | rm -f ${PKGD}${bindir}/g-ir-scanner-qemuwrapper | ||
177 | rm -f ${PKGD}${bindir}/g-ir-scanner-wrapper | ||
178 | rm -f ${PKGD}${bindir}/g-ir-compiler-wrapper | ||
179 | rm -f ${PKGD}${bindir}/g-ir-scanner-lddwrapper | ||
180 | } | ||
181 | |||
182 | SSTATE_SCAN_FILES += "g-ir-scanner-qemuwrapper g-ir-scanner-wrapper g-ir-compiler-wrapper g-ir-scanner-lddwrapper Gio-2.0.gir postinst-ldsoconf-${PN}" | ||
183 | |||
184 | # .typelib files are needed at runtime and so they go to the main package | ||
185 | FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib" | ||
186 | |||
187 | # .gir files go to dev package, as they're needed for developing (but not for running) | ||
188 | # things that depends on introspection. | ||
189 | FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir ${libdir}/gir-*/*.gir" | ||
190 | FILES_${PN}-dev_append = " ${datadir}/gir-*/*.rnc" | ||
191 | |||
192 | # These are used by gobject-based packages | ||
193 | # to generate transient introspection binaries | ||
194 | FILES_${PN}-dev_append = " ${datadir}/gobject-introspection-1.0/gdump.c \ | ||
195 | ${datadir}/gobject-introspection-1.0/Makefile.introspection" | ||
196 | |||
197 | # These are used by dependent packages (e.g. pygobject) to build their | ||
198 | # testsuites. | ||
199 | FILES_${PN}-dev_append = " ${datadir}/gobject-introspection-1.0/tests/*.c \ | ||
200 | ${datadir}/gobject-introspection-1.0/tests/*.h" | ||
201 | |||
202 | FILES_${PN}-dbg += "${libdir}/gobject-introspection/giscanner/.debug/" | ||
203 | FILES_${PN}-staticdev += "${libdir}/gobject-introspection/giscanner/*.a" | ||
204 | |||
205 | RDEPENDS_${PN} = "python3-pickle python3-xml" | ||
206 | |||
207 | BBCLASSEXTEND = "native" | ||